<h2>Editing: tex.vim</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'>&quot; Vim indent file
&quot; Language:     LaTeX
&quot; Maintainer:   Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot; Created:      Sat, 16 Feb 2002 16:50:19 +0100
&quot; Version: 1.0.0
&quot;   Please email me if you found something I can do.  Comments, bug report and
&quot;   feature request are welcome.

&quot; Last Update:  {{{
&quot;               25th Sep 2002, by LH :
&quot;               (*) better support for the option
&quot;               (*) use some regex instead of several '||'.
&quot;               Oct 9th, 2003, by JT:
&quot;               (*) don't change indentation of lines starting with '%'
&quot;               2005/06/15, Moshe Kaminsky &lt;kaminsky AT math.huji.ac.il&gt;
&quot;               (*) New variables:
&quot;                   g:tex_items, g:tex_itemize_env, g:tex_noindent_env
&quot;               2011/3/6, by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Don't change indentation of lines starting with '%'
&quot;                   I don't see any code with '%' and it doesn't work properly
&quot;                   so I add some code.
&quot;               (*) New features: Add smartindent-like indent for &quot;{}&quot; and  &quot;[]&quot;.
&quot;               (*) New variables: g:tex_indent_brace
&quot;               2011/9/25, by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Bug fix: smartindent-like indent for &quot;[]&quot;
&quot;               (*) New features: Align with &quot;&amp;&quot;.
&quot;               (*) New variable: g:tex_indent_and.
&quot;               2011/10/23 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Bug fix: improve the smartindent-like indent for &quot;{}&quot; and
&quot;               &quot;[]&quot;.
&quot;               2012/02/27 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Bug fix: support default folding marker.
&quot;               (*) Indent with &quot;&amp;&quot; is not very handy.  Make it not enable by
&quot;               default.
&quot;               2012/03/06 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Modify &quot;&amp;&quot; behavior and make it default again.  Now &quot;&amp;&quot;
&quot;               won't align when there are more then one &quot;&amp;&quot; in the previous
&quot;               line.
&quot;               (*) Add indent &quot;\left(&quot; and &quot;\right)&quot;
&quot;               (*) Trust user when in &quot;verbatim&quot; and &quot;lstlisting&quot;
&quot;               2012/03/11 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Modify &quot;&amp;&quot; so that only indent when current line start with
&quot;                   &quot;&amp;&quot;.
&quot;               2012/03/12 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Modify indentkeys.
&quot;               2012/03/18 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Add &amp;cpo
&quot;               2013/05/02 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Fix problem about GetTeXIndent checker. Thank Albert Netymk
&quot;                   for reporting this.
&quot;               2014/06/23 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Remove the feature g:tex_indent_and because it is buggy.
&quot;               (*) If there is not any obvious indentation hints, we do not
&quot;                   alert our user's current indentation.
&quot;               (*) g:tex_indent_brace now only works if the open brace is the
&quot;                   last character of that line.
&quot;               2014/08/03 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Indent current line if last line has larger indentation
&quot;               2016/11/08 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Fix problems for \[ and \].  Thanks Bruno for reporting.
&quot;               2017/04/30 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Fix a bug between g:tex_noindent_env and g:tex_indent_items
&quot;                   Now g:tex_noindent_env='document\|verbatim\|itemize' (Emacs
&quot;                   style) is supported.  Thanks Miles Wheeler for reporting.
&quot;               2018/02/07 by Yichao Zhou &lt;broken.zhou AT gmail.com&gt;
&quot;               (*) Make indentation more smart in the normal mode
&quot;
&quot; }}}

