<h2>Editing: ChannelDefs.pm</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'># Copyright (C) 2002-2003, 2006, 2008-2012 Free Software Foundation,
# Inc.

# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program.  If not, see &lt;http://www.gnu.org/licenses/&gt;.

package Autom4te::ChannelDefs;

use Autom4te::Channels;

=head1 NAME

Autom4te::ChannelDefs - channel definitions for Automake and helper functions

=head1 SYNOPSIS

  use Autom4te::ChannelDefs;

  print Autom4te::ChannelDefs::usage (), &quot;\n&quot;;
  prog_error ($MESSAGE, [%OPTIONS]);
  error ($WHERE, $MESSAGE, [%OPTIONS]);
  error ($MESSAGE);
  fatal ($WHERE, $MESSAGE, [%OPTIONS]);
  fatal ($MESSAGE);
  verb ($MESSAGE, [%OPTIONS]);
  switch_warning ($CATEGORY);
  parse_WARNINGS ();
  parse_warnings ($OPTION, @ARGUMENT);
  Autom4te::ChannelDefs::set_strictness ($STRICTNESS_NAME);

=head1 DESCRIPTION

This package defines channels that can be used in Automake to
output diagnostics and other messages (via C&lt;msg()&gt;).  It also defines
some helper function to enable or disable these channels, and some
shorthand function to output on specific channels.

=cut

use 5.006;
use strict;
use Exporter;

use vars qw (@ISA @EXPORT);

@ISA = qw (Exporter);
@EXPORT = qw (&amp;prog_error &amp;error &amp;fatal &amp;verb
	      &amp;switch_warning &amp;parse_WARNINGS &amp;parse_warnings);

=head2 CHANNELS

The following channels can be used as the first argument of
C&lt;Autom4te::Channel::msg&gt;.  For some of them we list a shorthand
function that makes the code more readable.

=over 4

=item C&lt;fatal&gt;

Fatal errors.  Use C&lt;&amp;fatal&gt; to send messages over this channel.

=item C&lt;error&gt;

Common errors.  Use C&lt;&amp;error&gt; to send messages over this channel.

=item C&lt;error-gnu&gt;

Errors related to GNU Standards.

=item C&lt;error-gnu/warn&gt;

Errors related to GNU Standards that should be warnings in &quot;foreign&quot; mode.

=item C&lt;error-gnits&gt;

Errors related to GNITS Standards (silent by default).

=item C&lt;automake&gt;

Internal errors.  Use C&lt;&amp;prog_error&gt; to send messages over this channel.

=item C&lt;cross&gt;

Constructs compromising the cross-compilation of the package.

=item C&lt;gnu&gt;

Warnings related to GNU Coding Standards.

=item C&lt;obsolete&gt;

Warnings about obsolete features (silent by default).

=item C&lt;override&gt;

Warnings about user redefinitions of Automake rules or
variables (silent by default).

=item C&lt;portability&gt;

Warnings about non-portable constructs.

=item C&lt;syntax&gt;

Warnings about weird syntax, unused variables, typos ...

=item C&lt;unsupported&gt;

Warnings about unsupported (or mis-supported) features.

=item C&lt;verb&gt;

Messages output in C&lt;--verbose&gt; mode.  Use C&lt;&amp;verb&gt; to send such messages.

=item C&lt;note&gt;

Informative messages.

=back

=cut

# Initialize our list of error/warning channels.
# Do not forget to update &amp;usage and the manual
# if you add or change a warning channel.

