<h2>Editing: getopt.awk</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'># getopt.awk --- Do C library getopt(3) function in awk
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
#
# Initial version: March, 1991
# Revised: May, 1993

# External variables:
#    Optind -- index in ARGV of first nonoption argument
#    Optarg -- string value of argument to current option
#    Opterr -- if nonzero, print our own diagnostic
#    Optopt -- current option letter

# Returns:
#    -1     at end of options
#    &quot;?&quot;    for unrecognized option
#    &lt;c&gt;    a character representing the current option

# Private Data:
#    _opti  -- index in multiflag option, e.g., -abc
function getopt(argc, argv, options,    thisopt, i)
{
    if (length(options) == 0)    # no options given
        return -1

    if (argv[Optind] == &quot;--&quot;) {  # all done
        Optind++
        _opti = 0
        return -1
    } else if (argv[Optind] !~ /^-[^:[:space:]]/) {
        _opti = 0
        return -1
    }
    if (_opti == 0)
        _opti = 2
    thisopt = substr(argv[Optind], _opti, 1)
    Optopt = thisopt
    i = index(options, thisopt)
    if (i == 0) {
        if (Opterr)
            printf(&quot;%c -- invalid option\n&quot;, thisopt) &gt; &quot;/dev/stderr&quot;
        if (_opti &gt;= length(argv[Optind])) {
            Optind++
            _opti = 0
        } else
            _opti++
        return &quot;?&quot;
    }
    if (substr(options, i + 1, 1) == &quot;:&quot;) {
        # get option argument
        if (length(substr(argv[Optind], _opti + 1)) &gt; 0)
            Optarg = substr(argv[Optind], _opti + 1)
        else
            Optarg = argv[++Optind]
        _opti = 0
    } else
        Optarg = &quot;&quot;
    if (_opti == 0 || _opti &gt;= length(argv[Optind])) {
        Optind++
        _opti = 0
    } else
        _opti++
    return thisopt
}
BEGIN {
    Opterr = 1    # default is to diagnose
    Optind = 1    # skip ARGV[0]

    # test program
    if (_getopt_test) {
        while ((_go_c = getopt(ARGC, ARGV, &quot;ab:cd&quot;)) != -1)
            printf(&quot;c = &lt;%c&gt;, Optarg = &lt;%s&gt;\n&quot;,
                                       _go_c, Optarg)
        printf(&quot;non-option arguments:\n&quot;)
        for (; Optind &lt; ARGC; Optind++)
            printf(&quot;\tARGV[%d] = &lt;%s&gt;\n&quot;,
                                    Optind, ARGV[Optind])
    }
}
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Fshare%2Fawk' class='btn'>Cancel</a>
        </form>