<h2>Editing: Gofer.pm</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'>{
    package DBD::Gofer;

    use strict;

    require DBI;
    require DBI::Gofer::Request;
    require DBI::Gofer::Response;
    require Carp;

    our $VERSION = &quot;0.015327&quot;;

#   $Id: Gofer.pm 15326 2012-06-06 16:32:38Z Tim $
#
#   Copyright (c) 2007, Tim Bunce, Ireland
#
#   You may distribute under the terms of either the GNU General Public
#   License or the Artistic License, as specified in the Perl README file.


    # attributes we'll allow local STORE
    our %xxh_local_store_attrib = map { $_=&gt;1 } qw(
        Active
        CachedKids
        Callbacks
        DbTypeSubclass
        ErrCount Executed
        FetchHashKeyName
        HandleError HandleSetErr
        InactiveDestroy
        AutoInactiveDestroy
        PrintError PrintWarn
        Profile
        RaiseError
        RootClass
        ShowErrorStatement
        Taint TaintIn TaintOut
        TraceLevel
        Warn
        dbi_quote_identifier_cache
        dbi_connect_closure
        dbi_go_execute_unique
    );
    our %xxh_local_store_attrib_if_same_value = map { $_=&gt;1 } qw(
        Username
        dbi_connect_method
    );

    our $drh = undef;    # holds driver handle once initialized
    our $methods_already_installed;

    sub driver{
        return $drh if $drh;

        DBI-&gt;setup_driver('DBD::Gofer');

        unless ($methods_already_installed++) {
            my $opts = { O=&gt; 0x0004 }; # IMA_KEEP_ERR
            DBD::Gofer::db-&gt;install_method('go_dbh_method', $opts);
            DBD::Gofer::st-&gt;install_method('go_sth_method', $opts);
            DBD::Gofer::st-&gt;install_method('go_clone_sth',  $opts);
            DBD::Gofer::db-&gt;install_method('go_cache',      $opts);
            DBD::Gofer::st-&gt;install_method('go_cache',      $opts);
        }

        my($class, $attr) = @_;
        $class .= &quot;::dr&quot;;
        ($drh) = DBI::_new_drh($class, {
            'Name' =&gt; 'Gofer',
            'Version' =&gt; $VERSION,
            'Attribution' =&gt; 'DBD Gofer by Tim Bunce',
        });

        $drh;
    }


    sub CLONE {
        undef $drh;
    }


    sub go_cache {
        my $h = shift;
        $h-&gt;{go_cache} = shift if @_;
        # return handle's override go_cache, if it has one
        return $h-&gt;{go_cache} if defined $h-&gt;{go_cache};
        # or else the transports default go_cache
        return $h-&gt;{go_transport}-&gt;{go_cache};
    }


    sub set_err_from_response { # set error/warn/info and propagate warnings
        my $h = shift;
        my $response = shift;
        if (my $warnings = $response-&gt;warnings) {
            warn $_ for @$warnings;
        }
        my ($err, $errstr, $state) = $response-&gt;err_errstr_state;
        # Only set_err() if there's an error else leave the current values
        # (The current values will normally be set undef by the DBI dispatcher
        # except for methods marked KEEPERR such as ping.)
        $h-&gt;set_err($err, $errstr, $state) if defined $err;
        return undef;
    }


    sub install_methods_proxy {
        my ($installed_methods) = @_;
        while ( my ($full_method, $attr) = each %$installed_methods ) {
            # need to install both a DBI dispatch stub and a proxy stub
            # (the dispatch stub may be already here due to local driver use)

            DBI-&gt;_install_method($full_method, &quot;&quot;, $attr||{})
                unless defined &amp;{$full_method};

            # now install proxy stubs on the driver side
            $full_method =~ m/^DBI::(\w\w)::(\w+)$/
                or die &quot;Invalid method name '$full_method' for install_method&quot;;
            my ($type, $method) = ($1, $2);
            my $driver_method = &quot;DBD::Gofer::${type}::${method}&quot;;
            next if defined &amp;{$driver_method};
            my $sub;
            if ($type eq 'db') {
                $sub = sub { return shift-&gt;go_dbh_method(undef, $method, @_) };
            }
            else {
                $sub = sub { shift-&gt;set_err($DBI::stderr, &quot;Can't call \$${type}h-&gt;$method when using DBD::Gofer&quot;); return; };
            }
            no strict 'refs';
            *$driver_method = $sub;
        }
    }
}


{   package DBD::Gofer::dr; # ====== DRIVER ======

    $imp_data_size = 0;
    use strict;

    sub connect_cached {
        my ($drh, $dsn, $user, $auth, $attr)= @_;
        $attr ||= {};
        return $drh-&gt;SUPER::connect_cached($dsn, $user, $auth, {
            (%$attr),
            go_connect_method =&gt; $attr-&gt;{go_connect_method} || 'connect_cached',
        });
    }


    sub connect {
        my($drh, $dsn, $user, $auth, $attr)= @_;
        my $orig_dsn = $dsn;

        # first remove dsn= and everything after it
        my $remote_dsn = ($dsn =~ s/;?\bdsn=(.*)$// &amp;&amp; $1)
            or return $drh-&gt;set_err($DBI::stderr, &quot;No dsn= argument in '$orig_dsn'&quot;);

        if ($attr-&gt;{go_bypass}) { # don't use DBD::Gofer for this connection
            # useful for testing with DBI_AUTOPROXY, e.g., t/03handle.t
            return DBI-&gt;connect($remote_dsn, $user, $auth, $attr);
        }

        my %go_attr;
        # extract any go_ attributes from the connect() attr arg
        for my $k (grep { /^go_/ } keys %$attr) {
            $go_attr{$k} = delete $attr-&gt;{$k};
        }
        # then override those with any attributes embedded in our dsn (not remote_dsn)
        for my $kv (grep /=/, split /;/, $dsn, -1) {
            my ($k, $v) = split /=/, $kv, 2;
            $go_attr{ &quot;go_$k&quot; } = $v;
        }

        if (not ref $go_attr{go_policy}) { # if not a policy object already
            my $policy_class = $go_attr{go_policy} || 'classic';
            $policy_class = &quot;DBD::Gofer::Policy::$policy_class&quot;
                unless $policy_class =~ /::/;
            _load_class($policy_class)
                or return $drh-&gt;set_err($DBI::stderr, &quot;Can't load $policy_class: $@&quot;);
            # replace policy name in %go_attr with policy object
            $go_attr{go_policy} = eval { $policy_class-&gt;new(\%go_attr) }
                or return $drh-&gt;set_err($DBI::stderr, &quot;Can't instanciate $policy_class: $@&quot;);
        }
        # policy object is left in $go_attr{go_policy} so transport can see it
        my $go_policy = $go_attr{go_policy};

        if ($go_attr{go_cache} and not ref $go_attr{go_cache}) { # if not a cache object already
            my $cache_class = $go_attr{go_cache};
            $cache_class = &quot;DBI::Util::CacheMemory&quot; if $cache_class eq '1';
            _load_class($cache_class)
                or return $drh-&gt;set_err($DBI::stderr, &quot;Can't load $cache_class $@&quot;);
            $go_attr{go_cache} = eval { $cache_class-&gt;new() }
                or $drh-&gt;set_err(0, &quot;Can't instanciate $cache_class: $@&quot;); # warning
        }

        # delete any other attributes that don't apply to transport
        my $go_connect_method = delete $go_attr{go_connect_method};

        my $transport_class = delete $go_attr{go_transport}
            or return $drh-&gt;set_err($DBI::stderr, &quot;No transport= argument in '$orig_dsn'&quot;);
        $transport_class = &quot;DBD::Gofer::Transport::$transport_class&quot;
            unless $transport_class =~ /::/;
        _load_class($transport_class)
            or return $drh-&gt;set_err($DBI::stderr, &quot;Can't load $transport_class: $@&quot;);
        my $go_transport = eval { $transport_class-&gt;new(\%go_attr) }
            or return $drh-&gt;set_err($DBI::stderr, &quot;Can't instanciate $transport_class: $@&quot;);

        my $request_class = &quot;DBI::Gofer::Request&quot;;
        my $go_request = eval {
            my $go_attr = { %$attr };
            # XXX user/pass of fwd server vs db server ? also impact of autoproxy
            if ($user) {
                $go_attr-&gt;{Username} = $user;
                $go_attr-&gt;{Password} = $auth;
            }
            # delete any attributes we can't serialize (or don't want to)
            delete @{$go_attr}{qw(Profile HandleError HandleSetErr Callbacks)};
            # delete any attributes that should only apply to the client-side
            delete @{$go_attr}{qw(RootClass DbTypeSubclass)};

            $go_connect_method ||= $go_policy-&gt;connect_method($remote_dsn, $go_attr) || 'connect';
            $request_class-&gt;new({
                dbh_connect_call =&gt; [ $go_connect_method, $remote_dsn, $user, $auth, $go_attr ],
            })
        } or return $drh-&gt;set_err($DBI::stderr, &quot;Can't instanciate $request_class: $@&quot;);

        my ($dbh, $dbh_inner) = DBI::_new_dbh($drh, {
            'Name' =&gt; $dsn,
            'USER' =&gt; $user,
            go_transport =&gt; $go_transport,
            go_request =&gt; $go_request,
            go_policy =&gt; $go_policy,
        });

        # mark as inactive temporarily for STORE. Active not set until connected() called.
        $dbh-&gt;STORE(Active =&gt; 0);

        # should we ping to check the connection
        # and fetch dbh attributes
        my $skip_connect_check = $go_policy-&gt;skip_connect_check($attr, $dbh);
        if (not $skip_connect_check) {
            if (not $dbh-&gt;go_dbh_method(undef, 'ping')) {
                return undef if $dbh-&gt;err; # error already recorded, typically
                return $dbh-&gt;set_err($DBI::stderr, &quot;ping failed&quot;);
            }
        }

        return $dbh;
    }

    sub _load_class { # return true or false+$@
        my $class = shift;
        (my $pm = $class) =~ s{::}{/}g;
        $pm .= &quot;.pm&quot;;
        return 1 if eval { require $pm };
        delete $INC{$pm}; # shouldn't be needed (perl bug?) and assigning undef isn't enough
        undef; # error in $@
    }

}


{   package DBD::Gofer::db; # ====== DATABASE ======
    $imp_data_size = 0;
    use strict;
    use Carp qw(carp croak);

    my %dbh_local_store_attrib = %DBD::Gofer::xxh_local_store_attrib;

    sub connected {
        shift-&gt;STORE(Active =&gt; 1);
    }

    sub go_dbh_method {
        my $dbh = shift;
        my $meta = shift;
        # @_ now contains ($method_name, @args)

        my $request = $dbh-&gt;{go_request};
        $request-&gt;init_request([ wantarray, @_ ], $dbh);
        ++$dbh-&gt;{go_request_count};

        my $go_policy = $dbh-&gt;{go_policy};
        my $dbh_attribute_update = $go_policy-&gt;dbh_attribute_update();
        $request-&gt;dbh_attributes( $go_policy-&gt;dbh_attribute_list() )
            if $dbh_attribute_update eq 'every'
            or $dbh-&gt;{go_request_count}==1;

        $request-&gt;dbh_last_insert_id_args($meta-&gt;{go_last_insert_id_args})
            if $meta-&gt;{go_last_insert_id_args};

        my $transport = $dbh-&gt;{go_transport}
            or return $dbh-&gt;set_err($DBI::stderr, &quot;Not connected (no transport)&quot;);

        local $transport-&gt;{go_cache} = $dbh-&gt;{go_cache}
            if defined $dbh-&gt;{go_cache};

        my ($response, $retransmit_sub) = $transport-&gt;transmit_request($request);
        $response ||= $transport-&gt;receive_response($request, $retransmit_sub);
        $dbh-&gt;{go_response} = $response
            or die &quot;No response object returned by $transport&quot;;

        die &quot;response '$response' returned by $transport is not a response object&quot;
            unless UNIVERSAL::isa($response,&quot;DBI::Gofer::Response&quot;);

        if (my $dbh_attributes = $response-&gt;dbh_attributes) {

            # XXX installed_methods piggybacks on dbh_attributes for now
            if (my $installed_methods = delete $dbh_attributes-&gt;{dbi_installed_methods}) {
                DBD::Gofer::install_methods_proxy($installed_methods)
                    if $dbh-&gt;{go_request_count}==1;
            }

            # XXX we don't STORE here, we just stuff the value into the attribute cache
            $dbh-&gt;{$_} = $dbh_attributes-&gt;{$_}
                for keys %$dbh_attributes;
        }

        my $rv = $response-&gt;rv;
        if (my $resultset_list = $response-&gt;sth_resultsets) {
            # dbh method call returned one or more resultsets
            # (was probably a metadata method like table_info)
            #
            # setup an sth but don't execute/forward it
            my $sth = $dbh-&gt;prepare(undef, { go_skip_prepare_check =&gt; 1 });
            # set the sth response to our dbh response
            (tied %$sth)-&gt;{go_response} = $response;
            # setup the sth with the results in our response
            $sth-&gt;more_results;
            # and return that new sth as if it came from original request
            $rv = [ $sth ];
        }
        elsif (!$rv) { # should only occur for major transport-level error
            #carp(&quot;no rv in response { @{[ %$response ]} }&quot;);
            $rv = [ ];
        }

        DBD::Gofer::set_err_from_response($dbh, $response);

        return (wantarray) ? @$rv : $rv-&gt;[0];
    }


    # Methods that should be forwarded but can be cached
    for my $method (qw(
        tables table_info column_info primary_key_info foreign_key_info statistics_info
        data_sources type_info_all get_info
        parse_trace_flags parse_trace_flag
        func
    )) {
        my $policy_name = &quot;cache_$method&quot;;
        my $super_name  = &quot;SUPER::$method&quot;;
        my $sub = sub {
            my $dbh = shift;
            my $rv;

            # if we know the remote side doesn't override the DBI's default method
            # then we might as well just call the DBI's default method on the client
            # (which may, in turn, call other methods that are forwarded, like get_info)
            if ($dbh-&gt;{dbi_default_methods}{$method} &amp;&amp; $dbh-&gt;{go_policy}-&gt;skip_default_methods()) {
                $dbh-&gt;trace_msg(&quot;    !! $method: using local default as remote method is also default\n&quot;);
                return $dbh-&gt;$super_name(@_);
            }

            my $cache;
            my $cache_key;
            if (my $cache_it = $dbh-&gt;{go_policy}-&gt;$policy_name(undef, $dbh, @_)) {
                $cache = $dbh-&gt;{go_meta_cache} ||= {}; # keep separate from go_cache
                $cache_key = sprintf &quot;%s_wa%d(%s)&quot;, $policy_name, wantarray||0,
                    join(&quot;,\t&quot;, map { # XXX basic but sufficient for now
                         !ref($_)            ? DBI::neat($_,1e6)
                        : ref($_) eq 'ARRAY' ? DBI::neat_list($_,1e6,&quot;,\001&quot;)
                        : ref($_) eq 'HASH'  ? do { my @k = sort keys %$_; DBI::neat_list([@k,@{$_}{@k}],1e6,&quot;,\002&quot;) }
                        : do { warn &quot;unhandled argument type ($_)&quot;; $_ }
                    } @_);
                if ($rv = $cache-&gt;{$cache_key}) {
                    $dbh-&gt;trace_msg(&quot;$method(@_) returning previously cached value ($cache_key)\n&quot;,4);
                    my @cache_rv = @$rv;
                    # if it's an sth we have to clone it
                    $cache_rv[0] = $cache_rv[0]-&gt;go_clone_sth if UNIVERSAL::isa($cache_rv[0],'DBI::st');
                    return (wantarray) ? @cache_rv : $cache_rv[0];
                }
            }

            $rv = [ (wantarray)
                ?       ($dbh-&gt;go_dbh_method(undef, $method, @_))
                : scalar $dbh-&gt;go_dbh_method(undef, $method, @_)
            ];

            if ($cache) {
                $dbh-&gt;trace_msg(&quot;$method(@_) caching return value ($cache_key)\n&quot;,4);
                my @cache_rv = @$rv;
                # if it's an sth we have to clone it
                #$cache_rv[0] = $cache_rv[0]-&gt;go_clone_sth
                #   if UNIVERSAL::isa($cache_rv[0],'DBI::st');
                $cache-&gt;{$cache_key} = \@cache_rv
                    unless UNIVERSAL::isa($cache_rv[0],'DBI::st'); # XXX cloning sth not yet done
            }

            return (wantarray) ? @$rv : $rv-&gt;[0];
        };
        no strict 'refs';
        *$method = $sub;
    }


    # Methods that can use the DBI defaults for some situations/drivers
    for my $method (qw(
        quote quote_identifier
    )) {    # XXX keep DBD::Gofer::Policy::Base in sync
        my $policy_name = &quot;locally_$method&quot;;
        my $super_name  = &quot;SUPER::$method&quot;;
        my $sub = sub {
            my $dbh = shift;

            # if we know the remote side doesn't override the DBI's default method
            # then we might as well just call the DBI's default method on the client
            # (which may, in turn, call other methods that are forwarded, like get_info)
            if ($dbh-&gt;{dbi_default_methods}{$method} &amp;&amp; $dbh-&gt;{go_policy}-&gt;skip_default_methods()) {
                $dbh-&gt;trace_msg(&quot;    !! $method: using local default as remote method is also default\n&quot;);
                return $dbh-&gt;$super_name(@_);
            }

            # false:    use remote gofer
            # 1:        use local DBI default method
            # code ref: use the code ref
            my $locally = $dbh-&gt;{go_policy}-&gt;$policy_name($dbh, @_);
            if ($locally) {
                return $locally-&gt;($dbh, @_) if ref $locally eq 'CODE';
                return $dbh-&gt;$super_name(@_);
            }
            return $dbh-&gt;go_dbh_method(undef, $method, @_); # propagate context
        };
        no strict 'refs';
        *$method = $sub;
    }


    # Methods that should always fail
    for my $method (qw(
        begin_work commit rollback
    )) {
        no strict 'refs';
        *$method = sub { return shift-&gt;set_err($DBI::stderr, &quot;$method not available with DBD::Gofer&quot;) }
    }


    sub do {
        my ($dbh, $sql, $attr, @args) = @_;
        delete $dbh-&gt;{Statement}; # avoid &quot;Modification of non-creatable hash value attempted&quot;
        $dbh-&gt;{Statement} = $sql; # for profiling and ShowErrorStatement
        my $meta = { go_last_insert_id_args =&gt; $attr-&gt;{go_last_insert_id_args} };
        return $dbh-&gt;go_dbh_method($meta, 'do', $sql, $attr, @args);
    }

    sub ping {
        my $dbh = shift;
        return $dbh-&gt;set_err('', &quot;can't ping while not connected&quot;) # info
            unless $dbh-&gt;SUPER::FETCH('Active');
        my $skip_ping = $dbh-&gt;{go_policy}-&gt;skip_ping();
        return ($skip_ping) ? 1 : $dbh-&gt;go_dbh_method(undef, 'ping', @_);
    }

    sub last_insert_id {
        my $dbh = shift;
        my $response = $dbh-&gt;{go_response} or return undef;
        return $response-&gt;last_insert_id;
    }

    sub FETCH {
        my ($dbh, $attrib) = @_;

        # FETCH is effectively already cached because the DBI checks the
        # attribute cache in the handle before calling FETCH
        # and this FETCH copies the value into the attribute cache

        # forward driver-private attributes (except ours)
        if ($attrib =~ m/^[a-z]/ &amp;&amp; $attrib !~ /^go_/) {
            my $value = $dbh-&gt;go_dbh_method(undef, 'FETCH', $attrib);
            $dbh-&gt;{$attrib} = $value; # XXX forces caching by DBI
            return $dbh-&gt;{$attrib} = $value;
        }

        # else pass up to DBI to handle
        return $dbh-&gt;SUPER::FETCH($attrib);
    }

    sub STORE {
        my ($dbh, $attrib, $value) = @_;
        if ($attrib eq 'AutoCommit') {
            croak &quot;Can't enable transactions when using DBD::Gofer&quot; if !$value;
            return $dbh-&gt;SUPER::STORE($attrib =&gt; ($value) ? -901 : -900);
        }
        return $dbh-&gt;SUPER::STORE($attrib =&gt; $value)
            # we handle this attribute locally
            if $dbh_local_store_attrib{$attrib}
            # or it's a private_ (application) attribute
            or $attrib =~ /^private_/
            # or not yet connected (ie being called by DBI-&gt;connect)
            or not $dbh-&gt;FETCH('Active');

        return $dbh-&gt;SUPER::STORE($attrib =&gt; $value)
            if $DBD::Gofer::xxh_local_store_attrib_if_same_value{$attrib}
            &amp;&amp; do { # values are the same
                my $crnt = $dbh-&gt;FETCH($attrib);
                local $^W;
                (defined($value) ^ defined($crnt))
                    ? 0 # definedness differs
                    : $value eq $crnt;
            };

        # dbh attributes are set at connect-time - see connect()
        carp(&quot;Can't alter \$dbh-&gt;{$attrib} after handle created with DBD::Gofer&quot;) if $dbh-&gt;FETCH('Warn');
        return $dbh-&gt;set_err($DBI::stderr, &quot;Can't alter \$dbh-&gt;{$attrib} after handle created with DBD::Gofer&quot;);
    }

    sub disconnect {
        my $dbh = shift;
        $dbh-&gt;{go_transport} = undef;
        $dbh-&gt;STORE(Active =&gt; 0);
    }

    sub prepare {
        my ($dbh, $statement, $attr)= @_;

        return $dbh-&gt;set_err($DBI::stderr, &quot;Can't prepare when disconnected&quot;)
            unless $dbh-&gt;FETCH('Active');

        $attr = { %$attr } if $attr; # copy so we can edit

        my $policy     = delete($attr-&gt;{go_policy}) || $dbh-&gt;{go_policy};
        my $lii_args   = delete $attr-&gt;{go_last_insert_id_args};
        my $go_prepare = delete($attr-&gt;{go_prepare_method})
                      || $dbh-&gt;{go_prepare_method}
                      || $policy-&gt;prepare_method($dbh, $statement, $attr)
                      || 'prepare'; # e.g. for code not using placeholders
        my $go_cache = delete $attr-&gt;{go_cache};
        # set to undef if there are no attributes left for the actual prepare call
        $attr = undef if $attr and not %$attr;

        my ($sth, $sth_inner) = DBI::_new_sth($dbh, {
            Statement =&gt; $statement,
            go_prepare_call =&gt; [ 0, $go_prepare, $statement, $attr ],
            # go_method_calls =&gt; [], # autovivs if needed
            go_request =&gt; $dbh-&gt;{go_request},
            go_transport =&gt; $dbh-&gt;{go_transport},
            go_policy =&gt; $policy,
            go_last_insert_id_args =&gt; $lii_args,
            go_cache =&gt; $go_cache,
        });
        $sth-&gt;STORE(Active =&gt; 0); # XXX needed? It should be the default

        my $skip_prepare_check = $policy-&gt;skip_prepare_check($attr, $dbh, $statement, $attr, $sth);
        if (not $skip_prepare_check) {
            $sth-&gt;go_sth_method() or return undef;
        }

        return $sth;
    }

    sub prepare_cached {
        my ($dbh, $sql, $attr, $if_active)= @_;
        $attr ||= {};
        return $dbh-&gt;SUPER::prepare_cached($sql, {
            %$attr,
            go_prepare_method =&gt; $attr-&gt;{go_prepare_method} || 'prepare_cached',
        }, $if_active);
    }

    *go_cache = \&amp;DBD::Gofer::go_cache;
}


{   package DBD::Gofer::st; # ====== STATEMENT ======
    $imp_data_size = 0;
    use strict;

    my %sth_local_store_attrib = (%DBD::Gofer::xxh_local_store_attrib, NUM_OF_FIELDS =&gt; 1);

    sub go_sth_method {
        my ($sth, $meta) = @_;

        if (my $ParamValues = $sth-&gt;{ParamValues}) {
            my $ParamAttr = $sth-&gt;{ParamAttr};
            # XXX the sort here is a hack to work around a DBD::Sybase bug
            # but only works properly for params 1..9
            # (reverse because of the unshift)
            my @params = reverse sort keys %$ParamValues;
            if (@params &gt; 9 &amp;&amp; ($sth-&gt;{Database}{go_dsn}||'') =~ /dbi:Sybase/) {
                # if more than 9 then we need to do a proper numeric sort
                # also warn to alert user of this issue
                warn &quot;Sybase param binding order hack in use&quot;;
                @params = sort { $b &lt;=&gt; $a } @params;
            }
            for my $p (@params) {
                # unshift to put binds before execute call
                unshift @{ $sth-&gt;{go_method_calls} },
                    [ 'bind_param', $p, $ParamValues-&gt;{$p}, $ParamAttr-&gt;{$p} ];
            }
        }

        my $dbh = $sth-&gt;{Database} or die &quot;panic&quot;;
        ++$dbh-&gt;{go_request_count};

        my $request = $sth-&gt;{go_request};
        $request-&gt;init_request($sth-&gt;{go_prepare_call}, $sth);
        $request-&gt;sth_method_calls(delete $sth-&gt;{go_method_calls})
            if $sth-&gt;{go_method_calls};
        $request-&gt;sth_result_attr({}); # (currently) also indicates this is an sth request

        $request-&gt;dbh_last_insert_id_args($meta-&gt;{go_last_insert_id_args})
            if $meta-&gt;{go_last_insert_id_args};

        my $go_policy = $sth-&gt;{go_policy};
        my $dbh_attribute_update = $go_policy-&gt;dbh_attribute_update();
        $request-&gt;dbh_attributes( $go_policy-&gt;dbh_attribute_list() )
            if $dbh_attribute_update eq 'every'
            or $dbh-&gt;{go_request_count}==1;

        my $transport = $sth-&gt;{go_transport}
            or return $sth-&gt;set_err($DBI::stderr, &quot;Not connected (no transport)&quot;);

        local $transport-&gt;{go_cache} = $sth-&gt;{go_cache}
            if defined $sth-&gt;{go_cache};

        my ($response, $retransmit_sub) = $transport-&gt;transmit_request($request);
        $response ||= $transport-&gt;receive_response($request, $retransmit_sub);
        $sth-&gt;{go_response} = $response
            or die &quot;No response object returned by $transport&quot;;
        $dbh-&gt;{go_response} = $response; # mainly for last_insert_id

        if (my $dbh_attributes = $response-&gt;dbh_attributes) {
            # XXX we don't STORE here, we just stuff the value into the attribute cache
            $dbh-&gt;{$_} = $dbh_attributes-&gt;{$_}
                for keys %$dbh_attributes;
            # record the values returned, so we know that we have fetched
            # values are which we have fetched (see dbh-&gt;FETCH method)
            $dbh-&gt;{go_dbh_attributes_fetched} = $dbh_attributes;
        }

        my $rv = $response-&gt;rv; # may be undef on error
        if ($response-&gt;sth_resultsets) {
            # setup first resultset - including sth attributes
            $sth-&gt;more_results;
        }
        else {
            $sth-&gt;STORE(Active =&gt; 0);
            $sth-&gt;{go_rows} = $rv;
        }
        # set error/warn/info (after more_results as that'll clear err)
        DBD::Gofer::set_err_from_response($sth, $response);

        return $rv;
    }


    sub bind_param {
        my ($sth, $param, $value, $attr) = @_;
        $sth-&gt;{ParamValues}{$param} = $value;
        $sth-&gt;{ParamAttr}{$param}   = $attr
            if defined $attr; # attr is sticky if not explicitly set
        return 1;
    }


    sub execute {
        my $sth = shift;
        $sth-&gt;bind_param($_, $_[$_-1]) for (1..@_);
        push @{ $sth-&gt;{go_method_calls} }, [ 'execute' ];
        my $meta = { go_last_insert_id_args =&gt; $sth-&gt;{go_last_insert_id_args} };
        return $sth-&gt;go_sth_method($meta);
    }


    sub more_results {
        my $sth = shift;

        $sth-&gt;finish;

        my $response = $sth-&gt;{go_response} or do {
            # e.g., we haven't sent a request yet (ie prepare then more_results)
            $sth-&gt;trace_msg(&quot;    No response object present&quot;, 3);
            return;
        };

        my $resultset_list = $response-&gt;sth_resultsets
            or return $sth-&gt;set_err($DBI::stderr, &quot;No sth_resultsets&quot;);

        my $meta = shift @$resultset_list
            or return undef; # no more result sets
        #warn &quot;more_results: &quot;.Data::Dumper::Dumper($meta);

        # pull out the special non-attributes first
        my ($rowset, $err, $errstr, $state)
            = delete @{$meta}{qw(rowset err errstr state)};

        # copy meta attributes into attribute cache
        my $NUM_OF_FIELDS = delete $meta-&gt;{NUM_OF_FIELDS};
        $sth-&gt;STORE('NUM_OF_FIELDS', $NUM_OF_FIELDS);
        # XXX need to use STORE for some?
        $sth-&gt;{$_} = $meta-&gt;{$_} for keys %$meta;

        if (($NUM_OF_FIELDS||0) &gt; 0) {
            $sth-&gt;{go_rows}           = ($rowset) ? @$rowset : -1;
            $sth-&gt;{go_current_rowset} = $rowset;
            $sth-&gt;{go_current_rowset_err} = [ $err, $errstr, $state ]
                if defined $err;
            $sth-&gt;STORE(Active =&gt; 1) if $rowset;
        }

        return $sth;
    }


    sub go_clone_sth {
        my ($sth1) = @_;
        # clone an (un-fetched-from) sth - effectively undoes the initial more_results
        # not 100% so just for use in caching returned sth e.g. table_info
        my $sth2 = $sth1-&gt;{Database}-&gt;prepare($sth1-&gt;{Statement}, { go_skip_prepare_check =&gt; 1 });
        $sth2-&gt;STORE($_, $sth1-&gt;{$_}) for qw(NUM_OF_FIELDS Active);
        my $sth2_inner = tied %$sth2;
        $sth2_inner-&gt;{$_} = $sth1-&gt;{$_} for qw(NUM_OF_PARAMS FetchHashKeyName);
        die &quot;not fully implemented yet&quot;;
        return $sth2;
    }


    sub fetchrow_arrayref {
        my ($sth) = @_;
        my $resultset = $sth-&gt;{go_current_rowset} || do {
            # should only happen if fetch called after execute failed
            my $rowset_err = $sth-&gt;{go_current_rowset_err}
                || [ 1, 'no result set (did execute fail)' ];
            return $sth-&gt;set_err( @$rowset_err );
        };
        return $sth-&gt;_set_fbav(shift @$resultset) if @$resultset;
        $sth-&gt;finish;     # no more data so finish
        return undef;
    }
    *fetch = \&amp;fetchrow_arrayref; # alias


    sub fetchall_arrayref {
        my ($sth, $slice, $max_rows) = @_;
        my $resultset = $sth-&gt;{go_current_rowset} || do {
            # should only happen if fetch called after execute failed
            my $rowset_err = $sth-&gt;{go_current_rowset_err}
                || [ 1, 'no result set (did execute fail)' ];
            return $sth-&gt;set_err( @$rowset_err );
        };
        my $mode = ref($slice) || 'ARRAY';
        return $sth-&gt;SUPER::fetchall_arrayref($slice, $max_rows)
            if ref($slice) or defined $max_rows;
        $sth-&gt;finish;     # no more data after this so finish
        return $resultset;
    }


    sub rows {
        return shift-&gt;{go_rows};
    }


    sub STORE {
        my ($sth, $attrib, $value) = @_;

        return $sth-&gt;SUPER::STORE($attrib =&gt; $value)
            if $sth_local_store_attrib{$attrib} # handle locally
            # or it's a private_ (application) attribute
            or $attrib =~ /^private_/;

        # otherwise warn but do it anyway
        # this will probably need refining later
        my $msg = &quot;Altering \$sth-&gt;{$attrib} won't affect proxied handle&quot;;
        Carp::carp($msg) if $sth-&gt;FETCH('Warn');

        # XXX could perhaps do
        #   push @{ $sth-&gt;{go_method_calls} }, [ 'STORE', $attrib, $value ]
        #       if not $sth-&gt;FETCH('Executed');
        # but how to handle repeat executions? How to we know when an
        # attribute is being set to affect the current resultset or the
        # next execution?
        # Could just always use go_method_calls I guess.

        # do the store locally anyway, just in case
        $sth-&gt;SUPER::STORE($attrib =&gt; $value);

        return $sth-&gt;set_err($DBI::stderr, $msg);
    }

    # sub bind_param_array
    # we use DBI's default, which sets $sth-&gt;{ParamArrays}{$param} = $value
    # and calls bind_param($param, undef, $attr) if $attr.

    sub execute_array {
        my $sth = shift;
        my $attr = shift;
        $sth-&gt;bind_param_array($_, $_[$_-1]) for (1..@_);
        push @{ $sth-&gt;{go_method_calls} }, [ 'execute_array', $attr ];
        return $sth-&gt;go_sth_method($attr);
    }

    *go_cache = \&amp;DBD::Gofer::go_cache;
}

1;

__END__

=head1 NAME

DBD::Gofer - A stateless-proxy driver for communicating with a remote DBI

=head1 SYNOPSIS

  use DBI;

  $original_dsn = &quot;dbi:...&quot;; # your original DBI Data Source Name

  $dbh = DBI-&gt;connect(&quot;dbi:Gofer:transport=$transport;...;dsn=$original_dsn&quot;,
                      $user, $passwd, \%attributes);

  ... use $dbh as if it was connected to $original_dsn ...


The C&lt;transport=$transport&gt; part specifies the name of the module to use to
transport the requests to the remote DBI. If $transport doesn't contain any
double colons then it's prefixed with C&lt;DBD::Gofer::Transport::&gt;.

The C&lt;dsn=$original_dsn&gt; part I&lt;must be the last element&gt; of the DSN because
everything after C&lt;dsn=&gt; is assumed to be the DSN that the remote DBI should
use.

The C&lt;...&gt; represents attributes that influence the operation of the Gofer
driver or transport. These are described below or in the documentation of the
transport module being used.

=encoding ISO8859-1

=head1 DESCRIPTION

DBD::Gofer is a DBI database driver that forwards requests to another DBI
driver, usually in a separate process, often on a separate machine. It tries to
be as transparent as possible so it appears that you are using the remote
driver directly.

DBD::Gofer is very similar to DBD::Proxy. The major difference is that with
DBD::Gofer no state is maintained on the remote end. That means every
request contains all the information needed to create the required state. (So,
for example, every request includes the DSN to connect to.) Each request can be
sent to any available server. The server executes the request and returns a
single response that includes all the data.

This is very similar to the way http works as a stateless protocol for the web.
Each request from your web browser can be handled by a different web server process.

=head2 Use Cases

This may seem like pointless overhead but there are situations where this is a
very good thing. Let's consider a specific case.

Imagine using DBD::Gofer with an http transport. Your application calls
connect(), prepare(&quot;select * from table where foo=?&quot;), bind_param(), and execute().
At this point DBD::Gofer builds a request containing all the information
about the method calls. It then uses the httpd transport to send that request
to an apache web server.

This 'dbi execute' web server executes the request (using DBI::Gofer::Execute
and related modules) and builds a response that contains all the rows of data,
if the statement returned any, along with all the attributes that describe the
results, such as $sth-&gt;{NAME}. This response is sent back to DBD::Gofer which
unpacks it and presents it to the application as if it had executed the
statement itself.

=head2 Advantages

Okay, but you still don't see the point? Well let's consider what we've gained:

=head3 Connection Pooling and Throttling

The 'dbi execute' web server leverages all the functionality of web
infrastructure in terms of load balancing, high-availability, firewalls, access
management, proxying, caching.

At its most basic level you get a configurable pool of persistent database connections.

=head3 Simple Scaling

Got thousands of processes all trying to connect to the database? You can use
DBD::Gofer to connect them to your smaller pool of 'dbi execute' web servers instead.

=head3 Caching

Client-side caching is as simple as adding &quot;C&lt;cache=1&gt;&quot; to the DSN.
This feature alone can be worth using DBD::Gofer for.

=head3 Fewer Network Round-trips

DBD::Gofer sends as few requests as possible (dependent on the policy being used).

=head3 Thin Clients / Unsupported Platforms

You no longer need drivers for your database on every system.  DBD::Gofer is pure perl.

=head1 CONSTRAINTS

There are some natural constraints imposed by the DBD::Gofer 'stateless' approach.
But not many:

=head2 You can't change database handle attributes after connect()

You can't change database handle attributes after you've connected.
Use the connect() call to specify all the attribute settings you want.

This is because it's critical that when a request is complete the database
handle is left in the same state it was when first connected.

An exception is made for attributes with names starting &quot;C&lt;private_&gt;&quot;:
They can be set after connect() but the change is only applied locally.

=head2 You can't change statement handle attributes after prepare()

You can't change statement handle attributes after prepare.

An exception is made for attributes with names starting &quot;C&lt;private_&gt;&quot;:
They can be set after prepare() but the change is only applied locally.

=head2 You can't use transactions

AutoCommit only. Transactions aren't supported.

(In theory transactions could be supported when using a transport that
maintains a connection, like C&lt;stream&gt; does. If you're interested in this
please get in touch via dbi-dev@perl.org)

=head2 You can't call driver-private sth methods

But that's rarely needed anyway.

=head1 GENERAL CAVEATS

A few important things to keep in mind when using DBD::Gofer:

=head2 Temporary tables, locks, and other per-connection persistent state

You shouldn't expect any per-session state to persist between requests.
This includes locks and temporary tables.

Because the server-side may execute your requests via a different
database connections, you can't rely on any per-connection persistent state,
such as temporary tables, being available from one request to the next.

This is an easy trap to fall into. A good way to check for this is to test your
code with a Gofer policy package that sets the C&lt;connect_method&gt; policy to
'connect' to force a new connection for each request. The C&lt;pedantic&gt; policy does this.

=head2 Driver-private Database Handle Attributes

Some driver-private dbh attributes may not be available if the driver has not
implemented the private_attribute_info() method (added in DBI 1.54).

=head2 Driver-private Statement Handle Attributes

Driver-private sth attributes can be set in the prepare() call. TODO

Some driver-private sth attributes may not be available if the driver has not
implemented the private_attribute_info() method (added in DBI 1.54).

=head2 Multiple Resultsets

Multiple resultsets are supported only if the driver supports the more_results() method
(an exception is made for DBD::Sybase).

=head2 Statement activity that also updates dbh attributes

Some drivers may update one or more dbh attributes after performing activity on
a child sth.  For example, DBD::mysql provides $dbh-&gt;{mysql_insertid} in addition to
$sth-&gt;{mysql_insertid}. Currently mysql_insertid is supported via a hack but a
more general mechanism is needed for other drivers to use.

=head2 Methods that report an error always return undef

With DBD::Gofer, a method that sets an error always return an undef or empty list.
That shouldn't be a problem in practice because the DBI doesn't define any
methods that return meaningful values while also reporting an error.

=head2 Subclassing only applies to client-side

The RootClass and DbTypeSubclass attributes are not passed to the Gofer server.

=head1 CAVEATS FOR SPECIFIC METHODS

=head2 last_insert_id

To enable use of last_insert_id you need to indicate to DBD::Gofer that you'd
like to use it.  You do that my adding a C&lt;go_last_insert_id_args&gt; attribute to
the do() or prepare() method calls. For example:

    $dbh-&gt;do($sql, { go_last_insert_id_args =&gt; [...] });

or

    $sth = $dbh-&gt;prepare($sql, { go_last_insert_id_args =&gt; [...] });

The array reference should contains the args that you want passed to the
last_insert_id() method.

=head2 execute_for_fetch

The array methods bind_param_array() and execute_array() are supported.
When execute_array() is called the data is serialized and executed in a single
round-trip to the Gofer server. This makes it very fast, but requires enough
memory to store all the serialized data.

The execute_for_fetch() method currently isn't optimised, it uses the DBI
fallback behaviour of executing each tuple individually.
(It could be implemented as a wrapper for execute_array() - patches welcome.)

=head1 TRANSPORTS

DBD::Gofer doesn't concern itself with transporting requests and responses to and fro.
For that it uses special Gofer transport modules.

Gofer transport modules usually come in pairs: one for the 'client' DBD::Gofer
driver to use and one for the remote 'server' end. They have very similar names:

    DBD::Gofer::Transport::&lt;foo&gt;
    DBI::Gofer::Transport::&lt;foo&gt;

Sometimes the transports on the DBD and DBI sides may have different names. For
example DBD::Gofer::Transport::http is typically used with DBI::Gofer::Transport::mod_perl
(DBD::Gofer::Transport::http and DBI::Gofer::Transport::mod_perl modules are
part of the GoferTransport-http distribution).

=head2 Bundled Transports

Several transport modules are provided with DBD::Gofer:

=head3 null

The null transport is the simplest of them all. It doesn't actually transport the request anywhere.
It just serializes (freezes) the request into a string, then thaws it back into
a data structure before passing it to DBI::Gofer::Execute to execute. The same
freeze and thaw is applied to the results.

The null transport is the best way to test if your application will work with Gofer.
Just set the DBI_AUTOPROXY environment variable to &quot;C&lt;dbi:Gofer:transport=null;policy=pedantic&gt;&quot;
(see L&lt;/Using DBI_AUTOPROXY&gt; below) and run your application, or ideally its test suite, as usual.

It doesn't take any parameters.

=head3 pipeone

The pipeone transport launches a subprocess for each request. It passes in the
request and reads the response.

The fact that a new subprocess is started for each request ensures that the
server side is truly stateless. While this does make the transport I&lt;very&gt; slow,
it is useful as a way to test that your application doesn't depend on
per-connection state, such as temporary tables, persisting between requests.

It's also useful both as a proof of concept and as a base class for the stream
driver.

=head3 stream

The stream driver also launches a subprocess and writes requests and reads
responses, like the pipeone transport.  In this case, however, the subprocess
is expected to handle more that one request. (Though it will be automatically
restarted if it exits.)

This is the first transport that is truly useful because it can launch the
subprocess on a remote machine using C&lt;ssh&gt;. This means you can now use DBD::Gofer
to easily access any databases that's accessible from any system you can login to.
You also get all the benefits of ssh, including encryption and optional compression.

See L&lt;/Using DBI_AUTOPROXY&gt; below for an example.

=head2 Other Transports

Implementing a Gofer transport is I&lt;very&gt; simple, and more transports are very welcome.
Just take a look at any existing transports that are similar to your needs.

=head3 http

See the GoferTransport-http distribution on CPAN: http://search.cpan.org/dist/GoferTransport-http/

=head3 Gearman

I know Ask Bjørn Hansen has implemented a transport for the C&lt;gearman&gt; distributed
job system, though it's not on CPAN at the time of writing this.

=head1 CONNECTING

Simply prefix your existing DSN with &quot;C&lt;dbi:Gofer:transport=$transport;dsn=&gt;&quot;
where $transport is the name of the Gofer transport you want to use (see L&lt;/TRANSPORTS&gt;).
The C&lt;transport&gt; and C&lt;dsn&gt; attributes must be specified and the C&lt;dsn&gt; attributes must be last.

Other attributes can be specified in the DSN to configure DBD::Gofer and/or the
Gofer transport module being used. The main attributes after C&lt;transport&gt;, are
C&lt;url&gt; and C&lt;policy&gt;. These and other attributes are described below.

=head2 Using DBI_AUTOPROXY

The simplest way to try out DBD::Gofer is to set the DBI_AUTOPROXY environment variable.
In this case you don't include the C&lt;dsn=&gt; part. For example:

    export DBI_AUTOPROXY=&quot;dbi:Gofer:transport=null&quot;

or, for a more useful example, try:

    export DBI_AUTOPROXY=&quot;dbi:Gofer:transport=stream;url=ssh:user@example.com&quot;

=head2 Connection Attributes

These attributes can be specified in the DSN. They can also be passed in the
\%attr parameter of the DBI connect method by adding a &quot;C&lt;go_&gt;&quot; prefix to the name.

=head3 transport

Specifies the Gofer transport class to use. Required. See L&lt;/TRANSPORTS&gt; above.

If the value does not include C&lt;::&gt; then &quot;C&lt;DBD::Gofer::Transport::&gt;&quot; is prefixed.

The transport object can be accessed via $h-&gt;{go_transport}.

=head3 dsn

Specifies the DSN for the remote side to connect to. Required, and must be last.

=head3 url

Used to tell the transport where to connect to. The exact form of the value depends on the transport used.

=head3 policy

Specifies the policy to use. See L&lt;/CONFIGURING BEHAVIOUR POLICY&gt;.

If the value does not include C&lt;::&gt; then &quot;C&lt;DBD::Gofer::Policy&gt;&quot; is prefixed.

The policy object can be accessed via $h-&gt;{go_policy}.

=head3 timeout

Specifies a timeout, in seconds, to use when waiting for responses from the server side.

=head3 retry_limit

Specifies the number of times a failed request will be retried. Default is 0.

=head3 retry_hook

Specifies a code reference to be called to decide if a failed request should be retried.
The code reference is called like this:

  $transport = $h-&gt;{go_transport};
  $retry = $transport-&gt;go_retry_hook-&gt;($request, $response, $transport);

If it returns true then the request will be retried, up to the C&lt;retry_limit&gt;.
If it returns a false but defined value then the request will not be retried.
If it returns undef then the default behaviour will be used, as if C&lt;retry_hook&gt;
had not been specified.

The default behaviour is to retry requests where $request-&gt;is_idempotent is true,
or the error message matches C&lt;/induced by DBI_GOFER_RANDOM/&gt;.

=head3 cache

Specifies that client-side caching should be performed.  The value is the name
of a cache class to use.

Any class implementing get($key) and set($key, $value) methods can be used.
That includes a great many powerful caching classes on CPAN, including the
Cache and Cache::Cache distributions.

You can use &quot;C&lt;cache=1&gt;&quot; is a shortcut for &quot;C&lt;cache=DBI::Util::CacheMemory&gt;&quot;.
See L&lt;DBI::Util::CacheMemory&gt; for a description of this simple fast default cache.

The cache object can be accessed via $h-&gt;go_cache. For example:

    $dbh-&gt;go_cache-&gt;clear; # free up memory being used by the cache

The cache keys are the frozen (serialized) requests, and the values are the
frozen responses.

The default behaviour is to only use the cache for requests where
$request-&gt;is_idempotent is true (i.e., the dbh has the ReadOnly attribute set
or the SQL statement is obviously a SELECT without a FOR UPDATE clause.)

For even more control you can use the C&lt;go_cache&gt; attribute to pass in an
instantiated cache object. Individual methods, including prepare(), can also
specify alternative caches via the C&lt;go_cache&gt; attribute. For example, to
specify no caching for a particular query, you could use

    $sth = $dbh-&gt;prepare( $sql, { go_cache =&gt; 0 } );

This can be used to implement different caching policies for different statements.

It's interesting to note that DBD::Gofer can be used to add client-side caching
to any (gofer compatible) application, with no code changes and no need for a
gofer server.  Just set the DBI_AUTOPROXY environment variable like this:

    DBI_AUTOPROXY='dbi:Gofer:transport=null;cache=1'

=head1 CONFIGURING BEHAVIOUR POLICY

DBD::Gofer supports a 'policy' mechanism that allows you to fine-tune the number of round-trips to the Gofer server.
The policies are grouped into classes (which may be subclassed) and referenced by the name of the class.

The L&lt;DBD::Gofer::Policy::Base&gt; class is the base class for all the policy
packages and describes all the available policies.

Three policy packages are supplied with DBD::Gofer:

L&lt;DBD::Gofer::Policy::pedantic&gt; is most 'transparent' but slowest because it
makes more  round-trips to the Gofer server.

L&lt;DBD::Gofer::Policy::classic&gt; is a reasonable compromise - it's the default policy.

L&lt;DBD::Gofer::Policy::rush&gt; is fastest, but may require code changes in your applications.

Generally the default C&lt;classic&gt; policy is fine. When first testing an existing
application with Gofer it is a good idea to start with the C&lt;pedantic&gt; policy
first and then switch to C&lt;classic&gt; or a custom policy, for final testing.


=head1 AUTHOR

Tim Bunce, L&lt;http://www.tim.bunce.name&gt;

=head1 LICENCE AND COPYRIGHT

Copyright (c) 2007, Tim Bunce, Ireland. All rights reserved.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself. See L&lt;perlartistic&gt;.

=head1 ACKNOWLEDGEMENTS

The development of DBD::Gofer and related modules was sponsored by
Shopzilla.com (L&lt;http://Shopzilla.com&gt;), where I currently work.

=head1 SEE ALSO

L&lt;DBI::Gofer::Request&gt;, L&lt;DBI::Gofer::Response&gt;, L&lt;DBI::Gofer::Execute&gt;.

L&lt;DBI::Gofer::Transport::Base&gt;, L&lt;DBD::Gofer::Policy::Base&gt;.

L&lt;DBI&gt;

=head1 Caveats for specific drivers

This section aims to record issues to be aware of when using Gofer with specific drivers.
It usually only documents issues that are not natural consequences of the limitations
of the Gofer approach - as documented above.

=head1 TODO

This is just a random brain dump... (There's more in the source of the Changes file, not the pod)

Document policy mechanism

Add mechanism for transports to list config params and for Gofer to apply any that match (and warn if any left over?)

Driver-private sth attributes - set via prepare() - change DBI spec

add hooks into transport base class for checking &amp; updating a result set cache
   ie via a standard cache interface such as:
   http://search.cpan.org/~robm/Cache-FastMmap/FastMmap.pm
   http://search.cpan.org/~bradfitz/Cache-Memcached/lib/Cache/Memcached.pm
   http://search.cpan.org/~dclinton/Cache-Cache/
   http://search.cpan.org/~cleishman/Cache/
Also caching instructions could be passed through the httpd transport layer
in such a way that appropriate http cache headers are added to the results
so that web caches (squid etc) could be used to implement the caching.
(MUST require the use of GET rather than POST requests.)

Rework handling of installed_methods to not piggyback on dbh_attributes?

Perhaps support transactions for transports where it's possible (ie null and stream)?
Would make stream transport (ie ssh) more useful to more people.

Make sth_result_attr more like dbh_attributes (using '*' etc)

Add @val = FETCH_many(@names) to DBI in C and use in Gofer/Execute?

Implement _new_sth in C.

=cut
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Flib64%2Fperl5%2Fvendor_perl%2FDBD' class='btn'>Cancel</a>
        </form>