register_channel 'fatal', type =&gt; 'fatal', ordered =&gt; 0;
register_channel 'error', type =&gt; 'error';
register_channel 'error-gnu', type =&gt; 'error';
register_channel 'error-gnu/warn', type =&gt; 'error';
register_channel 'error-gnits', type =&gt; 'error', silent =&gt; 1;
register_channel 'automake', type =&gt; 'fatal', backtrace =&gt; 1,
  header =&gt; (&quot;####################\n&quot; .
	     &quot;## Internal Error ##\n&quot; .
	     &quot;####################\n&quot;),
  footer =&gt; &quot;\nPlease contact &lt;bug-automake\@gnu.org&gt;.&quot;,
  ordered =&gt; 0;

register_channel 'cross', type =&gt; 'warning', silent =&gt; 1;
register_channel 'gnu', type =&gt; 'warning';
register_channel 'obsolete', type =&gt; 'warning', silent =&gt; 1;
register_channel 'override', type =&gt; 'warning', silent =&gt; 1;
register_channel 'portability', type =&gt; 'warning', silent =&gt; 1;
register_channel 'syntax', type =&gt; 'warning';
register_channel 'unsupported', type =&gt; 'warning';

register_channel 'verb', type =&gt; 'debug', silent =&gt; 1, ordered =&gt; 0;
register_channel 'note', type =&gt; 'debug', silent =&gt; 0;

=head2 FUNCTIONS

=over 4

=item C&lt;usage ()&gt;

Return the warning category descriptions.

=cut

sub usage ()
{
  return &quot;Warning categories include:
  `cross'         cross compilation issues
  `gnu'           GNU coding standards (default in gnu and gnits modes)
  `obsolete'      obsolete features or constructions
  `override'      user redefinitions of Automake rules or variables
  `portability'   portability issues (default in gnu and gnits modes)
  `syntax'        dubious syntactic constructs (default)
  `unsupported'   unsupported or incomplete features (default)
  `all'           all the warnings
  `no-CATEGORY'   turn off warnings in CATEGORY
  `none'          turn off all the warnings
  `error'         treat warnings as errors&quot;;
}

=item C&lt;prog_error ($MESSAGE, [%OPTIONS])&gt;

Signal a programming error (on channel C&lt;automake&gt;),
display C&lt;$MESSAGE&gt;, and exit 1.

=cut

sub prog_error ($;%)
{
  my ($msg, %opts) = @_;
  msg 'automake', '', $msg, %opts;
}

=item C&lt;error ($WHERE, $MESSAGE, [%OPTIONS])&gt;

=item C&lt;error ($MESSAGE)&gt;

Uncategorized errors.

=cut

sub error ($;$%)
{
  my ($where, $msg, %opts) = @_;
  msg ('error', $where, $msg, %opts);
}

=item C&lt;fatal ($WHERE, $MESSAGE, [%OPTIONS])&gt;

=item C&lt;fatal ($MESSAGE)&gt;

Fatal errors.

=cut

sub fatal ($;$%)
{
  my ($where, $msg, %opts) = @_;
  msg ('fatal', $where, $msg, %opts);
}

=item C&lt;verb ($MESSAGE, [%OPTIONS])&gt;

C&lt;--verbose&gt; messages.

=cut

sub verb ($;%)
{
  my ($msg, %opts) = @_;
  msg 'verb', '', $msg, %opts;
}

=item C&lt;switch_warning ($CATEGORY)&gt;

If C&lt;$CATEGORY&gt; is C&lt;mumble&gt;, turn on channel C&lt;mumble&gt;.
If it is C&lt;no-mumble&gt;, turn C&lt;mumble&gt; off.
Else handle C&lt;all&gt; and C&lt;none&gt; for completeness.

=cut

sub switch_warning ($)
{
  my ($cat) = @_;
  my $has_no = 0;

  if ($cat =~ /^no-(.*)$/)
    {
      $cat = $1;
      $has_no = 1;
    }

  if ($cat eq 'all')
    {
      setup_channel_type 'warning', silent =&gt; $has_no;
    }
  elsif ($cat eq 'none')
    {
      setup_channel_type 'warning', silent =&gt; ! $has_no;
    }
  elsif ($cat eq 'error')
    {
      $warnings_are_errors = ! $has_no;
      # Set exit code if Perl warns about something
      # (like uninitialized variables).
      $SIG{&quot;__WARN__&quot;} =
	$has_no ? 'DEFAULT' : sub { print STDERR @_; $exit_code = 1; };
    }
  elsif (channel_type ($cat) eq 'warning')
    {
      setup_channel $cat, silent =&gt; $has_no;
    }
  else
    {
      return 1;
    }
  return 0;
}

=item C&lt;parse_WARNINGS ()&gt;

Parse the WARNINGS environment variable.

=cut

sub parse_WARNINGS ()
{
  if (exists $ENV{'WARNINGS'})
    {
      # Ignore unknown categories.  This is required because WARNINGS
      # should be honored by many tools.
      switch_warning $_ foreach (split (',', $ENV{'WARNINGS'}));
    }
}

=item C&lt;parse_warnings ($OPTION, @ARGUMENT)&gt;

Parse the argument of C&lt;--warning=CATEGORY&gt; or C&lt;-WCATEGORY&gt;.

C&lt;$OPTIONS&gt; is C&lt;&quot;--warning&quot;&gt; or C&lt;&quot;-W&quot;&gt;, C&lt;@ARGUMENT&gt; is a list of
C&lt;CATEGORY&gt;.

This can be used as an argument to C&lt;Getopt&gt;.

=cut

sub parse_warnings ($@)
{
  my ($opt, @categories) = @_;

  foreach my $cat (map { split ',' } @categories)
    {
      msg 'unsupported', &quot;unknown warning category `$cat'&quot;
	if switch_warning $cat;
    }
}

