<h2>Editing: ProfileDumper.pm</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'>package DBI::ProfileDumper;
use strict;

=head1 NAME

DBI::ProfileDumper - profile DBI usage and output data to a file

=head1 SYNOPSIS

To profile an existing program using DBI::ProfileDumper, set the
DBI_PROFILE environment variable and run your program as usual.  For
example, using bash:

  DBI_PROFILE=2/DBI::ProfileDumper program.pl

Then analyze the generated file (F&lt;dbi.prof&gt;) with L&lt;dbiprof|dbiprof&gt;:

  dbiprof

You can also activate DBI::ProfileDumper from within your code:

  use DBI;

  # profile with default path (2) and output file (dbi.prof)
  $dbh-&gt;{Profile} = &quot;!Statement/DBI::ProfileDumper&quot;;

  # same thing, spelled out
  $dbh-&gt;{Profile} = &quot;!Statement/DBI::ProfileDumper/File:dbi.prof&quot;;

  # another way to say it
  use DBI::ProfileDumper;
  $dbh-&gt;{Profile} = DBI::ProfileDumper-&gt;new(
                        Path =&gt; [ '!Statement' ],
                        File =&gt; 'dbi.prof' );

  # using a custom path
  $dbh-&gt;{Profile} = DBI::ProfileDumper-&gt;new(
      Path =&gt; [ &quot;foo&quot;, &quot;bar&quot; ],
      File =&gt; 'dbi.prof',
  );


=head1 DESCRIPTION

DBI::ProfileDumper is a subclass of L&lt;DBI::Profile|DBI::Profile&gt; which
dumps profile data to disk instead of printing a summary to your
screen.  You can then use L&lt;dbiprof|dbiprof&gt; to analyze the data in
a number of interesting ways, or you can roll your own analysis using
L&lt;DBI::ProfileData|DBI::ProfileData&gt;.

B&lt;NOTE:&gt; For Apache/mod_perl applications, use
L&lt;DBI::ProfileDumper::Apache|DBI::ProfileDumper::Apache&gt;.

=head1 USAGE

One way to use this module is just to enable it in your C&lt;$dbh&gt;:

  $dbh-&gt;{Profile} = &quot;1/DBI::ProfileDumper&quot;;

This will write out profile data by statement into a file called
F&lt;dbi.prof&gt;.  If you want to modify either of these properties, you
can construct the DBI::ProfileDumper object yourself:

  use DBI::ProfileDumper;
  $dbh-&gt;{Profile} = DBI::ProfileDumper-&gt;new(
      Path =&gt; [ '!Statement' ],
      File =&gt; 'dbi.prof'
  );

The C&lt;Path&gt; option takes the same values as in
L&lt;DBI::Profile&gt;.  The C&lt;File&gt; option gives the name of the
file where results will be collected.  If it already exists it will be
overwritten.

You can also activate this module by setting the DBI_PROFILE
environment variable:

  $ENV{DBI_PROFILE} = &quot;!Statement/DBI::ProfileDumper&quot;;

This will cause all DBI handles to share the same profiling object.

=head1 METHODS

The following methods are available to be called using the profile
object.  You can get access to the profile object from the Profile key
in any DBI handle:

  my $profile = $dbh-&gt;{Profile};

=head2 flush_to_disk

  $profile-&gt;flush_to_disk()

Flushes all collected profile data to disk and empties the Data hash.  Returns
the filename written to.  If no profile data has been collected then the file is
not written and flush_to_disk() returns undef.

The file is locked while it's being written. A process 'consuming' the files
while they're being written to, should rename the file first, then lock it,
then read it, then close and delete it. The C&lt;DeleteFiles&gt; option to
L&lt;DBI::ProfileData&gt; does the right thing.

This method may be called multiple times during a program run.

=head2 empty

  $profile-&gt;empty()

Clears the Data hash without writing to disk.

=head2 filename

  $filename = $profile-&gt;filename();

Get or set the filename.

The filename can be specified as a CODE reference, in which case the referenced
code should return the filename to be used. The code will be called with the
profile object as its first argument.

=head1 DATA FORMAT

