<h2>Editing: DB.pm</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'>#
# Documentation is at the __END__
#

package DB;

# &quot;private&quot; globals

my ($running, $ready, $deep, $usrctxt, $evalarg, 
    @stack, @saved, @skippkg, @clients);
my $preeval = {};
my $posteval = {};
my $ineval = {};

####
#
# Globals - must be defined at startup so that clients can refer to 
# them right after a C&lt;require DB;&gt;
#
####

BEGIN {

  # these are hardcoded in perl source (some are magical)

  $DB::sub = '';        # name of current subroutine
  %DB::sub = ();        # &quot;filename:fromline-toline&quot; for every known sub
  $DB::single = 0;      # single-step flag (set it to 1 to enable stops in BEGIN/use)
  $DB::signal = 0;      # signal flag (will cause a stop at the next line)
  $DB::trace = 0;       # are we tracing through subroutine calls?
  @DB::args = ();       # arguments of current subroutine or @ARGV array
  @DB::dbline = ();     # list of lines in currently loaded file
  %DB::dbline = ();     # actions in current file (keyed by line number)
  @DB::ret = ();        # return value of last sub executed in list context
  $DB::ret = '';        # return value of last sub executed in scalar context

  # other &quot;public&quot; globals  

  $DB::package = '';    # current package space
  $DB::filename = '';   # current filename
  $DB::subname = '';    # currently executing sub (fully qualified name)
  $DB::lineno = '';     # current line number

  $DB::VERSION = $DB::VERSION = '1.08';

  # initialize private globals to avoid warnings

  $running = 1;         # are we running, or are we stopped?
  @stack = (0);
  @clients = ();
  $deep = 1000;
  $ready = 0;
  @saved = ();
  @skippkg = ();
  $usrctxt = '';
  $evalarg = '';
}

####
# entry point for all subroutine calls
#
sub sub {
  push(@stack, $DB::single);
  $DB::single &amp;= 1;
  $DB::single |= 4 if $#stack == $deep;
  if ($DB::sub eq 'DESTROY' or substr($DB::sub, -9) eq '::DESTROY' or not defined wantarray) {
    &amp;$DB::sub;
    $DB::single |= pop(@stack);
    $DB::ret = undef;
  }
  elsif (wantarray) {
    @DB::ret = &amp;$DB::sub;
    $DB::single |= pop(@stack);
    @DB::ret;
  }
  else {
    $DB::ret = &amp;$DB::sub;
    $DB::single |= pop(@stack);
    $DB::ret;
  }
}

