<h2>Editing: python.vim</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'>&quot; Vim indent file
&quot; Language:		Python
&quot; Maintainer:		Bram Moolenaar &lt;Bram@vim.org&gt;
&quot; Original Author:	David Bustos &lt;bustos@caltech.edu&gt;
&quot; Last Change:		2013 Jul 9

&quot; Only load this indent file when no other was loaded.
if exists(&quot;b:did_indent&quot;)
  finish
endif
let b:did_indent = 1

&quot; Some preliminary settings
setlocal nolisp		&quot; Make sure lisp indenting doesn't supersede us
setlocal autoindent	&quot; indentexpr isn't much help otherwise

setlocal indentexpr=GetPythonIndent(v:lnum)
setlocal indentkeys+=&lt;:&gt;,=elif,=except

&quot; Only define the function once.
if exists(&quot;*GetPythonIndent&quot;)
  finish
endif
let s:keepcpo= &amp;cpo
set cpo&amp;vim

&quot; Come here when loading the script the first time.

let s:maxoff = 50	&quot; maximum number of lines to look backwards for ()

function GetPythonIndent(lnum)

  &quot; If this line is explicitly joined: If the previous line was also joined,
  &quot; line it up with that one, otherwise add two 'shiftwidth'
  if getline(a:lnum - 1) =~ '\\$'
    if a:lnum &gt; 1 &amp;&amp; getline(a:lnum - 2) =~ '\\$'
      return indent(a:lnum - 1)
    endif
    return indent(a:lnum - 1) + (exists(&quot;g:pyindent_continue&quot;) ? eval(g:pyindent_continue) : (shiftwidth() * 2))
  endif

  &quot; If the start of the line is in a string don't change the indent.
  if has('syntax_items')
	\ &amp;&amp; synIDattr(synID(a:lnum, 1, 1), &quot;name&quot;) =~ &quot;String$&quot;
    return -1
  endif

  &quot; Search backwards for the previous non-empty line.
  let plnum = prevnonblank(v:lnum - 1)

  if plnum == 0
    &quot; This is the first non-empty line, use zero indent.
    return 0
  endif

  &quot; If the previous line is inside parenthesis, use the indent of the starting
  &quot; line.
  &quot; Trick: use the non-existing &quot;dummy&quot; variable to break out of the loop when
  &quot; going too far back.
  call cursor(plnum, 1)
  let parlnum = searchpair('(\|{\|\[', '', ')\|}\|\]', 'nbW',
	  \ &quot;line('.') &lt; &quot; . (plnum - s:maxoff) . &quot; ? dummy :&quot;
	  \ . &quot; synIDattr(synID(line('.'), col('.'), 1), 'name')&quot;
	  \ . &quot; =~ '\\(Comment\\|Todo\\|String\\)$'&quot;)
  if parlnum &gt; 0
    let plindent = indent(parlnum)
    let plnumstart = parlnum
  else
    let plindent = indent(plnum)
    let plnumstart = plnum
  endif


  &quot; When inside parenthesis: If at the first line below the parenthesis add
  &quot; two 'shiftwidth', otherwise same as previous line.
  &quot; i = (a
  &quot;       + b
  &quot;       + c)
  call cursor(a:lnum, 1)
  let p = searchpair('(\|{\|\[', '', ')\|}\|\]', 'bW',
	  \ &quot;line('.') &lt; &quot; . (a:lnum - s:maxoff) . &quot; ? dummy :&quot;
	  \ . &quot; synIDattr(synID(line('.'), col('.'), 1), 'name')&quot;
	  \ . &quot; =~ '\\(Comment\\|Todo\\|String\\)$'&quot;)
  if p &gt; 0
    if p == plnum
      &quot; When the start is inside parenthesis, only indent one 'shiftwidth'.
      let pp = searchpair('(\|{\|\[', '', ')\|}\|\]', 'bW',
	  \ &quot;line('.') &lt; &quot; . (a:lnum - s:maxoff) . &quot; ? dummy :&quot;
	  \ . &quot; synIDattr(synID(line('.'), col('.'), 1), 'name')&quot;
	  \ . &quot; =~ '\\(Comment\\|Todo\\|String\\)$'&quot;)
      if pp &gt; 0
	return indent(plnum) + (exists(&quot;g:pyindent_nested_paren&quot;) ? eval(g:pyindent_nested_paren) : shiftwidth())
      endif
      return indent(plnum) + (exists(&quot;g:pyindent_open_paren&quot;) ? eval(g:pyindent_open_paren) : (shiftwidth() * 2))
    endif
    if plnumstart == p
      return indent(plnum)
    endif
    return plindent
  endif


  &quot; Get the line and remove a trailing comment.
  &quot; Use syntax highlighting attributes when possible.
  let pline = getline(plnum)
  let pline_len = strlen(pline)
  if has('syntax_items')
    &quot; If the last character in the line is a comment, do a binary search for
    &quot; the start of the comment.  synID() is slow, a linear search would take
    &quot; too long on a long line.
    if synIDattr(synID(plnum, pline_len, 1), &quot;name&quot;) =~ &quot;\\(Comment\\|Todo\\)$&quot;
      let min = 1
      let max = pline_len
      while min &lt; max
	let col = (min + max) / 2
	if synIDattr(synID(plnum, col, 1), &quot;name&quot;) =~ &quot;\\(Comment\\|Todo\\)$&quot;
	  let max = col
	else
	  let min = col + 1
	endif
      endwhile
      let pline = strpart(pline, 0, min - 1)
    endif
  else
    let col = 0
    while col &lt; pline_len
      if pline[col] == '#'
	let pline = strpart(pline, 0, col)
	break
      endif
      let col = col + 1
    endwhile
  endif

  &quot; If the previous line ended with a colon, indent this line
  if pline =~ ':\s*$'
    return plindent + shiftwidth()
  endif

  &quot; If the previous line was a stop-execution statement...
  if getline(plnum) =~ '^\s*\(break\|continue\|raise\|return\|pass\)\&gt;'
    &quot; See if the user has already dedented
    if indent(a:lnum) &gt; indent(plnum) - shiftwidth()
      &quot; If not, recommend one dedent
      return indent(plnum) - shiftwidth()
    endif
    &quot; Otherwise, trust the user
    return -1
  endif

  &quot; If the current line begins with a keyword that lines up with &quot;try&quot;
  if getline(a:lnum) =~ '^\s*\(except\|finally\)\&gt;'
    let lnum = a:lnum - 1
    while lnum &gt;= 1
      if getline(lnum) =~ '^\s*\(try\|except\)\&gt;'
	let ind = indent(lnum)
	if ind &gt;= indent(a:lnum)
	  return -1	&quot; indent is already less than this
	endif
	return ind	&quot; line up with previous try or except
      endif
      let lnum = lnum - 1
    endwhile
    return -1		&quot; no matching &quot;try&quot;!
  endif

  &quot; If the current line begins with a header keyword, dedent
  if getline(a:lnum) =~ '^\s*\(elif\|else\)\&gt;'

    &quot; Unless the previous line was a one-liner
    if getline(plnumstart) =~ '^\s*\(for\|if\|try\)\&gt;'
      return plindent
    endif

    &quot; Or the user has already dedented
    if indent(a:lnum) &lt;= plindent - shiftwidth()
      return -1
    endif

    return plindent - shiftwidth()
  endif

  &quot; When after a () construct we probably want to go back to the start line.
  &quot; a = (b
  &quot;       + c)
  &quot; here
  if parlnum &gt; 0
    return plindent
  endif

  return -1

endfunction

let &amp;cpo = s:keepcpo
unlet s:keepcpo

&quot; vim:sw=2
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Findent' class='btn'>Cancel</a>
        </form>