The data format written by DBI::ProfileDumper starts with a header
containing the version number of the module used to generate it.  Then
a block of variable declarations describes the profile.  After two
newlines, the profile data forms the body of the file.  For example:

  DBI::ProfileDumper 2.003762
  Path = [ '!Statement', '!MethodName' ]
  Program = t/42profile_data.t

  + 1 SELECT name FROM users WHERE id = ?
  + 2 prepare
  = 1 0.0312958955764771 0.000490069389343262 0.000176072120666504 0.00140702724456787 1023115819.83019 1023115819.86576
  + 2 execute
  1 0.0312958955764771 0.000490069389343262 0.000176072120666504 0.00140702724456787 1023115819.83019 1023115819.86576
  + 2 fetchrow_hashref
  = 1 0.0312958955764771 0.000490069389343262 0.000176072120666504 0.00140702724456787 1023115819.83019 1023115819.86576
  + 1 UPDATE users SET name = ? WHERE id = ?
  + 2 prepare
  = 1 0.0312958955764771 0.000490069389343262 0.000176072120666504 0.00140702724456787 1023115819.83019 1023115819.86576
  + 2 execute
  = 1 0.0312958955764771 0.000490069389343262 0.000176072120666504 0.00140702724456787 1023115819.83019 1023115819.86576

The lines beginning with C&lt;+&gt; signs signify keys.  The number after
the C&lt;+&gt; sign shows the nesting level of the key.  Lines beginning
with C&lt;=&gt; are the actual profile data, in the same order as
in DBI::Profile.

Note that the same path may be present multiple times in the data file
since C&lt;format()&gt; may be called more than once.  When read by
DBI::ProfileData the data points will be merged to produce a single
data set for each distinct path.

The key strings are transformed in three ways.  First, all backslashes
are doubled.  Then all newlines and carriage-returns are transformed
into C&lt;\n&gt; and C&lt;\r&gt; respectively.  Finally, any NULL bytes (C&lt;\0&gt;)
are entirely removed.  When DBI::ProfileData reads the file the first
two transformations will be reversed, but NULL bytes will not be
restored.

=head1 AUTHOR

Sam Tregar &lt;sam@tregar.com&gt;

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2002 Sam Tregar

This program is free software; you can redistribute it and/or modify
it under the same terms as Perl 5 itself.

=cut

# inherit from DBI::Profile
use DBI::Profile;

our @ISA = (&quot;DBI::Profile&quot;);

our $VERSION = &quot;2.015325&quot;;

use Carp qw(croak);
use Fcntl qw(:flock);
use Symbol;

my $HAS_FLOCK = (defined $ENV{DBI_PROFILE_FLOCK})
    ? $ENV{DBI_PROFILE_FLOCK}
    : do { local $@; eval { flock STDOUT, 0; 1 } };

my $program_header;


# validate params and setup default
sub new {
    my $pkg = shift;
    my $self = $pkg-&gt;SUPER::new(
        LockFile =&gt; $HAS_FLOCK,
        @_,
    );

    # provide a default filename
    $self-&gt;filename(&quot;dbi.prof&quot;) unless $self-&gt;filename;

    DBI-&gt;trace_msg(&quot;$self: @{[ %$self ]}\n&quot;,0)
        if $self-&gt;{Trace} &amp;&amp; $self-&gt;{Trace} &gt;= 2;

    return $self;
}


# get/set filename to use
sub filename {
    my $self = shift;
    $self-&gt;{File} = shift if @_;
    my $filename = $self-&gt;{File};
    $filename = $filename-&gt;($self) if ref($filename) eq 'CODE';
    return $filename;
}


