<h2>Editing: j.vim</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'>&quot; Vim filetype plugin
&quot; Language:	J
&quot; Maintainer:	David Bürgin &lt;676c7473@gmail.com&gt;
&quot; URL:		https://github.com/glts/vim-j
&quot; Last Change:	2015-09-27

if exists('b:did_ftplugin')
  finish
endif
let b:did_ftplugin = 1

let s:save_cpo = &amp;cpo
set cpo&amp;vim

setlocal iskeyword=48-57,A-Z,a-z,_
setlocal comments=:NB.
setlocal commentstring=NB.\ %s
setlocal formatoptions-=t
setlocal matchpairs=(:)
setlocal path-=/usr/include

&quot; Includes. To make the shorthand form &quot;require 'web/cgi'&quot; work, double the
&quot; last path component. Also strip off leading folder names like &quot;~addons/&quot;.
setlocal include=\\v^\\s*(load\|require)\\s*'\\zs\\f+\\ze'
setlocal includeexpr=substitute(substitute(tr(v:fname,'\\','/'),'\\v^[^~][^/.]*(/[^/.]+)$','&amp;\\1',''),'\\v^\\~[^/]+/','','')
setlocal suffixesadd=.ijs

let b:undo_ftplugin = 'setlocal matchpairs&lt; formatoptions&lt; commentstring&lt; comments&lt; iskeyword&lt; path&lt; include&lt; includeexpr&lt; suffixesadd&lt;'

&quot; Section movement with ]] ][ [[ []. The start/end patterns below are amended
&quot; inside the function in order to avoid matching on the current cursor line.
let s:sectionstart = '\%(\s*Note\|.\{-}\&lt;\%([0-4]\|13\|noun\|adverb\|conjunction\|verb\|monad\|dyad\)\s\+\%(:\s*0\|def\s\+0\|define\)\)\&gt;.*'
let s:sectionend = '\s*)\s*'

function! s:SearchSection(end, backwards, visualmode) abort
  if a:visualmode !=# ''
    normal! gv
  endif
  let l:flags = a:backwards ? 'bsW' : 'sW'
  if a:end
    call search('^' . s:sectionend . (a:backwards ? '\n\_.\{-}\%#' : '$'), l:flags)
  else
    call search('^' . s:sectionstart . (a:backwards ? '\n\_.\{-}\%#' : '$'), l:flags)
  endif
endfunction

noremap &lt;buffer&gt; &lt;silent&gt; ]] :&lt;C-U&gt;call &lt;SID&gt;SearchSection(0, 0, '')&lt;CR&gt;
xnoremap &lt;buffer&gt; &lt;silent&gt; ]] :&lt;C-U&gt;call &lt;SID&gt;SearchSection(0, 0, visualmode())&lt;CR&gt;
sunmap &lt;buffer&gt; ]]
noremap &lt;buffer&gt; &lt;silent&gt; ][ :&lt;C-U&gt;call &lt;SID&gt;SearchSection(1, 0, '')&lt;CR&gt;
xnoremap &lt;buffer&gt; &lt;silent&gt; ][ :&lt;C-U&gt;call &lt;SID&gt;SearchSection(1, 0, visualmode())&lt;CR&gt;
sunmap &lt;buffer&gt; ][
noremap &lt;buffer&gt; &lt;silent&gt; [[ :&lt;C-U&gt;call &lt;SID&gt;SearchSection(0, 1, '')&lt;CR&gt;
xnoremap &lt;buffer&gt; &lt;silent&gt; [[ :&lt;C-U&gt;call &lt;SID&gt;SearchSection(0, 1, visualmode())&lt;CR&gt;
sunmap &lt;buffer&gt; [[
noremap &lt;buffer&gt; &lt;silent&gt; [] :&lt;C-U&gt;call &lt;SID&gt;SearchSection(1, 1, '')&lt;CR&gt;
xnoremap &lt;buffer&gt; &lt;silent&gt; [] :&lt;C-U&gt;call &lt;SID&gt;SearchSection(1, 1, visualmode())&lt;CR&gt;
sunmap &lt;buffer&gt; []

let b:undo_ftplugin .= ' | silent! execute &quot;unmap &lt;buffer&gt; ]]&quot;'
                   \ . ' | silent! execute &quot;unmap &lt;buffer&gt; ][&quot;'
                   \ . ' | silent! execute &quot;unmap &lt;buffer&gt; [[&quot;'
                   \ . ' | silent! execute &quot;unmap &lt;buffer&gt; []&quot;'

&quot; Browse dialog filter on Windows (see &quot;:help browsefilter&quot;)
if has('gui_win32') &amp;&amp; !exists('b:browsefilter')
  let b:browsefilter = &quot;J Script Files (*.ijs)\t*.ijs\n&quot;
                   \ . &quot;All Files (*.*)\t*.*\n&quot;
  let b:undo_ftplugin .= ' | unlet! b:browsefilter'
endif

&quot; Enhanced &quot;%&quot; matching (see &quot;:help matchit&quot;)
if exists('loaded_matchit') &amp;&amp; !exists('b:match_words')
  let b:match_ignorecase = 0
  let b:match_words = '^\%(\s*Note\|.\{-}\&lt;\%([0-4]\|13\|noun\|adverb\|conjunction\|verb\|monad\|dyad\)\s\+\%(\:\s*0\|def\s\+0\|define\)\)\&gt;:^\s*\:\s*$:^\s*)\s*$'
                  \ . ',\&lt;\%(for\%(_\a\k*\)\=\|if\|select\|try\|whil\%(e\|st\)\)\.:\&lt;\%(case\|catch[dt]\=\|else\%(if\)\=\|fcase\)\.:\&lt;end\.'
  let b:undo_ftplugin .= ' | unlet! b:match_ignorecase b:match_words'
endif

let &amp;cpo = s:save_cpo
unlet s:save_cpo
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Fftplugin' class='btn'>Cancel</a>
        </form>