&quot; Document: {{{
&quot;
&quot; To set the following options (ok, currently it's just one), add a line like
&quot;   let g:tex_indent_items = 1
&quot; to your ~/.vimrc.
&quot;
&quot; * g:tex_indent_brace
&quot;
&quot;   If this variable is unset or non-zero, it will use smartindent-like style
&quot;   for &quot;{}&quot; and &quot;[]&quot;.  Now this only works if the open brace is the last
&quot;   character of that line.
&quot;
&quot;         % Example 1
&quot;         \usetikzlibrary{
&quot;           external
&quot;         }
&quot;
&quot;         % Example 2
&quot;         \tikzexternalize[
&quot;           prefix=tikz]
&quot;
&quot; * g:tex_indent_items
&quot;
&quot;   If this variable is set, item-environments are indented like Emacs does
&quot;   it, i.e., continuation lines are indented with a shiftwidth.
&quot;
&quot;              set                      unset
&quot;   ------------------------------------------------------
&quot;       \begin{itemize}            \begin{itemize}
&quot;         \item blablabla            \item blablabla
&quot;           bla bla bla              bla bla bla
&quot;         \item blablabla            \item blablabla
&quot;           bla bla bla              bla bla bla
&quot;       \end{itemize}              \end{itemize}
&quot;
&quot;
&quot; * g:tex_items
&quot;
&quot;   A list of tokens to be considered as commands for the beginning of an item
&quot;   command. The tokens should be separated with '\|'. The initial '\' should
&quot;   be escaped. The default is '\\bibitem\|\\item'.
&quot;
&quot; * g:tex_itemize_env
&quot;
&quot;   A list of environment names, separated with '\|', where the items (item
&quot;   commands matching g:tex_items) may appear. The default is
&quot;   'itemize\|description\|enumerate\|thebibliography'.
&quot;
&quot; * g:tex_noindent_env
&quot;
&quot;   A list of environment names. separated with '\|', where no indentation is
&quot;   required. The default is 'document\|verbatim'.
&quot; }}}

&quot; Only define the function once
if exists(&quot;b:did_indent&quot;)
    finish
endif

let s:cpo_save = &amp;cpo
set cpo&amp;vim

&quot; Define global variable {{{

let b:did_indent = 1

if !exists(&quot;g:tex_indent_items&quot;)
    let g:tex_indent_items = 1
endif
if !exists(&quot;g:tex_indent_brace&quot;)
    let g:tex_indent_brace = 1
endif
if !exists(&quot;g:tex_max_scan_line&quot;)
    let g:tex_max_scan_line = 60
endif
if g:tex_indent_items
    if !exists(&quot;g:tex_itemize_env&quot;)
        let g:tex_itemize_env = 'itemize\|description\|enumerate\|thebibliography'
    endif
    if !exists('g:tex_items')
        let g:tex_items = '\\bibitem\|\\item'
    endif
else
    let g:tex_items = ''
endif

if !exists(&quot;g:tex_noindent_env&quot;)
    let g:tex_noindent_env = 'document\|verbatim\|lstlisting'
endif &quot;}}}

&quot; VIM Setting &quot; {{{
setlocal autoindent
setlocal nosmartindent
setlocal indentexpr=GetTeXIndent()
setlocal indentkeys&amp;
exec 'setlocal indentkeys+=[,(,{,),},],\&amp;' . substitute(g:tex_items, '^\|\(\\|\)', ',=', 'g')
let g:tex_items = '^\s*' . substitute(g:tex_items, '^\(\^\\s\*\)*', '', '')
&quot; }}}

function! GetTeXIndent() &quot; {{{
    &quot; Find a non-blank line above the current line.
    let lnum = prevnonblank(v:lnum - 1)
    let cnum = v:lnum

    &quot; Comment line is not what we need.
    while lnum != 0 &amp;&amp; getline(lnum) =~ '^\s*%'
        let lnum = prevnonblank(lnum - 1)
    endwhile

    &quot; At the start of the file use zero indent.
    if lnum == 0
        return 0
    endif

    let line = substitute(getline(lnum), '\s*%.*', '','g')     &quot; last line
    let cline = substitute(getline(v:lnum), '\s*%.*', '', 'g') &quot; current line

    &quot;  We are in verbatim, so do what our user what.
    if synIDattr(synID(v:lnum, indent(v:lnum), 1), &quot;name&quot;) == &quot;texZone&quot;
        if empty(cline)
            return indent(lnum)
        else
            return indent(v:lnum)
        end
    endif

    if lnum == 0
        return 0
    endif

    let ind = indent(lnum)
    let stay = 1

    &quot; New code for comment: retain the indent of current line
    if cline =~ '^\s*%'
        return indent(v:lnum)
    endif

    &quot; Add a 'shiftwidth' after beginning of environments.
    &quot; Don't add it for \begin{document} and \begin{verbatim}
    &quot; if line =~ '^\s*\\begin{\(.*\)}'  &amp;&amp; line !~ 'verbatim'
    &quot; LH modification : \begin does not always start a line
    &quot; ZYC modification : \end after \begin won't cause wrong indent anymore
    if line =~ '\\begin{.*}' 
        if line !~ g:tex_noindent_env
            let ind = ind + shiftwidth()
            let stay = 0
        endif

        if g:tex_indent_items
            &quot; Add another sw for item-environments
            if line =~ g:tex_itemize_env
                let ind = ind + shiftwidth()
                let stay = 0
            endif
        endif
    endif

    if cline =~ '\\end{.*}'
        let retn = s:GetEndIndentation(v:lnum)
        if retn != -1
            return retn
        endif
    end
    &quot; Subtract a 'shiftwidth' when an environment ends
    if cline =~ '\\end{.*}'
                \ &amp;&amp; cline !~ g:tex_noindent_env
                \ &amp;&amp; cline !~ '\\begin{.*}.*\\end{.*}'
        if g:tex_indent_items
            &quot; Remove another sw for item-environments
            if cline =~ g:tex_itemize_env
                let ind = ind - shiftwidth()
                let stay = 0
            endif
        endif

        let ind = ind - shiftwidth()
        let stay = 0
    endif

    if g:tex_indent_brace
        if line =~ '[[{]$'
            let ind += shiftwidth()
            let stay = 0
        endif

        if cline =~ '^\s*\\\?[\]}]' &amp;&amp; s:CheckPairedIsLastCharacter(v:lnum, indent(v:lnum))
            let ind -= shiftwidth()
            let stay = 0
        endif

        if line !~ '^\s*\\\?[\]}]'
            for i in range(indent(lnum)+1, strlen(line)-1)
                let char = line[i]
                if char == ']' || char == '}'
                    if s:CheckPairedIsLastCharacter(lnum, i)
                        let ind -= shiftwidth()
                        let stay = 0
                    endif
                endif
            endfor
        endif
    endif

    &quot; Special treatment for 'item'
    &quot; ----------------------------

    if g:tex_indent_items
        &quot; '\item' or '\bibitem' itself:
        if cline =~ g:tex_items
            let ind = ind - shiftwidth()
            let stay = 0
        endif
        &quot; lines following to '\item' are intented once again:
        if line =~ g:tex_items
            let ind = ind + shiftwidth()
            let stay = 0
        endif
    endif

    if stay &amp;&amp; mode() == 'i'
        &quot; If there is no obvious indentation hint, and indentation is triggered
        &quot; in insert mode, we trust our user.
        if empty(cline)
            return ind
        else
            return max([indent(v:lnum), s:GetLastBeginIndentation(v:lnum)])
        endif
    else
        return ind
    endif
endfunction &quot;}}}

function! s:GetLastBeginIndentation(lnum) &quot; {{{
    let matchend = 1
    for lnum in range(a:lnum-1, max([a:lnum - g:tex_max_scan_line, 1]), -1)
        let line = getline(lnum)
        if line =~ '\\end{.*}'
            let matchend += 1
        endif
        if line =~ '\\begin{.*}'
            let matchend -= 1
        endif
        if matchend == 0
            if line =~ g:tex_noindent_env
                return indent(lnum)
            endif
            if line =~ g:tex_itemize_env
                return indent(lnum) + 2 * shiftwidth()
            endif
            return indent(lnum) + shiftwidth()
        endif
    endfor
    return -1
endfunction

function! s:GetEndIndentation(lnum) &quot; {{{
    if getline(a:lnum) =~ '\\begin{.*}.*\\end{.*}'
        return -1
    endif

    let min_indent = 100
    let matchend = 1
    for lnum in range(a:lnum-1, max([a:lnum-g:tex_max_scan_line, 1]), -1)
        let line = getline(lnum)
        if line =~ '\\end{.*}'
            let matchend += 1
        endif
        if line =~ '\\begin{.*}'
            let matchend -= 1
        endif
        if matchend == 0
            return indent(lnum)
        endif
        if !empty(line)
            let min_indent = min([min_indent, indent(lnum)])
        endif
    endfor
    return min_indent - shiftwidth()
endfunction

&quot; Most of the code is from matchparen.vim
function! s:CheckPairedIsLastCharacter(lnum, col) &quot;{{{
    let c_lnum = a:lnum
    let c_col = a:col+1

    let line = getline(c_lnum)
    if line[c_col-1] == '\'
        let c_col = c_col + 1
    endif
    let c = line[c_col-1]

    let plist = split(&amp;matchpairs, '.\zs[:,]')
    let i = index(plist, c)
    if i &lt; 0
        return 0
    endif

    &quot; Figure out the arguments for searchpairpos().
    if i % 2 == 0
        let s_flags = 'nW'
        let c2 = plist[i + 1]
    else
        let s_flags = 'nbW'
        let c2 = c
        let c = plist[i - 1]
    endif
    if c == '['
        let c = '\['
        let c2 = '\]'
    endif

    &quot; Find the match.  When it was just before the cursor move it there for a
    &quot; moment.
    let save_cursor = winsaveview()
    call cursor(c_lnum, c_col)

    &quot; When not in a string or comment ignore matches inside them.
    &quot; We match &quot;escape&quot; for special items, such as lispEscapeSpecial.
    let s_skip ='synIDattr(synID(line(&quot;.&quot;), col(&quot;.&quot;), 0), &quot;name&quot;) ' .
                \ '=~?  &quot;string\\|character\\|singlequote\\|escape\\|comment&quot;'
    execute 'if' s_skip '| let s_skip = 0 | endif'

    let stopline = max([0, c_lnum - g:tex_max_scan_line])

    &quot; Limit the search time to 300 msec to avoid a hang on very long lines.
    &quot; This fails when a timeout is not supported.
    try
        let [m_lnum, m_col] = searchpairpos(c, '', c2, s_flags, s_skip, stopline, 100)
    catch /E118/
    endtry

    call winrestview(save_cursor)

    if m_lnum &gt; 0
        let line = getline(m_lnum)
        return strlen(line) == m_col
    endif

    return 0
endfunction &quot;}}}

let &amp;cpo = s:cpo_save
unlet s:cpo_save

&quot; vim: set sw=4 textwidth=80:
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Findent' class='btn'>Cancel</a>
        </form>