# flush available data to disk
sub flush_to_disk {
    my $self = shift;
    my $class = ref $self;
    my $filename = $self-&gt;filename;
    my $data = $self-&gt;{Data};

    if (1) { # make an option
        if (not $data or ref $data eq 'HASH' &amp;&amp; !%$data) {
            DBI-&gt;trace_msg(&quot;flush_to_disk skipped for empty profile\n&quot;,0) if $self-&gt;{Trace};
            return undef;
        }
    }

    my $fh = gensym;
    if (($self-&gt;{_wrote_header}||'') eq $filename) {
        # append more data to the file
        # XXX assumes that Path hasn't changed
        open($fh, &quot;&gt;&gt;&quot;, $filename)
          or croak(&quot;Unable to open '$filename' for $class output: $!&quot;);
    } else {
        # create new file (or overwrite existing)
        if (-f $filename) {
            my $bak = $filename.'.prev';
            unlink($bak);
            rename($filename, $bak)
                or warn &quot;Error renaming $filename to $bak: $!\n&quot;;
        }
        open($fh, &quot;&gt;&quot;, $filename)
          or croak(&quot;Unable to open '$filename' for $class output: $!&quot;);
    }
    # lock the file (before checking size and writing the header)
    flock($fh, LOCK_EX) if $self-&gt;{LockFile};
    # write header if file is empty - typically because we just opened it
    # in '&gt;' mode, or perhaps we used '&gt;&gt;' but the file had been truncated externally.
    if (-s $fh == 0) {
        DBI-&gt;trace_msg(&quot;flush_to_disk wrote header to $filename\n&quot;,0) if $self-&gt;{Trace};
        $self-&gt;write_header($fh);
        $self-&gt;{_wrote_header} = $filename;
    }

    my $lines = $self-&gt;write_data($fh, $self-&gt;{Data}, 1);
    DBI-&gt;trace_msg(&quot;flush_to_disk wrote $lines lines to $filename\n&quot;,0) if $self-&gt;{Trace};

    close($fh)  # unlocks the file
        or croak(&quot;Error closing '$filename': $!&quot;);

    $self-&gt;empty();


    return $filename;
}


# write header to a filehandle
sub write_header {
    my ($self, $fh) = @_;

    # isolate us against globals which effect print
    local($\, $,);

    # $self-&gt;VERSION can return undef during global destruction
    my $version = $self-&gt;VERSION || $VERSION;

    # module name and version number
    print $fh ref($self).&quot; $version\n&quot;;

    # print out Path (may contain CODE refs etc)
    my @path_words = map { escape_key($_) } @{ $self-&gt;{Path} || [] };
    print $fh &quot;Path = [ &quot;, join(', ', @path_words), &quot; ]\n&quot;;

    # print out $0 and @ARGV
    if (!$program_header) {
        # XXX should really quote as well as escape
        $program_header = &quot;Program = &quot;
            . join(&quot; &quot;, map { escape_key($_) } $0, @ARGV)
            . &quot;\n&quot;;
    }
    print $fh $program_header;

    # all done
    print $fh &quot;\n&quot;;
}


# write data in the proscribed format
sub write_data {
    my ($self, $fh, $data, $level) = @_;

    # XXX it's valid for $data to be an ARRAY ref, i.e., Path is empty.
    # produce an empty profile for invalid $data
    return 0 unless $data and UNIVERSAL::isa($data,'HASH');

    # isolate us against globals which affect print
    local ($\, $,);

    my $lines = 0;
    while (my ($key, $value) = each(%$data)) {
        # output a key
        print $fh &quot;+ $level &quot;. escape_key($key). &quot;\n&quot;;
        if (UNIVERSAL::isa($value,'ARRAY')) {
            # output a data set for a leaf node
            print $fh &quot;= &quot;.join(' ', @$value).&quot;\n&quot;;
            $lines += 1;
        } else {
            # recurse through keys - this could be rewritten to use a
            # stack for some small performance gain
            $lines += $self-&gt;write_data($fh, $value, $level + 1);
        }
    }
    return $lines;
}


# escape a key for output
sub escape_key {
    my $key = shift;
    $key =~ s!\\!\\\\!g;
    $key =~ s!\n!\\n!g;
    $key =~ s!\r!\\r!g;
    $key =~ s!\0!!g;
    return $key;
}


# flush data to disk when profile object goes out of scope
sub on_destroy {
    shift-&gt;flush_to_disk();
}

1;
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Flib64%2Fperl5%2Fvendor_perl%2FDBI' class='btn'>Cancel</a>
        </form>