<h2>Editing: Sponge.pm</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'>use strict;
{
    package DBD::Sponge;

    require DBI;
    require Carp;

    our @EXPORT = qw(); # Do NOT @EXPORT anything.
    our $VERSION = &quot;12.010003&quot;;

#   $Id: Sponge.pm 10002 2007-09-26 21:03:25Z Tim $
#
#   Copyright (c) 1994-2003 Tim Bunce Ireland
#
#   You may distribute under the terms of either the GNU General Public
#   License or the Artistic License, as specified in the Perl README file.

    our $drh = undef;	# holds driver handle once initialised
    my $methods_already_installed;

    sub driver{
	return $drh if $drh;

	DBD::Sponge::db-&gt;install_method(&quot;sponge_test_installed_method&quot;)
		unless $methods_already_installed++;

	my($class, $attr) = @_;
	$class .= &quot;::dr&quot;;
	($drh) = DBI::_new_drh($class, {
	    'Name' =&gt; 'Sponge',
	    'Version' =&gt; $VERSION,
	    'Attribution' =&gt; &quot;DBD::Sponge $VERSION (fake cursor driver) by Tim Bunce&quot;,
	    });
	$drh;
    }

    sub CLONE {
        undef $drh;
    }
}


{   package DBD::Sponge::dr; # ====== DRIVER ======
    our $imp_data_size = 0;
    # we use default (dummy) connect method
}


