<h2>Editing: sas.vim</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'>&quot; Vim indent file
&quot; Language:     SAS
&quot; Maintainer:   Zhen-Huan Hu &lt;wildkeny@gmail.com&gt;
&quot; Version:      3.0.1
&quot; Last Change:  Mar 13, 2017

if exists(&quot;b:did_indent&quot;)
  finish
endif
let b:did_indent = 1

setlocal indentexpr=GetSASIndent()
setlocal indentkeys+=;,=~data,=~proc,=~macro

if exists(&quot;*GetSASIndent&quot;)
  finish
endif

let s:cpo_save = &amp;cpo
set cpo&amp;vim

&quot; Regex that captures the start of a data/proc section
let s:section_str = '\v%(^|;)\s*%(data|proc)&gt;'
&quot; Regex that captures the end of a run-processing section
let s:section_run = '\v%(^|;)\s*run\s*;'
&quot; Regex that captures the end of a data/proc section
let s:section_end = '\v%(^|;)\s*%(quit|enddata)\s*;'

&quot; Regex that captures the start of a control block (anything inside a section)
let s:block_str = '\v&lt;%(do&gt;%([^;]+&lt;%(to|over)&gt;[^;]+)=|%(define|layout|method|select)&gt;[^;]+|begingraph)\s*;'
&quot; Regex that captures the end of a control block (anything inside a section)
let s:block_end = '\v&lt;%(end|endlayout|endgraph)\s*;'

&quot; Regex that captures the start of a macro
let s:macro_str = '\v%(^|;)\s*\%macro&gt;'
&quot; Regex that captures the end of a macro
let s:macro_end = '\v%(^|;)\s*\%mend\s*;'

&quot; Regex that defines the end of the program
let s:program_end = '\v%(^|;)\s*endsas\s*;'

&quot; List of procs supporting run-processing
let s:run_processing_procs = [
      \ 'catalog', 'chart', 'datasets', 'document', 'ds2', 'plot', 'sql',
      \ 'gareabar', 'gbarline', 'gchart', 'gkpi', 'gmap', 'gplot', 'gradar', 'greplay', 'gslide', 'gtile',
      \ 'anova', 'arima', 'catmod', 'factex', 'glm', 'model', 'optex', 'plan', 'reg',
      \ 'iml',
      \ ]

&quot; Find the line number of previous keyword defined by the regex
function! s:PrevMatch(lnum, regex)
  let prev_lnum = prevnonblank(a:lnum - 1)
  while prev_lnum &gt; 0
    let prev_line = getline(prev_lnum)
    if prev_line =~ a:regex
      break
    else
      let prev_lnum = prevnonblank(prev_lnum - 1)
    endif
  endwhile
  return prev_lnum
endfunction

&quot; Main function
function! GetSASIndent()
  let prev_lnum = prevnonblank(v:lnum - 1)
  if prev_lnum ==# 0
    &quot; Leave the indentation of the first line unchanged
    return indent(1)
  else
    let prev_line = getline(prev_lnum)
    &quot; Previous non-blank line contains the start of a macro/section/block
    &quot; while not the end of a macro/section/block (at the same line)
    if (prev_line =~ s:section_str &amp;&amp; prev_line !~ s:section_run &amp;&amp; prev_line !~ s:section_end) ||
          \ (prev_line =~ s:block_str &amp;&amp; prev_line !~ s:block_end) ||
          \ (prev_line =~ s:macro_str &amp;&amp; prev_line !~ s:macro_end)
      let ind = indent(prev_lnum) + &amp;sts
    elseif prev_line =~ s:section_run &amp;&amp; prev_line !~ s:section_end
      let prev_section_str_lnum = s:PrevMatch(v:lnum, s:section_str)
      let prev_section_end_lnum = max([
            \ s:PrevMatch(v:lnum, s:section_end),
            \ s:PrevMatch(v:lnum, s:macro_end  ),
            \ s:PrevMatch(v:lnum, s:program_end)])
      &quot; Check if the section supports run-processing
      if prev_section_end_lnum &lt; prev_section_str_lnum &amp;&amp;
            \ getline(prev_section_str_lnum) =~ '\v%(^|;)\s*proc\s+%(' .
            \ join(s:run_processing_procs, '|') . ')&gt;'
        let ind = indent(prev_lnum) + &amp;sts
      else
        let ind = indent(prev_lnum)
      endif
    else
      let ind = indent(prev_lnum)
    endif
  endif
  &quot; Re-adjustments based on the inputs of the current line
  let curr_line = getline(v:lnum)
  if curr_line =~ s:program_end
    &quot; End of the program
    &quot; Same indentation as the first non-blank line
    return indent(nextnonblank(1))
  elseif curr_line =~ s:macro_end
    &quot; Current line is the end of a macro
    &quot; Match the indentation of the start of the macro
    return indent(s:PrevMatch(v:lnum, s:macro_str))
  elseif curr_line =~ s:block_end &amp;&amp; curr_line !~ s:block_str
    &quot; Re-adjust if current line is the end of a block
    &quot; while not the beginning of a block (at the same line)
    &quot; Returning the indent of previous block start directly
    &quot; would not work due to nesting
    let ind = ind - &amp;sts
  elseif curr_line =~ s:section_str || curr_line =~ s:section_run || curr_line =~ s:section_end
    &quot; Re-adjust if current line is the start/end of a section
    &quot; since the end of a section could be inexplicit
    let prev_section_str_lnum = s:PrevMatch(v:lnum, s:section_str)
    &quot; Check if the previous section supports run-processing
    if getline(prev_section_str_lnum) =~ '\v%(^|;)\s*proc\s+%(' .
          \ join(s:run_processing_procs, '|') . ')&gt;'
      let prev_section_end_lnum = max([
            \ s:PrevMatch(v:lnum, s:section_end),
            \ s:PrevMatch(v:lnum, s:macro_end  ),
            \ s:PrevMatch(v:lnum, s:program_end)])
    else
      let prev_section_end_lnum = max([
            \ s:PrevMatch(v:lnum, s:section_end),
            \ s:PrevMatch(v:lnum, s:section_run),
            \ s:PrevMatch(v:lnum, s:macro_end  ),
            \ s:PrevMatch(v:lnum, s:program_end)])
    endif
    if prev_section_end_lnum &lt; prev_section_str_lnum
      let ind = ind - &amp;sts
    endif
  endif
  return ind
endfunction

let &amp;cpo = s:cpo_save
unlet s:cpo_save
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Findent' class='btn'>Cancel</a>
        </form>