<h2>Editing: Wrap.pm</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'># Copyright (C) 2003-2018 Free Software Foundation, Inc.

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2, or (at your option)
# any later version.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program.  If not, see &lt;https://www.gnu.org/licenses/&gt;.

package Automake::Wrap;

use 5.006;
use strict;

require Exporter;
use vars '@ISA', '@EXPORT_OK';
@ISA = qw/Exporter/;
@EXPORT_OK = qw/wrap makefile_wrap/;

=head1 NAME

Automake::Wrap - a paragraph formatter

=head1 SYNOPSIS

  use Automake::Wrap 'wrap', 'makefile_wrap';

  print wrap ($first_ident, $next_ident, $end_of_line, $max_length,
              @values);

  print makefile_wrap (&quot;VARIABLE = &quot;, &quot;    &quot;, @values);

=head1 DESCRIPTION

This modules provide facility to format list of strings.  It is
comparable to Perl's L&lt;Text::Wrap&gt;, however we can't use L&lt;Text::Wrap&gt;
because some versions will abort when some word to print exceeds the
maximum length allowed.  (Ticket #17141, fixed in Perl 5.8.0.)

=head2 Functions

=over 4

=cut

# _tab_length ($TXT)
# ------------------
# Compute the length of TXT, counting tab characters as 8 characters.
sub _tab_length($)
{
  my ($txt) = @_;
  my $len = length ($txt);
  $len += 7 * ($txt =~ tr/\t/\t/);
  return $len;
}

=item C&lt;wrap ($head, $fill, $eol, $max_len, @values)&gt;

Format C&lt;@values&gt; as a block of text that starts with C&lt;$head&gt;,
followed by the strings in C&lt;@values&gt; separated by spaces or by
C&lt;&quot;$eol\n$fill&quot;&gt; so that the length of each line never exceeds
C&lt;$max_len&gt;.

The C&lt;$max_len&gt; constraint is ignored for C&lt;@values&gt; items which
are too big to fit alone one a line.

The constructed paragraph is C&lt;&quot;\n&quot;&gt;-terminated.

=cut

sub wrap($$$$@)
{
  my ($head, $fill, $eol, $max_len, @values) = @_;

  my $result = $head;
  my $column = _tab_length ($head);

  my $fill_len = _tab_length ($fill);
  my $eol_len = _tab_length ($eol);

  my $not_first_word = 0;

  foreach (@values)
    {
      my $len = _tab_length ($_);

      # See if the new variable fits on this line.
      # (The + 1 is for the space we add in front of the value.).
      if ($column + $len + $eol_len + 1 &gt; $max_len
	  # Do not break before the first word if it does not fit on
	  # the next line anyway.
	  &amp;&amp; ($not_first_word || $fill_len + $len + $eol_len + 1 &lt;= $max_len))
	{
	  # Start a new line.
	  $result .= &quot;$eol\n&quot; . $fill;
	  $column = $fill_len;
	}
      elsif ($not_first_word)
	{
	  # Add a space only if result does not already end
	  # with a space.
	  $_ = &quot; $_&quot; if $result =~ /\S\z/;
	  ++$len;
	}
      $result .= $_;
      $column += $len;
      $not_first_word = 1;
    }

  $result .= &quot;\n&quot;;
  return $result;
}


=item C&lt;makefile_wrap ($head, $fill, @values)&gt;

Format C&lt;@values&gt; in a way which is suitable for F&lt;Makefile&gt;s.
This is comparable to C&lt;wrap&gt;, except C&lt;$eol&gt; is known to
be C&lt;&quot; \\&quot;&gt;, and the maximum length has been hardcoded to C&lt;72&gt;.

A space is appended to C&lt;$head&gt; when this is not already
the case.

This can be used to format variable definitions or dependency lines.

  makefile_wrap ('VARIABLE =', &quot;\t&quot;, @values);
  makefile_wrap ('rule:', &quot;\t&quot;, @dependencies);

=cut

sub makefile_wrap ($$@)
{
  my ($head, $fill, @values) = @_;
  if (@values)
    {
      $head .= ' ' if $head =~ /\S\z/;
      return wrap $head, $fill, &quot; \\&quot;, 72, @values;
    }
  return &quot;$head\n&quot;;
}


1;
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Fshare%2Fautomake-1.16%2FAutomake' class='btn'>Cancel</a>
        </form>