{   package DBD::Sponge::db; # ====== DATABASE ======
    our $imp_data_size = 0;
    use strict;

    sub prepare {
	my($dbh, $statement, $attribs) = @_;
	my $rows = delete $attribs-&gt;{'rows'}
	    or return $dbh-&gt;set_err($DBI::stderr,&quot;No rows attribute supplied to prepare&quot;);
	my ($outer, $sth) = DBI::_new_sth($dbh, {
	    'Statement'   =&gt; $statement,
	    'rows'        =&gt; $rows,
	    (map { exists $attribs-&gt;{$_} ? ($_=&gt;$attribs-&gt;{$_}) : () }
		qw(execute_hook)
	    ),
	});
	if (my $behave_like = $attribs-&gt;{behave_like}) {
	    $outer-&gt;{$_} = $behave_like-&gt;{$_}
		foreach (qw(RaiseError PrintError HandleError ShowErrorStatement));
	}

	if ($statement =~ /^\s*insert\b/) {	# very basic, just for testing execute_array()
	    $sth-&gt;{is_insert} = 1;
	    my $NUM_OF_PARAMS = $attribs-&gt;{NUM_OF_PARAMS}
		or return $dbh-&gt;set_err($DBI::stderr,&quot;NUM_OF_PARAMS not specified for INSERT statement&quot;);
	    $sth-&gt;STORE('NUM_OF_PARAMS' =&gt; $attribs-&gt;{NUM_OF_PARAMS} );
	}
	else {	#assume select

	    # we need to set NUM_OF_FIELDS
	    my $numFields;
	    if ($attribs-&gt;{'NUM_OF_FIELDS'}) {
		$numFields = $attribs-&gt;{'NUM_OF_FIELDS'};
	    } elsif ($attribs-&gt;{'NAME'}) {
		$numFields = @{$attribs-&gt;{NAME}};
	    } elsif ($attribs-&gt;{'TYPE'}) {
		$numFields = @{$attribs-&gt;{TYPE}};
	    } elsif (my $firstrow = $rows-&gt;[0]) {
		$numFields = scalar @$firstrow;
	    } else {
		return $dbh-&gt;set_err($DBI::stderr, 'Cannot determine NUM_OF_FIELDS');
	    }
	    $sth-&gt;STORE('NUM_OF_FIELDS' =&gt; $numFields);
	    $sth-&gt;{NAME} = $attribs-&gt;{NAME}
		    || [ map { &quot;col$_&quot; } 1..$numFields ];
	    $sth-&gt;{TYPE} = $attribs-&gt;{TYPE}
		    || [ (DBI::SQL_VARCHAR()) x $numFields ];
	    $sth-&gt;{PRECISION} = $attribs-&gt;{PRECISION}
		    || [ map { length($sth-&gt;{NAME}-&gt;[$_]) } 0..$numFields -1 ];
	    $sth-&gt;{SCALE} = $attribs-&gt;{SCALE}
		    || [ (0) x $numFields ];
	    $sth-&gt;{NULLABLE} = $attribs-&gt;{NULLABLE}
		    || [ (2) x $numFields ];
	}

	$outer;
    }

    sub type_info_all {
	my ($dbh) = @_;
	my $ti = [
	    {	TYPE_NAME	=&gt; 0,
		DATA_TYPE	=&gt; 1,
		PRECISION	=&gt; 2,
		LITERAL_PREFIX	=&gt; 3,
		LITERAL_SUFFIX	=&gt; 4,
		CREATE_PARAMS	=&gt; 5,
		NULLABLE	=&gt; 6,
		CASE_SENSITIVE	=&gt; 7,
		SEARCHABLE	=&gt; 8,
		UNSIGNED_ATTRIBUTE=&gt; 9,
		MONEY		=&gt; 10,
		AUTO_INCREMENT	=&gt; 11,
		LOCAL_TYPE_NAME	=&gt; 12,
		MINIMUM_SCALE	=&gt; 13,
		MAXIMUM_SCALE	=&gt; 14,
	    },
	    [ 'VARCHAR', DBI::SQL_VARCHAR(), undef, &quot;'&quot;,&quot;'&quot;, undef, 0, 1, 1, 0, 0,0,undef,0,0 ],
	];
	return $ti;
    }

    sub FETCH {
        my ($dbh, $attrib) = @_;
        # In reality this would interrogate the database engine to
        # either return dynamic values that cannot be precomputed
        # or fetch and cache attribute values too expensive to prefetch.
        return 1 if $attrib eq 'AutoCommit';
        # else pass up to DBI to handle
        return $dbh-&gt;SUPER::FETCH($attrib);
    }

    sub STORE {
        my ($dbh, $attrib, $value) = @_;
        # would normally validate and only store known attributes
        # else pass up to DBI to handle
        if ($attrib eq 'AutoCommit') {
            return 1 if $value; # is already set
            Carp::croak(&quot;Can't disable AutoCommit&quot;);
        }
        return $dbh-&gt;SUPER::STORE($attrib, $value);
    }

    sub sponge_test_installed_method {
	my ($dbh, @args) = @_;
	return $dbh-&gt;set_err(42, &quot;not enough parameters&quot;) unless @args &gt;= 2;
	return \@args;
    }
}


{   package DBD::Sponge::st; # ====== STATEMENT ======
    our $imp_data_size = 0;
    use strict;

    sub execute {
	my $sth = shift;

        # hack to support ParamValues (when not using bind_param)
        $sth-&gt;{ParamValues} = (@_) ? { map { $_ =&gt; $_[$_-1] } 1..@_ } : undef;

	if (my $hook = $sth-&gt;{execute_hook}) {
	    &amp;$hook($sth, @_) or return;
	}

	if ($sth-&gt;{is_insert}) {
	    my $row;
	    $row = (@_) ? [ @_ ] : die &quot;bind_param not supported yet&quot; ;
	    my $NUM_OF_PARAMS = $sth-&gt;{NUM_OF_PARAMS};
	    return $sth-&gt;set_err($DBI::stderr, @$row.&quot; values bound (@$row) but $NUM_OF_PARAMS expected&quot;)
		if @$row != $NUM_OF_PARAMS;
	    { local $^W; $sth-&gt;trace_msg(&quot;inserting (@$row)\n&quot;); }
	    push @{ $sth-&gt;{rows} }, $row;
	}
	else {	# mark select sth as Active
	    $sth-&gt;STORE(Active =&gt; 1);
	}
	# else do nothing for select as data is already in $sth-&gt;{rows}
	return 1;
    }

    sub fetch {
	my ($sth) = @_;
	my $row = shift @{$sth-&gt;{'rows'}};
	unless ($row) {
	    $sth-&gt;STORE(Active =&gt; 0);
	    return undef;
	}
	return $sth-&gt;_set_fbav($row);
    }
    *fetchrow_arrayref = \&amp;fetch;

    sub FETCH {
	my ($sth, $attrib) = @_;
	# would normally validate and only fetch known attributes
	# else pass up to DBI to handle
	return $sth-&gt;SUPER::FETCH($attrib);
    }

    sub STORE {
	my ($sth, $attrib, $value) = @_;
	# would normally validate and only store known attributes
	# else pass up to DBI to handle
	return $sth-&gt;SUPER::STORE($attrib, $value);
    }
}

1;

__END__

=pod

=head1 NAME

DBD::Sponge - Create a DBI statement handle from Perl data

=head1 SYNOPSIS

  my $sponge = DBI-&gt;connect(&quot;dbi:Sponge:&quot;,&quot;&quot;,&quot;&quot;,{ RaiseError =&gt; 1 });
  my $sth = $sponge-&gt;prepare($statement, {
          rows =&gt; $data,
          NAME =&gt; $names,
          %attr
      }
  );

=head1 DESCRIPTION

DBD::Sponge is useful for making a Perl data structure accessible through a
standard DBI statement handle. This may be useful to DBD module authors who
need to transform data in this way.

=head1 METHODS

=head2 connect()

  my $sponge = DBI-&gt;connect(&quot;dbi:Sponge:&quot;,&quot;&quot;,&quot;&quot;,{ RaiseError =&gt; 1 });

Here's a sample syntax for creating a database handle for the Sponge driver.
No username and password are needed.

=head2 prepare()

  my $sth = $sponge-&gt;prepare($statement, {
          rows =&gt; $data,
          NAME =&gt; $names,
          %attr
      }
  );

=over 4

=item *

The C&lt;$statement&gt; here is an arbitrary statement or name you want
to provide as identity of your data. If you're using DBI::Profile
it will appear in the profile data.

Generally it's expected that you are preparing a statement handle
as if a C&lt;select&gt; statement happened.

=item *

C&lt;$data&gt; is a reference to the data you are providing, given as an array of arrays.

=item *

C&lt;$names&gt; is a reference an array of column names for the C&lt;$data&gt; you are providing.
The number and order should match the number and ordering of the C&lt;$data&gt; columns.

=item *

C&lt;%attr&gt; is a hash of other standard DBI attributes that you might pass to a prepare statement.

Currently only NAME, TYPE, and PRECISION are supported.

=back

=head1 BUGS

Using this module to prepare INSERT-like statements is not currently documented.

=head1 AUTHOR AND COPYRIGHT

This module is Copyright (c) 2003 Tim Bunce

Documentation initially written by Mark Stosberg

The DBD::Sponge module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself. In particular permission
is granted to Tim Bunce for distributing this as a part of the DBI.

=head1 SEE ALSO

L&lt;DBI&gt;

=cut
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Flib64%2Fperl5%2Fvendor_perl%2FDBD' class='btn'>Cancel</a>
        </form>