####
# this is called by perl for every statement
#
sub DB {
  return unless $ready;
  &amp;save;
  ($DB::package, $DB::filename, $DB::lineno) = caller;

  return if @skippkg and grep { $_ eq $DB::package } @skippkg;

  $usrctxt = &quot;package $DB::package;&quot;;		# this won't let them modify, alas
  local(*DB::dbline) = &quot;::_&lt;$DB::filename&quot;;

  my ($stop, $action);
  if (($stop,$action) = split(/\0/,$DB::dbline{$DB::lineno})) {
    if ($stop eq '1') {
      $DB::signal |= 1;
    }
    else {
      $stop = 0 unless $stop;			# avoid un_init warning
      $evalarg = &quot;\$DB::signal |= do { $stop; }&quot;; &amp;eval;
      $DB::dbline{$DB::lineno} =~ s/;9($|\0)/$1/;    # clear any temp breakpt
    }
  }
  if ($DB::single || $DB::trace || $DB::signal) {
    $DB::subname = ($DB::sub =~ /\'|::/) ? $DB::sub : &quot;${DB::package}::$DB::sub&quot;; #';
    DB-&gt;loadfile($DB::filename, $DB::lineno);
  }
  $evalarg = $action, &amp;eval if $action;
  if ($DB::single || $DB::signal) {
    _outputall($#stack . &quot; levels deep in subroutine calls.\n&quot;) if $DB::single &amp; 4;
    $DB::single = 0;
    $DB::signal = 0;
    $running = 0;
    
    &amp;eval if ($evalarg = DB-&gt;prestop);
    my $c;
    for $c (@clients) {
      # perform any client-specific prestop actions
      &amp;eval if ($evalarg = $c-&gt;cprestop);
      
      # Now sit in an event loop until something sets $running
      do {
	$c-&gt;idle;                     # call client event loop; must not block
	if ($running == 2) {          # client wants something eval-ed
	  &amp;eval if ($evalarg = $c-&gt;evalcode);
	  $running = 0;
	}
      } until $running;
      
      # perform any client-specific poststop actions
      &amp;eval if ($evalarg = $c-&gt;cpoststop);
    }
    &amp;eval if ($evalarg = DB-&gt;poststop);
  }
  ($@, $!, $,, $/, $\, $^W) = @saved;
  ();
}
  
####
# this takes its argument via $evalarg to preserve current @_
#    
sub eval {
  ($@, $!, $,, $/, $\, $^W) = @saved;
  eval &quot;$usrctxt $evalarg; &amp;DB::save&quot;;
  _outputall($@) if $@;
}

###############################################################################
#         no compile-time subroutine call allowed before this point           #
###############################################################################

use strict;                # this can run only after DB() and sub() are defined

sub save {
  @saved = ($@, $!, $,, $/, $\, $^W);
  $, = &quot;&quot;; $/ = &quot;\n&quot;; $\ = &quot;&quot;; $^W = 0;
}

sub catch {
  for (@clients) { $_-&gt;awaken; }
  $DB::signal = 1;
  $ready = 1;
}

####
#
# Client callable (read inheritable) methods defined after this point
#
####

sub register {
  my $s = shift;
  $s = _clientname($s) if ref($s);
  push @clients, $s;
}

sub done {
  my $s = shift;
  $s = _clientname($s) if ref($s);
  @clients = grep {$_ ne $s} @clients;
  $s-&gt;cleanup;
#  $running = 3 unless @clients;
  exit(0) unless @clients;
}

sub _clientname {
  my $name = shift;
  &quot;$name&quot; =~ /^(.+)=[A-Z]+\(.+\)$/;
  return $1;
}

sub next {
  my $s = shift;
  $DB::single = 2;
  $running = 1;
}

sub step {
  my $s = shift;
  $DB::single = 1;
  $running = 1;
}

sub cont {
  my $s = shift;
  my $i = shift;
  $s-&gt;set_tbreak($i) if $i;
  for ($i = 0; $i &lt;= $#stack;) {
	$stack[$i++] &amp;= ~1;
  }
  $DB::single = 0;
  $running = 1;
}

####
# XXX caller must experimentally determine $i (since it depends
# on how many client call frames are between this call and the DB call).
# Such is life.
#
sub ret {
  my $s = shift;
  my $i = shift;      # how many levels to get to DB sub
  $i = 0 unless defined $i;
  $stack[$#stack-$i] |= 1;
  $DB::single = 0;
  $running = 1;
}

####
# XXX caller must experimentally determine $start (since it depends
# on how many client call frames are between this call and the DB call).
# Such is life.
#
sub backtrace {
  my $self = shift;
  my $start = shift;
  my($p,$f,$l,$s,$h,$w,$e,$r,$a, @a, @ret,$i);
  $start = 1 unless $start;
  for ($i = $start; ($p,$f,$l,$s,$h,$w,$e,$r) = caller($i); $i++) {
    @a = @DB::args;
    for (@a) {
      s/'/\\'/g;
      s/([^\0]*)/'$1'/ unless /^-?[\d.]+$/;
      require 'meta_notation.pm';
      $_ = _meta_notation($_) if /[[:^print:]]/a;
    }
    $w = $w ? '@ = ' : '$ = ';
    $a = $h ? '(' . join(', ', @a) . ')' : '';
    $e =~ s/\n\s*\;\s*\Z// if $e;
    $e =~ s/[\\\']/\\$1/g if $e;
    if ($r) {
      $s = &quot;require '$e'&quot;;
    } elsif (defined $r) {
      $s = &quot;eval '$e'&quot;;
    } elsif ($s eq '(eval)') {
      $s = &quot;eval {...}&quot;;
    }
    $f = &quot;file '$f'&quot; unless $f eq '-e';
    push @ret, &quot;$w&amp;$s$a from $f line $l&quot;;
    last if $DB::signal;
  }
  return @ret;
}

sub _outputall {
  my $c;
  for $c (@clients) {
    $c-&gt;output(@_);
  }
}

sub trace_toggle {
  my $s = shift;
  $DB::trace = !$DB::trace;
}


####
# without args: returns all defined subroutine names
# with subname args: returns a listref [file, start, end]
#
sub subs {
  my $s = shift;
  if (@_) {
    my(@ret) = ();
    while (@_) {
      my $name = shift;
      push @ret, [$DB::sub{$name} =~ /^(.*)\:(\d+)-(\d+)$/] 
	if exists $DB::sub{$name};
    }
    return @ret;
  }
  return keys %DB::sub;
}

####
# first argument is a filename whose subs will be returned
# if a filename is not supplied, all subs in the current
# filename are returned.
#
sub filesubs {
  my $s = shift;
  my $fname = shift;
  $fname = $DB::filename unless $fname;
  return grep { $DB::sub{$_} =~ /^$fname/ } keys %DB::sub;
}

####
# returns a list of all filenames that DB knows about
#
sub files {
  my $s = shift;
  my(@f) = grep(m|^_&lt;|, keys %main::);
  return map { substr($_,2) } @f;
}

####
# returns reference to an array holding the lines in currently
# loaded file
#
sub lines {
  my $s = shift;
  return \@DB::dbline;
}

####
# loadfile($file, $line)
#
sub loadfile {
  my $s = shift;
  my($file, $line) = @_;
  if (!defined $main::{'_&lt;' . $file}) {
    my $try;
    if (($try) = grep(m|^_&lt;.*$file|, keys %main::)) {  
      $file = substr($try,2);
    }
  }
  if (defined($main::{'_&lt;' . $file})) {
    my $c;
#    _outputall(&quot;Loading file $file..&quot;);
    *DB::dbline = &quot;::_&lt;$file&quot;;
    $DB::filename = $file;
    for $c (@clients) {
#      print &quot;2 &quot;, $file, '|', $line, &quot;\n&quot;;
      $c-&gt;showfile($file, $line);
    }
    return $file;
  }
  return undef;
}

sub lineevents {
  my $s = shift;
  my $fname = shift;
  my(%ret) = ();
  my $i;
  $fname = $DB::filename unless $fname;
  local(*DB::dbline) = &quot;::_&lt;$fname&quot;;
  for ($i = 1; $i &lt;= $#DB::dbline; $i++) {
    $ret{$i} = [$DB::dbline[$i], split(/\0/, $DB::dbline{$i})] 
      if defined $DB::dbline{$i};
  }
  return %ret;
}

sub set_break {
  my $s = shift;
  my $i = shift;
  my $cond = shift;
  $i ||= $DB::lineno;
  $cond ||= '1';
  $i = _find_subline($i) if ($i =~ /\D/);
  $s-&gt;output(&quot;Subroutine not found.\n&quot;) unless $i;
  if ($i) {
    if ($DB::dbline[$i] == 0) {
      $s-&gt;output(&quot;Line $i not breakable.\n&quot;);
    }
    else {
      $DB::dbline{$i} =~ s/^[^\0]*/$cond/;
    }
  }
}

sub set_tbreak {
  my $s = shift;
  my $i = shift;
  $i = _find_subline($i) if ($i =~ /\D/);
  $s-&gt;output(&quot;Subroutine not found.\n&quot;) unless $i;
  if ($i) {
    if ($DB::dbline[$i] == 0) {
      $s-&gt;output(&quot;Line $i not breakable.\n&quot;);
    }
    else {
      $DB::dbline{$i} =~ s/($|\0)/;9$1/; # add one-time-only b.p.
    }
  }
}

sub _find_subline {
  my $name = shift;
  $name =~ s/\'/::/;
  $name = &quot;${DB::package}\:\:&quot; . $name if $name !~ /::/;
  $name = &quot;main&quot; . $name if substr($name,0,2) eq &quot;::&quot;;
  my($fname, $from, $to) = ($DB::sub{$name} =~ /^(.*):(\d+)-(\d+)$/);
  if ($from) {
    local *DB::dbline = &quot;::_&lt;$fname&quot;;
    ++$from while $DB::dbline[$from] == 0 &amp;&amp; $from &lt; $to;
    return $from;
  }
  return undef;
}

sub clr_breaks {
  my $s = shift;
  my $i;
  if (@_) {
    while (@_) {
      $i = shift;
      $i = _find_subline($i) if ($i =~ /\D/);
      $s-&gt;output(&quot;Subroutine not found.\n&quot;) unless $i;
      if (defined $DB::dbline{$i}) {
        $DB::dbline{$i} =~ s/^[^\0]+//;
        if ($DB::dbline{$i} =~ s/^\0?$//) {
          delete $DB::dbline{$i};
        }
      }
    }
  }
  else {
    for ($i = 1; $i &lt;= $#DB::dbline ; $i++) {
      if (defined $DB::dbline{$i}) {
        $DB::dbline{$i} =~ s/^[^\0]+//;
        if ($DB::dbline{$i} =~ s/^\0?$//) {
          delete $DB::dbline{$i};
        }
      }
    }
  }
}

sub set_action {
  my $s = shift;
  my $i = shift;
  my $act = shift;
  $i = _find_subline($i) if ($i =~ /\D/);
  $s-&gt;output(&quot;Subroutine not found.\n&quot;) unless $i;
  if ($i) {
    if ($DB::dbline[$i] == 0) {
      $s-&gt;output(&quot;Line $i not actionable.\n&quot;);
    }
    else {
      $DB::dbline{$i} =~ s/\0[^\0]*//;
      $DB::dbline{$i} .= &quot;\0&quot; . $act;
    }
  }
}

sub clr_actions {
  my $s = shift;
  my $i;
  if (@_) {
    while (@_) {
      my $i = shift;
      $i = _find_subline($i) if ($i =~ /\D/);
      $s-&gt;output(&quot;Subroutine not found.\n&quot;) unless $i;
      if ($i &amp;&amp; $DB::dbline[$i] != 0) {
	$DB::dbline{$i} =~ s/\0[^\0]*//;
	delete $DB::dbline{$i} if $DB::dbline{$i} =~ s/^\0?$//;
      }
    }
  }
  else {
    for ($i = 1; $i &lt;= $#DB::dbline ; $i++) {
      if (defined $DB::dbline{$i}) {
	$DB::dbline{$i} =~ s/\0[^\0]*//;
	delete $DB::dbline{$i} if $DB::dbline{$i} =~ s/^\0?$//;
      }
    }
  }
}

sub prestop {
  my ($client, $val) = @_;
  return defined($val) ? $preeval-&gt;{$client} = $val : $preeval-&gt;{$client};
}

sub poststop {
  my ($client, $val) = @_;
  return defined($val) ? $posteval-&gt;{$client} = $val : $posteval-&gt;{$client};
}

#
# &quot;pure virtual&quot; methods
#

# client-specific pre/post-stop actions.
sub cprestop {}
sub cpoststop {}

# client complete startup
sub awaken {}

sub skippkg {
  my $s = shift;
  push @skippkg, @_ if @_;
}

sub evalcode {
  my ($client, $val) = @_;
  if (defined $val) {
    $running = 2;    # hand over to DB() to evaluate in its context
    $ineval-&gt;{$client} = $val;
  }
  return $ineval-&gt;{$client};
}

sub ready {
  my $s = shift;
  return $ready = 1;
}

# stubs
    
sub init {}
sub stop {}
sub idle {}
sub cleanup {}
sub output {}

#
# client init
#
for (@clients) { $_-&gt;init }

$SIG{'INT'} = \&amp;DB::catch;

# disable this if stepping through END blocks is desired
# (looks scary and deconstructivist with Swat)
END { $ready = 0 }

1;
__END__

=head1 NAME

DB - programmatic interface to the Perl debugging API

=head1 SYNOPSIS

    package CLIENT;
    use DB;
    @ISA = qw(DB);

    # these (inherited) methods can be called by the client

    CLIENT-&gt;register()      # register a client package name
    CLIENT-&gt;done()          # de-register from the debugging API
    CLIENT-&gt;skippkg('hide::hide')  # ask DB not to stop in this package
    CLIENT-&gt;cont([WHERE])       # run some more (until BREAK or 
                                # another breakpointt)
    CLIENT-&gt;step()              # single step
    CLIENT-&gt;next()              # step over
    CLIENT-&gt;ret()               # return from current subroutine
    CLIENT-&gt;backtrace()         # return the call stack description
    CLIENT-&gt;ready()             # call when client setup is done
    CLIENT-&gt;trace_toggle()      # toggle subroutine call trace mode
    CLIENT-&gt;subs([SUBS])        # return subroutine information
    CLIENT-&gt;files()             # return list of all files known to DB
    CLIENT-&gt;lines()             # return lines in currently loaded file
    CLIENT-&gt;loadfile(FILE,LINE) # load a file and let other clients know
    CLIENT-&gt;lineevents()        # return info on lines with actions
    CLIENT-&gt;set_break([WHERE],[COND])
    CLIENT-&gt;set_tbreak([WHERE])
    CLIENT-&gt;clr_breaks([LIST])
    CLIENT-&gt;set_action(WHERE,ACTION)
    CLIENT-&gt;clr_actions([LIST])
    CLIENT-&gt;evalcode(STRING)  # eval STRING in executing code's context
    CLIENT-&gt;prestop([STRING]) # execute in code context before stopping
    CLIENT-&gt;poststop([STRING])# execute in code context before resuming

    # These methods will be called at the appropriate times.
    # Stub versions provided do nothing.
    # None of these can block.

    CLIENT-&gt;init()          # called when debug API inits itself
    CLIENT-&gt;stop(FILE,LINE) # when execution stops
    CLIENT-&gt;idle()          # while stopped (can be a client event loop)
    CLIENT-&gt;cleanup()       # just before exit
    CLIENT-&gt;output(LIST)    # called to print any output that
                            # the API must show

=head1 DESCRIPTION

Perl debug information is frequently required not just by debuggers,
but also by modules that need some &quot;special&quot; information to do their
job properly, like profilers.

This module abstracts and provides all of the hooks into Perl internal
debugging functionality, so that various implementations of Perl debuggers
(or packages that want to simply get at the &quot;privileged&quot; debugging data)
can all benefit from the development of this common code.  Currently used
by Swat, the perl/Tk GUI debugger.

Note that multiple &quot;front-ends&quot; can latch into this debugging API
simultaneously.  This is intended to facilitate things like
debugging with a command line and GUI at the same time, debugging 
debuggers etc.  [Sounds nice, but this needs some serious support -- GSAR]

In particular, this API does B&lt;not&gt; provide the following functions:

=over 4

=item *

data display

=item *

command processing

=item *

command alias management

=item *

user interface (tty or graphical)

=back

These are intended to be services performed by the clients of this API.

This module attempts to be squeaky clean w.r.t C&lt;use strict;&gt; and when
warnings are enabled.


=head2 Global Variables

The following &quot;public&quot; global names can be read by clients of this API.
Beware that these should be considered &quot;readonly&quot;.

=over 8

=item  $DB::sub

Name of current executing subroutine.

=item  %DB::sub

The keys of this hash are the names of all the known subroutines.  Each value
is an encoded string that has the sprintf(3) format 
C&lt;(&quot;%s:%d-%d&quot;, filename, fromline, toline)&gt;.

=item  $DB::single

Single-step flag.  Will be true if the API will stop at the next statement.

=item  $DB::signal

Signal flag. Will be set to a true value if a signal was caught.  Clients may
check for this flag to abort time-consuming operations.

=item  $DB::trace

This flag is set to true if the API is tracing through subroutine calls.

=item  @DB::args

Contains the arguments of current subroutine, or the C&lt;@ARGV&gt; array if in the 
toplevel context.

=item  @DB::dbline

List of lines in currently loaded file.

=item  %DB::dbline

Actions in current file (keys are line numbers).  The values are strings that
have the sprintf(3) format C&lt;(&quot;%s\000%s&quot;, breakcondition, actioncode)&gt;. 

=item  $DB::package

Package namespace of currently executing code.

=item  $DB::filename

Currently loaded filename.

=item  $DB::subname

Fully qualified name of currently executing subroutine.

=item  $DB::lineno

Line number that will be executed next.

=back

=head2 API Methods

The following are methods in the DB base class.  A client must
access these methods by inheritance (*not* by calling them directly),
since the API keeps track of clients through the inheritance
mechanism.

=over 8

=item CLIENT-&gt;register()

register a client object/package

=item CLIENT-&gt;evalcode(STRING)

eval STRING in executing code context

=item CLIENT-&gt;skippkg('D::hide')

ask DB not to stop in these packages

=item CLIENT-&gt;run()

run some more (until a breakpt is reached)

=item CLIENT-&gt;step()

single step

=item CLIENT-&gt;next()

step over

=item CLIENT-&gt;done()

de-register from the debugging API

=back

=head2 Client Callback Methods

The following &quot;virtual&quot; methods can be defined by the client.  They will
be called by the API at appropriate points.  Note that unless specified
otherwise, the debug API only defines empty, non-functional default versions
of these methods.

=over 8

=item CLIENT-&gt;init()

Called after debug API inits itself.

=item CLIENT-&gt;prestop([STRING])

Usually inherited from DB package.  If no arguments are passed,
returns the prestop action string.

=item CLIENT-&gt;stop()

Called when execution stops (w/ args file, line).

=item CLIENT-&gt;idle()

Called while stopped (can be a client event loop).

=item CLIENT-&gt;poststop([STRING])

Usually inherited from DB package.  If no arguments are passed,
returns the poststop action string.

=item CLIENT-&gt;evalcode(STRING)

Usually inherited from DB package.  Ask for a STRING to be C&lt;eval&gt;-ed
in executing code context.

=item CLIENT-&gt;cleanup()

Called just before exit.

=item CLIENT-&gt;output(LIST)

Called when API must show a message (warnings, errors etc.).


=back


=head1 BUGS

The interface defined by this module is missing some of the later additions
to perl's debugging functionality.  As such, this interface should be considered
highly experimental and subject to change.

=head1 AUTHOR

Gurusamy Sarathy	gsar@activestate.com

This code heavily adapted from an early version of perl5db.pl attributable
to Larry Wall and the Perl Porters.

=cut
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Fshare%2Fperl5' class='btn'>Cancel</a>
        </form>