<h2>Editing: go.vim</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'>&quot; Vim syntax file
&quot; Language:	Go
&quot; Maintainer:	David Barnett (https://github.com/google/vim-ft-go)
&quot; Last Change:	2014 Aug 16

&quot; Options:
&quot;   There are some options for customizing the highlighting; the recommended
&quot;   settings are the default values, but you can write:
&quot;     let OPTION_NAME = 0
&quot;   in your ~/.vimrc file to disable particular options. You can also write:
&quot;     let OPTION_NAME = 1
&quot;   to enable particular options. At present, all options default to on.
&quot;
&quot;   - g:go_highlight_array_whitespace_error
&quot;     Highlights white space after &quot;[]&quot;.
&quot;   - g:go_highlight_chan_whitespace_error
&quot;     Highlights white space around the communications operator that don't
&quot;     follow the standard style.
&quot;   - g:go_highlight_extra_types
&quot;     Highlights commonly used library types (io.Reader, etc.).
&quot;   - g:go_highlight_space_tab_error
&quot;     Highlights instances of tabs following spaces.
&quot;   - g:go_highlight_trailing_whitespace_error
&quot;     Highlights trailing white space.

&quot; Quit when a (custom) syntax file was already loaded
if exists('b:current_syntax')
  finish
endif

if !exists('g:go_highlight_array_whitespace_error')
  let g:go_highlight_array_whitespace_error = 1
endif
if !exists('g:go_highlight_chan_whitespace_error')
  let g:go_highlight_chan_whitespace_error = 1
endif
if !exists('g:go_highlight_extra_types')
  let g:go_highlight_extra_types = 1
endif
if !exists('g:go_highlight_space_tab_error')
  let g:go_highlight_space_tab_error = 1
endif
if !exists('g:go_highlight_trailing_whitespace_error')
  let g:go_highlight_trailing_whitespace_error = 1
endif

syn case match

syn keyword     goDirective         package import
syn keyword     goDeclaration       var const type
syn keyword     goDeclType          struct interface

hi def link     goDirective         Statement
hi def link     goDeclaration       Keyword
hi def link     goDeclType          Keyword

&quot; Keywords within functions
syn keyword     goStatement         defer go goto return break continue fallthrough
syn keyword     goConditional       if else switch select
syn keyword     goLabel             case default
syn keyword     goRepeat            for range

hi def link     goStatement         Statement
hi def link     goConditional       Conditional
hi def link     goLabel             Label
hi def link     goRepeat            Repeat

&quot; Predefined types
syn keyword     goType              chan map bool string error
syn keyword     goSignedInts        int int8 int16 int32 int64 rune
syn keyword     goUnsignedInts      byte uint uint8 uint16 uint32 uint64 uintptr
syn keyword     goFloats            float32 float64
syn keyword     goComplexes         complex64 complex128

hi def link     goType              Type
hi def link     goSignedInts        Type
hi def link     goUnsignedInts      Type
hi def link     goFloats            Type
hi def link     goComplexes         Type

&quot; Treat func specially: it's a declaration at the start of a line, but a type
&quot; elsewhere. Order matters here.
syn match       goType              /\&lt;func\&gt;/
syn match       goDeclaration       /^func\&gt;/

&quot; Predefined functions and values
syn keyword     goBuiltins          append cap close complex copy delete imag len
syn keyword     goBuiltins          make new panic print println real recover
syn keyword     goConstants         iota true false nil

hi def link     goBuiltins          Keyword
hi def link     goConstants         Keyword

&quot; Comments; their contents
syn keyword     goTodo              contained TODO FIXME XXX BUG
syn cluster     goCommentGroup      contains=goTodo
syn region      goComment           start=&quot;/\*&quot; end=&quot;\*/&quot; contains=@goCommentGroup,@Spell
syn region      goComment           start=&quot;//&quot; end=&quot;$&quot; contains=@goCommentGroup,@Spell

hi def link     goComment           Comment
hi def link     goTodo              Todo

&quot; Go escapes
syn match       goEscapeOctal       display contained &quot;\\[0-7]\{3}&quot;
syn match       goEscapeC           display contained +\\[abfnrtv\\'&quot;]+
syn match       goEscapeX           display contained &quot;\\x\x\{2}&quot;
syn match       goEscapeU           display contained &quot;\\u\x\{4}&quot;
syn match       goEscapeBigU        display contained &quot;\\U\x\{8}&quot;
syn match       goEscapeError       display contained +\\[^0-7xuUabfnrtv\\'&quot;]+

hi def link     goEscapeOctal       goSpecialString
hi def link     goEscapeC           goSpecialString
hi def link     goEscapeX           goSpecialString
hi def link     goEscapeU           goSpecialString
hi def link     goEscapeBigU        goSpecialString
hi def link     goSpecialString     Special
hi def link     goEscapeError       Error

&quot; Strings and their contents
syn cluster     goStringGroup       contains=goEscapeOctal,goEscapeC,goEscapeX,goEscapeU,goEscapeBigU,goEscapeError
syn region      goString            start=+&quot;+ skip=+\\\\\|\\&quot;+ end=+&quot;+ contains=@goStringGroup
syn region      goRawString         start=+`+ end=+`+

hi def link     goString            String
hi def link     goRawString         String

&quot; Characters; their contents
syn cluster     goCharacterGroup    contains=goEscapeOctal,goEscapeC,goEscapeX,goEscapeU,goEscapeBigU
syn region      goCharacter         start=+'+ skip=+\\\\\|\\'+ end=+'+ contains=@goCharacterGroup

hi def link     goCharacter         Character

&quot; Regions
syn region      goBlock             start=&quot;{&quot; end=&quot;}&quot; transparent fold
syn region      goParen             start='(' end=')' transparent

&quot; Integers
syn match       goDecimalInt        &quot;\&lt;\d\+\([Ee]\d\+\)\?\&gt;&quot;
syn match       goHexadecimalInt    &quot;\&lt;0x\x\+\&gt;&quot;
syn match       goOctalInt          &quot;\&lt;0\o\+\&gt;&quot;
syn match       goOctalError        &quot;\&lt;0\o*[89]\d*\&gt;&quot;

hi def link     goDecimalInt        Integer
hi def link     goHexadecimalInt    Integer
hi def link     goOctalInt          Integer
hi def link     Integer             Number

&quot; Floating point
syn match       goFloat             &quot;\&lt;\d\+\.\d*\([Ee][-+]\d\+\)\?\&gt;&quot;
syn match       goFloat             &quot;\&lt;\.\d\+\([Ee][-+]\d\+\)\?\&gt;&quot;
syn match       goFloat             &quot;\&lt;\d\+[Ee][-+]\d\+\&gt;&quot;

hi def link     goFloat             Float

&quot; Imaginary literals
syn match       goImaginary         &quot;\&lt;\d\+i\&gt;&quot;
syn match       goImaginary         &quot;\&lt;\d\+\.\d*\([Ee][-+]\d\+\)\?i\&gt;&quot;
syn match       goImaginary         &quot;\&lt;\.\d\+\([Ee][-+]\d\+\)\?i\&gt;&quot;
syn match       goImaginary         &quot;\&lt;\d\+[Ee][-+]\d\+i\&gt;&quot;

hi def link     goImaginary         Number

&quot; Spaces after &quot;[]&quot;
if go_highlight_array_whitespace_error != 0
  syn match goSpaceError display &quot;\(\[\]\)\@&lt;=\s\+&quot;
endif

&quot; Spacing errors around the 'chan' keyword
if go_highlight_chan_whitespace_error != 0
  &quot; receive-only annotation on chan type
  syn match goSpaceError display &quot;\(&lt;-\)\@&lt;=\s\+\(chan\&gt;\)\@=&quot;
  &quot; send-only annotation on chan type
  syn match goSpaceError display &quot;\(\&lt;chan\)\@&lt;=\s\+\(&lt;-\)\@=&quot;
  &quot; value-ignoring receives in a few contexts
  syn match goSpaceError display &quot;\(\(^\|[={(,;]\)\s*&lt;-\)\@&lt;=\s\+&quot;
endif

&quot; Extra types commonly seen
if go_highlight_extra_types != 0
  syn match goExtraType /\&lt;bytes\.\(Buffer\)\&gt;/
  syn match goExtraType /\&lt;io\.\(Reader\|Writer\|ReadWriter\|ReadWriteCloser\)\&gt;/
  syn match goExtraType /\&lt;reflect\.\(Kind\|Type\|Value\)\&gt;/
  syn match goExtraType /\&lt;unsafe\.Pointer\&gt;/
endif

&quot; Space-tab error
if go_highlight_space_tab_error != 0
  syn match goSpaceError display &quot; \+\t&quot;me=e-1
endif

&quot; Trailing white space error
if go_highlight_trailing_whitespace_error != 0
  syn match goSpaceError display excludenl &quot;\s\+$&quot;
endif

hi def link     goExtraType         Type
hi def link     goSpaceError        Error

&quot; Search backwards for a global declaration to start processing the syntax.
&quot;syn sync match goSync grouphere NONE /^\(const\|var\|type\|func\)\&gt;/

&quot; There's a bug in the implementation of grouphere. For now, use the
&quot; following as a more expensive/less precise workaround.
syn sync minlines=500

let b:current_syntax = 'go'

&quot; vim: sw=2 sts=2 et
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Fsyntax' class='btn'>Cancel</a>
        </form>