<h2>Editing: matchparen.vim</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'>&quot; Vim plugin for showing matching parens
&quot; Maintainer:  Bram Moolenaar &lt;Bram@vim.org&gt;
&quot; Last Change: 2017 Sep 30

&quot; Exit quickly when:
&quot; - this plugin was already loaded (or disabled)
&quot; - when 'compatible' is set
&quot; - the &quot;CursorMoved&quot; autocmd event is not available.
if exists(&quot;g:loaded_matchparen&quot;) || &amp;cp || !exists(&quot;##CursorMoved&quot;)
  finish
endif
let g:loaded_matchparen = 1

if !exists(&quot;g:matchparen_timeout&quot;)
  let g:matchparen_timeout = 300
endif
if !exists(&quot;g:matchparen_insert_timeout&quot;)
  let g:matchparen_insert_timeout = 60
endif

augroup matchparen
  &quot; Replace all matchparen autocommands
  autocmd! CursorMoved,CursorMovedI,WinEnter * call s:Highlight_Matching_Pair()
  if exists('##TextChanged')
    autocmd! TextChanged,TextChangedI * call s:Highlight_Matching_Pair()
  endif
augroup END

&quot; Skip the rest if it was already done.
if exists(&quot;*s:Highlight_Matching_Pair&quot;)
  finish
endif

let s:cpo_save = &amp;cpo
set cpo-=C

&quot; The function that is invoked (very often) to define a &quot;:match&quot; highlighting
&quot; for any matching paren.
function! s:Highlight_Matching_Pair()
  &quot; Remove any previous match.
  if exists('w:paren_hl_on') &amp;&amp; w:paren_hl_on
    silent! call matchdelete(3)
    let w:paren_hl_on = 0
  endif

  &quot; Avoid that we remove the popup menu.
  &quot; Return when there are no colors (looks like the cursor jumps).
  if pumvisible() || (&amp;t_Co &lt; 8 &amp;&amp; !has(&quot;gui_running&quot;))
    return
  endif

  &quot; Get the character under the cursor and check if it's in 'matchpairs'.
  let c_lnum = line('.')
  let c_col = col('.')
  let before = 0

  let text = getline(c_lnum)
  let matches = matchlist(text, '\(.\)\=\%'.c_col.'c\(.\=\)')
  if empty(matches)
    let [c_before, c] = ['', '']
  else
    let [c_before, c] = matches[1:2]
  endif
  let plist = split(&amp;matchpairs, '.\zs[:,]')
  let i = index(plist, c)
  if i &lt; 0
    &quot; not found, in Insert mode try character before the cursor
    if c_col &gt; 1 &amp;&amp; (mode() == 'i' || mode() == 'R')
      let before = strlen(c_before)
      let c = c_before
      let i = index(plist, c)
    endif
    if i &lt; 0
      &quot; not found, nothing to do
      return
    endif
  endif

  &quot; Figure out the arguments for searchpairpos().
  if i % 2 == 0
    let s_flags = 'nW'
    let c2 = plist[i + 1]
  else
    let s_flags = 'nbW'
    let c2 = c
    let c = plist[i - 1]
  endif
  if c == '['
    let c = '\['
    let c2 = '\]'
  endif

  &quot; Find the match.  When it was just before the cursor move it there for a
  &quot; moment.
  if before &gt; 0
    let has_getcurpos = exists(&quot;*getcurpos&quot;)
    if has_getcurpos
      &quot; getcurpos() is more efficient but doesn't exist before 7.4.313.
      let save_cursor = getcurpos()
    else
      let save_cursor = winsaveview()
    endif
    call cursor(c_lnum, c_col - before)
  endif

  &quot; Build an expression that detects whether the current cursor position is in
  &quot; certain syntax types (string, comment, etc.), for use as searchpairpos()'s
  &quot; skip argument.
  &quot; We match &quot;escape&quot; for special items, such as lispEscapeSpecial.
  let s_skip = '!empty(filter(map(synstack(line(&quot;.&quot;), col(&quot;.&quot;)), ''synIDattr(v:val, &quot;name&quot;)''), ' .
	\ '''v:val =~? &quot;string\\|character\\|singlequote\\|escape\\|comment&quot;''))'
  &quot; If executing the expression determines that the cursor is currently in
  &quot; one of the syntax types, then we want searchpairpos() to find the pair
  &quot; within those syntax types (i.e., not skip).  Otherwise, the cursor is
  &quot; outside of the syntax types and s_skip should keep its value so we skip any
  &quot; matching pair inside the syntax types.
  execute 'if' s_skip '| let s_skip = 0 | endif'

  &quot; Limit the search to lines visible in the window.
  let stoplinebottom = line('w$')
  let stoplinetop = line('w0')
  if i % 2 == 0
    let stopline = stoplinebottom
  else
    let stopline = stoplinetop
  endif

  &quot; Limit the search time to 300 msec to avoid a hang on very long lines.
  &quot; This fails when a timeout is not supported.
  if mode() == 'i' || mode() == 'R'
    let timeout = exists(&quot;b:matchparen_insert_timeout&quot;) ? b:matchparen_insert_timeout : g:matchparen_insert_timeout
  else
    let timeout = exists(&quot;b:matchparen_timeout&quot;) ? b:matchparen_timeout : g:matchparen_timeout
  endif
  try
    let [m_lnum, m_col] = searchpairpos(c, '', c2, s_flags, s_skip, stopline, timeout)
  catch /E118/
    &quot; Can't use the timeout, restrict the stopline a bit more to avoid taking
    &quot; a long time on closed folds and long lines.
    &quot; The &quot;viewable&quot; variables give a range in which we can scroll while
    &quot; keeping the cursor at the same position.
    &quot; adjustedScrolloff accounts for very large numbers of scrolloff.
    let adjustedScrolloff = min([&amp;scrolloff, (line('w$') - line('w0')) / 2])
    let bottom_viewable = min([line('$'), c_lnum + &amp;lines - adjustedScrolloff - 2])
    let top_viewable = max([1, c_lnum-&amp;lines+adjustedScrolloff + 2])
    &quot; one of these stoplines will be adjusted below, but the current values are
    &quot; minimal boundaries within the current window
    if i % 2 == 0
      if has(&quot;byte_offset&quot;) &amp;&amp; has(&quot;syntax_items&quot;) &amp;&amp; &amp;smc &gt; 0
	let stopbyte = min([line2byte(&quot;$&quot;), line2byte(&quot;.&quot;) + col(&quot;.&quot;) + &amp;smc * 2])
	let stopline = min([bottom_viewable, byte2line(stopbyte)])
      else
	let stopline = min([bottom_viewable, c_lnum + 100])
      endif
      let stoplinebottom = stopline
    else
      if has(&quot;byte_offset&quot;) &amp;&amp; has(&quot;syntax_items&quot;) &amp;&amp; &amp;smc &gt; 0
	let stopbyte = max([1, line2byte(&quot;.&quot;) + col(&quot;.&quot;) - &amp;smc * 2])
	let stopline = max([top_viewable, byte2line(stopbyte)])
      else
	let stopline = max([top_viewable, c_lnum - 100])
      endif
      let stoplinetop = stopline
    endif
    let [m_lnum, m_col] = searchpairpos(c, '', c2, s_flags, s_skip, stopline)
  endtry

  if before &gt; 0
    if has_getcurpos
      call setpos('.', save_cursor)
    else
      call winrestview(save_cursor)
    endif
  endif

  &quot; If a match is found setup match highlighting.
  if m_lnum &gt; 0 &amp;&amp; m_lnum &gt;= stoplinetop &amp;&amp; m_lnum &lt;= stoplinebottom 
    if exists('*matchaddpos')
      call matchaddpos('MatchParen', [[c_lnum, c_col - before], [m_lnum, m_col]], 10, 3)
    else
      exe '3match MatchParen /\(\%' . c_lnum . 'l\%' . (c_col - before) .
	    \ 'c\)\|\(\%' . m_lnum . 'l\%' . m_col . 'c\)/'
    endif
    let w:paren_hl_on = 1
  endif
endfunction

&quot; Define commands that will disable and enable the plugin.
command! DoMatchParen call s:DoMatchParen()
command! NoMatchParen call s:NoMatchParen()

func! s:NoMatchParen()
  let w = winnr()
  noau windo silent! call matchdelete(3)
  unlet! g:loaded_matchparen
  exe &quot;noau &quot;. w . &quot;wincmd w&quot;
  au! matchparen
endfunc

func! s:DoMatchParen()
  runtime plugin/matchparen.vim
  let w = winnr()
  silent windo doau CursorMoved
  exe &quot;noau &quot;. w . &quot;wincmd w&quot;
endfunc

let &amp;cpo = s:cpo_save
unlet s:cpo_save
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Fplugin' class='btn'>Cancel</a>
        </form>