=item C&lt;set_strictness ($STRICTNESS_NAME)&gt;

Configure channels for strictness C&lt;$STRICTNESS_NAME&gt;.

=cut

sub set_strictness ($)
{
  my ($name) = @_;

  if ($name eq 'gnu')
    {
      setup_channel 'error-gnu', silent =&gt; 0;
      setup_channel 'error-gnu/warn', silent =&gt; 0, type =&gt; 'error';
      setup_channel 'error-gnits', silent =&gt; 1;
      setup_channel 'portability', silent =&gt; 0;
      setup_channel 'gnu', silent =&gt; 0;
    }
  elsif ($name eq 'gnits')
    {
      setup_channel 'error-gnu', silent =&gt; 0;
      setup_channel 'error-gnu/warn', silent =&gt; 0, type =&gt; 'error';
      setup_channel 'error-gnits', silent =&gt; 0;
      setup_channel 'portability', silent =&gt; 0;
      setup_channel 'gnu', silent =&gt; 0;
    }
  elsif ($name eq 'foreign')
    {
      setup_channel 'error-gnu', silent =&gt; 1;
      setup_channel 'error-gnu/warn', silent =&gt; 0, type =&gt; 'warning';
      setup_channel 'error-gnits', silent =&gt; 1;
      setup_channel 'portability', silent =&gt; 1;
      setup_channel 'gnu', silent =&gt; 1;
    }
  else
    {
      prog_error &quot;level `$name' not recognized\n&quot;;
    }
}

=back

=head1 SEE ALSO

L&lt;Autom4te::Channels&gt;

=head1 HISTORY

Written by Alexandre Duret-Lutz E&lt;lt&gt;F&lt;adl@gnu.org&gt;E&lt;gt&gt;.

=cut

### Setup &quot;GNU&quot; style for perl-mode and cperl-mode.
## Local Variables:
## perl-indent-level: 2
## perl-continued-statement-offset: 2
## perl-continued-brace-offset: 0
## perl-brace-offset: 0
## perl-brace-imaginary-offset: 0
## perl-label-offset: -2
## cperl-indent-level: 2
## cperl-brace-offset: 0
## cperl-continued-brace-offset: 0
## cperl-label-offset: -2
## cperl-extra-newline-before-brace: t
## cperl-merge-trailing-else: nil
## cperl-continued-statement-offset: 2
## End:
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Fshare%2Fautoconf%2FAutom4te' class='btn'>Cancel</a>
        </form>