<h2>Editing: File.pm</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'># -*- perl -*-
#
#   DBD::File - A base class for implementing DBI drivers that
#               act on plain files
#
#  This module is currently maintained by
#
#      H.Merijn Brand &amp; Jens Rehsack
#
#  The original author is Jochen Wiedmann.
#
#  Copyright (C) 2009-2013 by H.Merijn Brand &amp; Jens Rehsack
#  Copyright (C) 2004 by Jeff Zucker
#  Copyright (C) 1998 by Jochen Wiedmann
#
#  All rights reserved.
#
#  You may distribute this module under the terms of either the GNU
#  General Public License or the Artistic License, as specified in
#  the Perl README file.

require 5.008;

use strict;
use warnings;

use DBI ();

package DBD::File;

use strict;
use warnings;

use base qw( DBI::DBD::SqlEngine );
use Carp;
use vars qw( @ISA $VERSION $drh );

$VERSION = &quot;0.44&quot;;

$drh = undef;		# holds driver handle(s) once initialized

sub driver ($;$)
{
    my ($class, $attr) = @_;

    # Drivers typically use a singleton object for the $drh
    # We use a hash here to have one singleton per subclass.
    # (Otherwise DBD::CSV and DBD::DBM, for example, would
    # share the same driver object which would cause problems.)
    # An alternative would be to not cache the $drh here at all
    # and require that subclasses do that. Subclasses should do
    # their own caching, so caching here just provides extra safety.
    $drh-&gt;{$class} and return $drh-&gt;{$class};

    $attr ||= {};
    {	no strict &quot;refs&quot;;
	unless ($attr-&gt;{Attribution}) {
	    $class eq &quot;DBD::File&quot; and
		$attr-&gt;{Attribution} = &quot;$class by Jeff Zucker&quot;;
	    $attr-&gt;{Attribution} ||= ${$class . &quot;::ATTRIBUTION&quot;} ||
		&quot;oops the author of $class forgot to define this&quot;;
	    }
	$attr-&gt;{Version} ||= ${$class . &quot;::VERSION&quot;};
	$attr-&gt;{Name} or ($attr-&gt;{Name} = $class) =~ s/^DBD\:\://;
	}

    $drh-&gt;{$class} = $class-&gt;SUPER::driver ($attr);

    # XXX inject DBD::XXX::Statement unless exists

    return $drh-&gt;{$class};
    } # driver

sub CLONE
{
    undef $drh;
    } # CLONE

# ====== DRIVER ================================================================

package DBD::File::dr;

use strict;
use warnings;

use vars qw( @ISA $imp_data_size );

use Carp;

@DBD::File::dr::ISA           = qw( DBI::DBD::SqlEngine::dr );
$DBD::File::dr::imp_data_size = 0;

sub dsn_quote
{
    my $str = shift;
    ref     $str and return &quot;&quot;;
    defined $str or  return &quot;&quot;;
    $str =~ s/([;:\\])/\\$1/g;
    return $str;
    } # dsn_quote

# XXX rewrite using TableConfig ...
sub default_table_source { &quot;DBD::File::TableSource::FileSystem&quot; }

sub connect
{
    my ($drh, $dbname, $user, $auth, $attr) = @_;

    # We do not (yet) care about conflicting attributes here
    # my $dbh = DBI-&gt;connect (&quot;dbi:CSV:f_dir=test&quot;, undef, undef, { f_dir =&gt; &quot;text&quot; });
    # will test here that both test and text should exist
    if (my $attr_hash = (DBI-&gt;parse_dsn ($dbname))[3]) {
	if (defined $attr_hash-&gt;{f_dir} &amp;&amp; ! -d $attr_hash-&gt;{f_dir}) {
	    my $msg = &quot;No such directory '$attr_hash-&gt;{f_dir}&quot;;
	    $drh-&gt;set_err (2, $msg);
	    $attr_hash-&gt;{RaiseError} and croak $msg;
	    return;
	    }
	}
    if ($attr and defined $attr-&gt;{f_dir} &amp;&amp; ! -d $attr-&gt;{f_dir}) {
	my $msg = &quot;No such directory '$attr-&gt;{f_dir}&quot;;
	$drh-&gt;set_err (2, $msg);
	$attr-&gt;{RaiseError} and croak $msg;
	return;
	}

    return $drh-&gt;SUPER::connect ($dbname, $user, $auth, $attr);
    } # connect

sub disconnect_all
{
    } # disconnect_all

sub DESTROY
{
    undef;
    } # DESTROY

# ====== DATABASE ==============================================================

package DBD::File::db;

use strict;
use warnings;

use vars qw( @ISA $imp_data_size );

use Carp;
require File::Spec;
require Cwd;
use Scalar::Util qw( refaddr ); # in CORE since 5.7.3

@DBD::File::db::ISA           = qw( DBI::DBD::SqlEngine::db );
$DBD::File::db::imp_data_size = 0;

sub data_sources
{
    my ($dbh, $attr, @other) = @_;
    ref ($attr) eq &quot;HASH&quot; or $attr = {};
    exists $attr-&gt;{f_dir}        or $attr-&gt;{f_dir}        = $dbh-&gt;{f_dir};
    exists $attr-&gt;{f_dir_search} or $attr-&gt;{f_dir_search} = $dbh-&gt;{f_dir_search};
    return $dbh-&gt;SUPER::data_sources ($attr, @other);
    } # data_source

sub set_versions
{
    my $dbh = shift;
    $dbh-&gt;{f_version} = $DBD::File::VERSION;

    return $dbh-&gt;SUPER::set_versions ();
    } # set_versions

sub init_valid_attributes
{
    my $dbh = shift;

    $dbh-&gt;{f_valid_attrs} = {
	f_version        =&gt; 1, # DBD::File version
	f_dir            =&gt; 1, # base directory
	f_dir_search     =&gt; 1, # extended search directories
	f_ext            =&gt; 1, # file extension
	f_schema         =&gt; 1, # schema name
	f_lock           =&gt; 1, # Table locking mode
	f_lockfile       =&gt; 1, # Table lockfile extension
	f_encoding       =&gt; 1, # Encoding of the file
	f_valid_attrs    =&gt; 1, # File valid attributes
	f_readonly_attrs =&gt; 1, # File readonly attributes
	};
    $dbh-&gt;{f_readonly_attrs} = {
	f_version        =&gt; 1, # DBD::File version
	f_valid_attrs    =&gt; 1, # File valid attributes
	f_readonly_attrs =&gt; 1, # File readonly attributes
	};

    return $dbh-&gt;SUPER::init_valid_attributes ();
    } # init_valid_attributes

sub init_default_attributes
{
    my ($dbh, $phase) = @_;

    # must be done first, because setting flags implicitly calls $dbdname::db-&gt;STORE
    $dbh-&gt;SUPER::init_default_attributes ($phase);

    # DBI::BD::SqlEngine::dr::connect will detect old-style drivers and
    # don't call twice
    unless (defined $phase) {
        # we have an &quot;old&quot; driver here
        $phase = defined $dbh-&gt;{sql_init_phase};
	$phase and $phase = $dbh-&gt;{sql_init_phase};
	}

    if (0 == $phase) {
	# f_ext should not be initialized
	# f_map is deprecated (but might return)
	$dbh-&gt;{f_dir} = Cwd::abs_path (File::Spec-&gt;curdir ());

	push @{$dbh-&gt;{sql_init_order}{90}}, &quot;f_meta&quot;;

	# complete derived attributes, if required
	(my $drv_class = $dbh-&gt;{ImplementorClass}) =~ s/::db$//;
	my $drv_prefix = DBI-&gt;driver_prefix ($drv_class);
        if (exists $dbh-&gt;{$drv_prefix . &quot;meta&quot;} and !$dbh-&gt;{sql_engine_in_gofer}) {
            my $attr = $dbh-&gt;{$drv_prefix . &quot;meta&quot;};
            defined $dbh-&gt;{f_valid_attrs}{f_meta}
		and $dbh-&gt;{f_valid_attrs}{f_meta} = 1;

            $dbh-&gt;{f_meta} = $dbh-&gt;{$attr};
	    }
	}

    return $dbh;
    } # init_default_attributes

sub validate_FETCH_attr
{
    my ($dbh, $attrib) = @_;

    $attrib eq &quot;f_meta&quot; and $dbh-&gt;{sql_engine_in_gofer} and $attrib = &quot;sql_meta&quot;;

    return $dbh-&gt;SUPER::validate_FETCH_attr ($attrib);
    } # validate_FETCH_attr

sub validate_STORE_attr
{
    my ($dbh, $attrib, $value) = @_;

    if ($attrib eq &quot;f_dir&quot; &amp;&amp; defined $value) {
	-d $value or
	    return $dbh-&gt;set_err ($DBI::stderr, &quot;No such directory '$value'&quot;);
	File::Spec-&gt;file_name_is_absolute ($value) or
	    $value = Cwd::abs_path ($value);
	}

    if ($attrib eq &quot;f_ext&quot;) {
	$value eq &quot;&quot; || $value =~ m{^\.\w+(?:/[rR]*)?$} or
	    carp &quot;'$value' doesn't look like a valid file extension attribute\n&quot;;
	}

    $attrib eq &quot;f_meta&quot; and $dbh-&gt;{sql_engine_in_gofer} and $attrib = &quot;sql_meta&quot;;

    return $dbh-&gt;SUPER::validate_STORE_attr ($attrib, $value);
    } # validate_STORE_attr

sub get_f_versions
{
    my ($dbh, $table) = @_;

    my $class = $dbh-&gt;{ImplementorClass};
    $class =~ s/::db$/::Table/;
    my $dver;
    my $dtype = &quot;IO::File&quot;;
    eval {
	$dver = IO::File-&gt;VERSION ();

	# when we're still alive here, everything went ok - no need to check for $@
	$dtype .= &quot; ($dver)&quot;;
	};

    my $f_encoding;
    if ($table) {
	my $meta;
	$table and (undef, $meta) = $class-&gt;get_table_meta ($dbh, $table, 1);
	$meta and $meta-&gt;{f_encoding} and $f_encoding = $meta-&gt;{f_encoding};
	} # if ($table)
    $f_encoding ||= $dbh-&gt;{f_encoding};

    $f_encoding and $dtype .= &quot; + &quot; . $f_encoding . &quot; encoding&quot;;

    return sprintf &quot;%s using %s&quot;, $dbh-&gt;{f_version}, $dtype;
    } # get_f_versions

# ====== STATEMENT =============================================================

package DBD::File::st;

use strict;
use warnings;

use vars qw( @ISA $imp_data_size );

@DBD::File::st::ISA           = qw( DBI::DBD::SqlEngine::st );
$DBD::File::st::imp_data_size = 0;

my %supported_attrs = (
    TYPE      =&gt; 1,
    PRECISION =&gt; 1,
    NULLABLE  =&gt; 1,
    );

sub FETCH
{
    my ($sth, $attr) = @_;

    if ($supported_attrs{$attr}) {
	my $stmt = $sth-&gt;{sql_stmt};

	if (exists $sth-&gt;{ImplementorClass} &amp;&amp;
	    exists $sth-&gt;{sql_stmt} &amp;&amp;
	    $sth-&gt;{sql_stmt}-&gt;isa (&quot;SQL::Statement&quot;)) {

	    # fill overall_defs unless we know
	    unless (exists $sth-&gt;{f_overall_defs} &amp;&amp; ref $sth-&gt;{f_overall_defs}) {
		my $types = $sth-&gt;{Database}{Types};
		unless ($types) { # Fetch types only once per database
		    if (my $t = $sth-&gt;{Database}-&gt;type_info_all ()) {
			foreach my $i (1 .. $#$t) {
			    $types-&gt;{uc $t-&gt;[$i][0]}   = $t-&gt;[$i][1];
			    $types-&gt;{$t-&gt;[$i][1]} ||= uc $t-&gt;[$i][0];
			    }
			}
		    # sane defaults
		    for ([  0, &quot;&quot;		],
			 [  1, &quot;CHAR&quot;		],
			 [  4, &quot;INTEGER&quot;	],
			 [ 12, &quot;VARCHAR&quot;	],
			 ) {
			$types-&gt;{$_-&gt;[0]} ||= $_-&gt;[1];
			$types-&gt;{$_-&gt;[1]} ||= $_-&gt;[0];
			}
		    $sth-&gt;{Database}{Types} = $types;
		    }
		my $all_meta =
		    $sth-&gt;{Database}-&gt;func (&quot;*&quot;, &quot;table_defs&quot;, &quot;get_sql_engine_meta&quot;);
		foreach my $tbl (keys %$all_meta) {
		    my $meta = $all_meta-&gt;{$tbl};
		    exists $meta-&gt;{table_defs} &amp;&amp; ref $meta-&gt;{table_defs} or next;
		    foreach (keys %{$meta-&gt;{table_defs}{columns}}) {
			my $field_info = $meta-&gt;{table_defs}{columns}{$_};
			if (defined $field_info-&gt;{data_type} &amp;&amp;
				    $field_info-&gt;{data_type} !~ m/^[0-9]+$/) {
			    $field_info-&gt;{type_name} = uc $field_info-&gt;{data_type};
			    $field_info-&gt;{data_type} = $types-&gt;{$field_info-&gt;{type_name}} || 0;
			    }
			$field_info-&gt;{type_name} ||= $types-&gt;{$field_info-&gt;{data_type}} || &quot;CHAR&quot;;
			$sth-&gt;{f_overall_defs}{$_} = $field_info;
			}
		    }
		}

	    my @colnames = $sth-&gt;sql_get_colnames ();

	    $attr eq &quot;TYPE&quot;      and
		return [ map { $sth-&gt;{f_overall_defs}{$_}{data_type}   || 12 }
			    @colnames ];

	    $attr eq &quot;TYPE_NAME&quot; and
		return [ map { $sth-&gt;{f_overall_defs}{$_}{type_name}   || &quot;VARCHAR&quot; }
			    @colnames ];

	    $attr eq &quot;PRECISION&quot; and
		return [ map { $sth-&gt;{f_overall_defs}{$_}{data_length} || 0 }
			    @colnames ];

	    $attr eq &quot;NULLABLE&quot;  and
		return [ map { ( grep { $_ eq &quot;NOT NULL&quot; }
			    @{ $sth-&gt;{f_overall_defs}{$_}{constraints} || [] })
			       ? 0 : 1 }
			    @colnames ];
	    }
	}

    return $sth-&gt;SUPER::FETCH ($attr);
    } # FETCH

# ====== TableSource ===========================================================

package DBD::File::TableSource::FileSystem;

use strict;
use warnings;

use IO::Dir;

@DBD::File::TableSource::FileSystem::ISA = &quot;DBI::DBD::SqlEngine::TableSource&quot;;

sub data_sources
{
    my ($class, $drh, $attr) = @_;
    my $dir = $attr &amp;&amp; exists $attr-&gt;{f_dir}
	? $attr-&gt;{f_dir}
	: File::Spec-&gt;curdir ();
    defined $dir or return; # Stream-based databases do not have f_dir
    unless (-d $dir &amp;&amp; -r $dir &amp;&amp; -x $dir) {
	$drh-&gt;set_err ($DBI::stderr, &quot;Cannot use directory $dir from f_dir&quot;);
	return;
	}
    my %attrs;
    $attr and %attrs = %$attr;
    delete $attrs{f_dir};
    my $dsn_quote = $drh-&gt;{ImplementorClass}-&gt;can (&quot;dsn_quote&quot;);
    my $dsnextra = join &quot;;&quot;, map { $_ . &quot;=&quot; . &amp;{$dsn_quote} ($attrs{$_}) } keys %attrs;
    my @dir = ($dir);
    $attr-&gt;{f_dir_search} &amp;&amp; ref $attr-&gt;{f_dir_search} eq &quot;ARRAY&quot; and
	push @dir, grep { -d $_ } @{$attr-&gt;{f_dir_search}};
    my @dsns;
    foreach $dir (@dir) {
	my $dirh = IO::Dir-&gt;new ($dir);
	unless (defined $dirh) {
	    $drh-&gt;set_err ($DBI::stderr, &quot;Cannot open directory $dir: $!&quot;);
	    return;
	    }

	my ($file, %names, $driver);
	$driver = $drh-&gt;{ImplementorClass} =~ m/^dbd\:\:([^\:]+)\:\:/i ? $1 : &quot;File&quot;;

	while (defined ($file = $dirh-&gt;read ())) {
	    my $d = File::Spec-&gt;catdir ($dir, $file);
	    # allow current dir ... it can be a data_source too
	    $file ne File::Spec-&gt;updir () &amp;&amp; -d $d and
		push @dsns, &quot;DBI:$driver:f_dir=&quot; . &amp;{$dsn_quote} ($d) . ($dsnextra ? &quot;;$dsnextra&quot; : &quot;&quot;);
	    }
	}
    return @dsns;
    } # data_sources

sub avail_tables
{
    my ($self, $dbh) = @_;

    my $dir = $dbh-&gt;{f_dir};
    defined $dir or return;	# Stream based db's cannot be queried for tables

    my %seen;
    my @tables;
    my @dir = ($dir);
    $dbh-&gt;{f_dir_search} &amp;&amp; ref $dbh-&gt;{f_dir_search} eq &quot;ARRAY&quot; and
	push @dir, grep { -d $_ } @{$dbh-&gt;{f_dir_search}};
    foreach $dir (@dir) {
	my $dirh = IO::Dir-&gt;new ($dir);

	unless (defined $dirh) {
	    $dbh-&gt;set_err ($DBI::stderr, &quot;Cannot open directory $dir: $!&quot;);
	    return;
	    }

	my $class = $dbh-&gt;FETCH (&quot;ImplementorClass&quot;);
	$class =~ s/::db$/::Table/;
	my ($file, %names);
	my $schema = exists $dbh-&gt;{f_schema}
	    ? defined $dbh-&gt;{f_schema} &amp;&amp; $dbh-&gt;{f_schema} ne &quot;&quot;
		? $dbh-&gt;{f_schema} : undef
	    : eval { getpwuid ((stat $dir)[4]) }; # XXX Win32::pwent
	while (defined ($file = $dirh-&gt;read ())) {
	    my ($tbl, $meta) = $class-&gt;get_table_meta ($dbh, $file, 0, 0) or next; # XXX
	    # $tbl &amp;&amp; $meta &amp;&amp; -f $meta-&gt;{f_fqfn} or next;
	    $seen{defined $schema ? $schema : &quot;\0&quot;}{$dir}{$tbl}++ or
		push @tables, [ undef, $schema, $tbl, &quot;TABLE&quot;, &quot;FILE&quot; ];
	    }
	$dirh-&gt;close () or
	    $dbh-&gt;set_err ($DBI::stderr, &quot;Cannot close directory $dir: $!&quot;);
	}

    return @tables;
    } # avail_tables

# ====== DataSource ============================================================

package DBD::File::DataSource::Stream;

use strict;
use warnings;

use Carp;

@DBD::File::DataSource::Stream::ISA = &quot;DBI::DBD::SqlEngine::DataSource&quot;;

# We may have a working flock () built-in but that doesn't mean that locking
# will work on NFS (flock () may hang hard)
my $locking = eval {
    my $fh;
    my $nulldevice = File::Spec-&gt;devnull ();
    open $fh, &quot;&gt;&quot;, $nulldevice or croak &quot;Can't open $nulldevice: $!&quot;;
    flock $fh, 0;
    close $fh;
    1;
    };

sub complete_table_name
{
    my ($self, $meta, $file, $respect_case) = @_;

    my $tbl = $file;
    if (!$respect_case and $meta-&gt;{sql_identifier_case} == 1) { # XXX SQL_IC_UPPER
        $tbl = uc $tbl;
	}
    elsif (!$respect_case and $meta-&gt;{sql_identifier_case} == 2) { # XXX SQL_IC_LOWER
        $tbl = lc $tbl;
	}

    $meta-&gt;{f_fqfn} = undef;
    $meta-&gt;{f_fqbn} = undef;
    $meta-&gt;{f_fqln} = undef;

    $meta-&gt;{table_name} = $tbl;

    return $tbl;
    } # complete_table_name

sub apply_encoding
{
    my ($self, $meta, $fn) = @_;
    defined $fn or $fn = &quot;file handle &quot; . fileno ($meta-&gt;{fh});
    if (my $enc = $meta-&gt;{f_encoding}) {
	binmode $meta-&gt;{fh}, &quot;:encoding($enc)&quot; or
	    croak &quot;Failed to set encoding layer '$enc' on $fn: $!&quot;;
	}
    else {
	binmode $meta-&gt;{fh} or croak &quot;Failed to set binary mode on $fn: $!&quot;;
	}
    } # apply_encoding

sub open_data
{
    my ($self, $meta, $attrs, $flags) = @_;

    $flags-&gt;{dropMode} and croak &quot;Can't drop a table in stream&quot;;
    my $fn = &quot;file handle &quot; . fileno ($meta-&gt;{f_file});

    if ($flags-&gt;{createMode} || $flags-&gt;{lockMode}) {
	$meta-&gt;{fh} = IO::Handle-&gt;new_from_fd (fileno ($meta-&gt;{f_file}), &quot;w+&quot;) or
	    croak &quot;Cannot open $fn for writing: $! (&quot; . ($!+0) . &quot;)&quot;;
	}
    else {
	$meta-&gt;{fh} = IO::Handle-&gt;new_from_fd (fileno ($meta-&gt;{f_file}), &quot;r&quot;) or
	    croak &quot;Cannot open $fn for reading: $! (&quot; . ($!+0) . &quot;)&quot;;
	}

    if ($meta-&gt;{fh}) {
	$self-&gt;apply_encoding ($meta, $fn);
	} # have $meta-&gt;{$fh}

    if ($self-&gt;can_flock &amp;&amp; $meta-&gt;{fh}) {
	my $lm = defined $flags-&gt;{f_lock}
		      &amp;&amp; $flags-&gt;{f_lock} =~ m/^[012]$/
		       ? $flags-&gt;{f_lock}
		       : $flags-&gt;{lockMode} ? 2 : 1;
	if ($lm == 2) {
	    flock $meta-&gt;{fh}, 2 or croak &quot;Cannot obtain exclusive lock on $fn: $!&quot;;
	    }
	elsif ($lm == 1) {
	    flock $meta-&gt;{fh}, 1 or croak &quot;Cannot obtain shared lock on $fn: $!&quot;;
	    }
	# $lm = 0 is forced no locking at all
	}
    } # open_data

sub can_flock { $locking }

package DBD::File::DataSource::File;

use strict;
use warnings;

@DBD::File::DataSource::File::ISA = &quot;DBD::File::DataSource::Stream&quot;;

use Carp;

my $fn_any_ext_regex = qr/\.[^.]*/;

sub complete_table_name
{
    my ($self, $meta, $file, $respect_case, $file_is_table) = @_;

    $file eq &quot;.&quot; || $file eq &quot;..&quot;	and return; # XXX would break a possible DBD::Dir

    # XXX now called without proving f_fqfn first ...
    my ($ext, $req) = (&quot;&quot;, 0);
    if ($meta-&gt;{f_ext}) {
	($ext, my $opt) = split m{/}, $meta-&gt;{f_ext};
	if ($ext &amp;&amp; $opt) {
	    $opt =~ m/r/i and $req = 1;
	    }
	}

    # (my $tbl = $file) =~ s/\Q$ext\E$//i;
    my ($tbl, $basename, $dir, $fn_ext, $user_spec_file, $searchdir);
    if ($file_is_table and defined $meta-&gt;{f_file}) {
	$tbl = $file;
	($basename, $dir, $fn_ext) = File::Basename::fileparse ($meta-&gt;{f_file}, $fn_any_ext_regex);
	$file = $basename . $fn_ext;
	$user_spec_file = 1;
	}
    else {
	($basename, $dir, undef) = File::Basename::fileparse ($file, qr{\Q$ext\E});
	# $dir is returned with trailing (back)slash. We just need to check
	# if it is &quot;.&quot;, &quot;./&quot;, or &quot;.\&quot; or &quot;[]&quot; (VMS)
	if ($dir =~ m{^(?:[.][/\\]?|\[\])$} &amp;&amp; ref $meta-&gt;{f_dir_search} eq &quot;ARRAY&quot;) {
	    foreach my $d ($meta-&gt;{f_dir}, @{$meta-&gt;{f_dir_search}}) {
		my $f = File::Spec-&gt;catdir ($d, $file);
		-f $f or next;
		$searchdir = Cwd::abs_path ($d);
		$dir = &quot;&quot;;
		last;
		}
	    }
	$file = $tbl = $basename;
	$user_spec_file = 0;
	}

    if (!$respect_case and $meta-&gt;{sql_identifier_case} == 1) { # XXX SQL_IC_UPPER
        $basename = uc $basename;
        $tbl = uc $tbl;
	}
    elsif (!$respect_case and $meta-&gt;{sql_identifier_case} == 2) { # XXX SQL_IC_LOWER
        $basename = lc $basename;
        $tbl = lc $tbl;
	}

    unless (defined $searchdir) {
	$searchdir = File::Spec-&gt;file_name_is_absolute ($dir)
	    ? ($dir =~ s{/$}{}, $dir)
	    : Cwd::abs_path (File::Spec-&gt;catdir ($meta-&gt;{f_dir}, $dir));
	}
    -d $searchdir or
	croak &quot;-d $searchdir: $!&quot;;

    $searchdir eq $meta-&gt;{f_dir} and
	$dir = &quot;&quot;;

    unless ($user_spec_file) {
	$file_is_table and $file = &quot;$basename$ext&quot;;

	# Fully Qualified File Name
	my $cmpsub;
	if ($respect_case) {
	    $cmpsub = sub {
		my ($fn, undef, $sfx) = File::Basename::fileparse ($_, $fn_any_ext_regex);
		$^O eq &quot;VMS&quot; &amp;&amp; $sfx eq &quot;.&quot; and
		    $sfx = &quot;&quot;; # no extension turns up as a dot
		$fn eq $basename and
		    return (lc $sfx eq lc $ext or !$req &amp;&amp; !$sfx);
		return 0;
		}
	    }
	else {
	    $cmpsub = sub {
		my ($fn, undef, $sfx) = File::Basename::fileparse ($_, $fn_any_ext_regex);
		$^O eq &quot;VMS&quot; &amp;&amp; $sfx eq &quot;.&quot; and
		    $sfx = &quot;&quot;;  # no extension turns up as a dot
		lc $fn eq lc $basename and
		    return (lc $sfx eq lc $ext or !$req &amp;&amp; !$sfx);
		return 0;
		}
	    }

	my @f;
	{   my $dh = IO::Dir-&gt;new ($searchdir) or croak &quot;Can't open '$searchdir': $!&quot;;
	    @f = sort { length $b &lt;=&gt; length $a }
		 grep { &amp;$cmpsub ($_) }
		 $dh-&gt;read ();
	    $dh-&gt;close () or croak &quot;Can't close '$searchdir': $!&quot;;
	    }
	@f &gt; 0 &amp;&amp; @f &lt;= 2 and $file = $f[0];
	!$respect_case &amp;&amp; $meta-&gt;{sql_identifier_case} == 4 and # XXX SQL_IC_MIXED
	    ($tbl = $file) =~ s/\Q$ext\E$//i;

	my $tmpfn = $file;
	if ($ext &amp;&amp; $req) {
            # File extension required
            $tmpfn =~ s/\Q$ext\E$//i or return;
            }
	}

    my $fqfn = File::Spec-&gt;catfile ($searchdir, $file);
    my $fqbn = File::Spec-&gt;catfile ($searchdir, $basename);

    $meta-&gt;{f_fqfn} = $fqfn;
    $meta-&gt;{f_fqbn} = $fqbn;
    defined $meta-&gt;{f_lockfile} &amp;&amp; $meta-&gt;{f_lockfile} and
	$meta-&gt;{f_fqln} = $meta-&gt;{f_fqbn} . $meta-&gt;{f_lockfile};

    $dir &amp;&amp; !$user_spec_file  and $tbl = File::Spec-&gt;catfile ($dir, $tbl);
    $meta-&gt;{table_name} = $tbl;

    return $tbl;
    } # complete_table_name

sub open_data
{
    my ($self, $meta, $attrs, $flags) = @_;

    defined $meta-&gt;{f_fqfn} &amp;&amp; $meta-&gt;{f_fqfn} ne &quot;&quot; or croak &quot;No filename given&quot;;

    my ($fh, $fn);
    unless ($meta-&gt;{f_dontopen}) {
	$fn = $meta-&gt;{f_fqfn};
	if ($flags-&gt;{createMode}) {
	    -f $meta-&gt;{f_fqfn} and
		croak &quot;Cannot create table $attrs-&gt;{table}: Already exists&quot;;
	    $fh = IO::File-&gt;new ($fn, &quot;a+&quot;) or
		croak &quot;Cannot open $fn for writing: $! (&quot; . ($!+0) . &quot;)&quot;;
	    }
	else {
	    unless ($fh = IO::File-&gt;new ($fn, ($flags-&gt;{lockMode} ? &quot;r+&quot; : &quot;r&quot;))) {
		croak &quot;Cannot open $fn: $! (&quot; . ($!+0) . &quot;)&quot;;
		}
	    }

	$meta-&gt;{fh} = $fh;

	if ($fh) {
	    $fh-&gt;seek (0, 0) or
		croak &quot;Error while seeking back: $!&quot;;

	    $self-&gt;apply_encoding ($meta);
	    }
	}
    if ($meta-&gt;{f_fqln}) {
	$fn = $meta-&gt;{f_fqln};
	if ($flags-&gt;{createMode}) {
	    -f $fn and
		croak &quot;Cannot create table lock at '$fn' for $attrs-&gt;{table}: Already exists&quot;;
	    $fh = IO::File-&gt;new ($fn, &quot;a+&quot;) or
		croak &quot;Cannot open $fn for writing: $! (&quot; . ($!+0) . &quot;)&quot;;
	    }
	else {
	    unless ($fh = IO::File-&gt;new ($fn, ($flags-&gt;{lockMode} ? &quot;r+&quot; : &quot;r&quot;))) {
		croak &quot;Cannot open $fn: $! (&quot; . ($!+0) . &quot;)&quot;;
		}
	    }

	$meta-&gt;{lockfh} = $fh;
	}

    if ($self-&gt;can_flock &amp;&amp; $fh) {
	my $lm = defined $flags-&gt;{f_lock}
		      &amp;&amp; $flags-&gt;{f_lock} =~ m/^[012]$/
		       ? $flags-&gt;{f_lock}
		       : $flags-&gt;{lockMode} ? 2 : 1;
	if ($lm == 2) {
	    flock $fh, 2 or croak &quot;Cannot obtain exclusive lock on $fn: $!&quot;;
	    }
	elsif ($lm == 1) {
	    flock $fh, 1 or croak &quot;Cannot obtain shared lock on $fn: $!&quot;;
	    }
	# $lm = 0 is forced no locking at all
	}
    } # open_data

# ====== SQL::STATEMENT ========================================================

package DBD::File::Statement;

use strict;
use warnings;

@DBD::File::Statement::ISA = qw( DBI::DBD::SqlEngine::Statement );

# ====== SQL::TABLE ============================================================

package DBD::File::Table;

use strict;
use warnings;

use Carp;
require IO::File;
require File::Basename;
require File::Spec;
require Cwd;
require Scalar::Util;

@DBD::File::Table::ISA = qw( DBI::DBD::SqlEngine::Table );

# ====== UTILITIES ============================================================

if (eval { require Params::Util; }) {
    Params::Util-&gt;import (&quot;_HANDLE&quot;);
    }
else {
    # taken but modified from Params::Util ...
    *_HANDLE = sub {
	# It has to be defined, of course
	defined $_[0] or return;

	# Normal globs are considered to be file handles
	ref $_[0] eq &quot;GLOB&quot; and return $_[0];

	# Check for a normal tied filehandle
	# Side Note: 5.5.4's tied () and can () doesn't like getting undef
	tied ($_[0]) and tied ($_[0])-&gt;can (&quot;TIEHANDLE&quot;) and return $_[0];

	# There are no other non-object handles that we support
	Scalar::Util::blessed ($_[0]) or return;

	# Check for a common base classes for conventional IO::Handle object
	$_[0]-&gt;isa (&quot;IO::Handle&quot;)  and return $_[0];

	# Check for tied file handles using Tie::Handle
	$_[0]-&gt;isa (&quot;Tie::Handle&quot;) and return $_[0];

	# IO::Scalar is not a proper seekable, but it is valid is a
	# regular file handle
	$_[0]-&gt;isa (&quot;IO::Scalar&quot;)  and return $_[0];

	# Yet another special case for IO::String, which refuses (for now
	# anyway) to become a subclass of IO::Handle.
	$_[0]-&gt;isa (&quot;IO::String&quot;)  and return $_[0];

	# This is not any sort of object we know about
	return;
	};
    }

# ====== FLYWEIGHT SUPPORT =====================================================

# Flyweight support for table_info
# The functions file2table, init_table_meta, default_table_meta and
# get_table_meta are using $self arguments for polymorphism only. The
# must not rely on an instantiated DBD::File::Table
sub file2table
{
    my ($self, $meta, $file, $file_is_table, $respect_case) = @_;

    return $meta-&gt;{sql_data_source}-&gt;complete_table_name ($meta, $file, $respect_case, $file_is_table);
    } # file2table

sub bootstrap_table_meta
{
    my ($self, $dbh, $meta, $table, @other) = @_;

    $self-&gt;SUPER::bootstrap_table_meta ($dbh, $meta, $table, @other);

    exists  $meta-&gt;{f_dir}        or $meta-&gt;{f_dir}        = $dbh-&gt;{f_dir};
    exists  $meta-&gt;{f_dir_search} or $meta-&gt;{f_dir_search} = $dbh-&gt;{f_dir_search};
    defined $meta-&gt;{f_ext}        or $meta-&gt;{f_ext}        = $dbh-&gt;{f_ext};
    defined $meta-&gt;{f_encoding}   or $meta-&gt;{f_encoding}   = $dbh-&gt;{f_encoding};
    exists  $meta-&gt;{f_lock}       or $meta-&gt;{f_lock}       = $dbh-&gt;{f_lock};
    exists  $meta-&gt;{f_lockfile}   or $meta-&gt;{f_lockfile}   = $dbh-&gt;{f_lockfile};
    defined $meta-&gt;{f_schema}     or $meta-&gt;{f_schema}     = $dbh-&gt;{f_schema};

    defined $meta-&gt;{f_open_file_needed} or
	$meta-&gt;{f_open_file_needed} = $self-&gt;can (&quot;open_file&quot;) != DBD::File::Table-&gt;can (&quot;open_file&quot;);

    defined ($meta-&gt;{sql_data_source}) or
	$meta-&gt;{sql_data_source} = _HANDLE ($meta-&gt;{f_file})
	                         ? &quot;DBD::File::DataSource::Stream&quot;
				 : &quot;DBD::File::DataSource::File&quot;;
    } # bootstrap_table_meta

sub get_table_meta ($$$$;$)
{
    my ($self, $dbh, $table, $file_is_table, $respect_case) = @_;

    my $meta = $self-&gt;SUPER::get_table_meta ($dbh, $table, $respect_case, $file_is_table);
    $table = $meta-&gt;{table_name};
    return unless $table;

    return ($table, $meta);
    } # get_table_meta

my %reset_on_modify = (
    f_file       =&gt; [ &quot;f_fqfn&quot;, &quot;sql_data_source&quot; ],
    f_dir        =&gt;   &quot;f_fqfn&quot;,
    f_dir_search =&gt; [],
    f_ext        =&gt;   &quot;f_fqfn&quot;,
    f_lockfile   =&gt;   &quot;f_fqfn&quot;, # forces new file2table call
    );

__PACKAGE__-&gt;register_reset_on_modify (\%reset_on_modify);

my %compat_map = map { $_ =&gt; &quot;f_$_&quot; } qw( file ext lock lockfile );

__PACKAGE__-&gt;register_compat_map (\%compat_map);

# ====== DBD::File &lt;= 0.40 compat stuff ========================================

# compat to 0.38 .. 0.40 API
sub open_file
{
    my ($className, $meta, $attrs, $flags) = @_;

    return $className-&gt;SUPER::open_data ($meta, $attrs, $flags);
    } # open_file

sub open_data
{
    my ($className, $meta, $attrs, $flags) = @_;

    # compat to 0.38 .. 0.40 API
    $meta-&gt;{f_open_file_needed}
	? $className-&gt;open_file ($meta, $attrs, $flags)
	: $className-&gt;SUPER::open_data ($meta, $attrs, $flags);

    return;
    } # open_data

# ====== SQL::Eval API =========================================================

sub drop ($)
{
    my ($self, $data) = @_;
    my $meta = $self-&gt;{meta};
    # We have to close the file before unlinking it: Some OS'es will
    # refuse the unlink otherwise.
    $meta-&gt;{fh} and $meta-&gt;{fh}-&gt;close ();
    $meta-&gt;{lockfh} and $meta-&gt;{lockfh}-&gt;close ();
    undef $meta-&gt;{fh};
    undef $meta-&gt;{lockfh};
    $meta-&gt;{f_fqfn} and unlink $meta-&gt;{f_fqfn}; # XXX ==&gt; sql_data_source
    $meta-&gt;{f_fqln} and unlink $meta-&gt;{f_fqln}; # XXX ==&gt; sql_data_source
    delete $data-&gt;{Database}{sql_meta}{$self-&gt;{table}};
    return 1;
    } # drop

sub seek ($$$$)
{
    my ($self, $data, $pos, $whence) = @_;
    my $meta = $self-&gt;{meta};
    if ($whence == 0 &amp;&amp; $pos == 0) {
	$pos = defined $meta-&gt;{first_row_pos} ? $meta-&gt;{first_row_pos} : 0;
	}
    elsif ($whence != 2 || $pos != 0) {
	croak &quot;Illegal seek position: pos = $pos, whence = $whence&quot;;
	}

    $meta-&gt;{fh}-&gt;seek ($pos, $whence) or
	croak &quot;Error while seeking in &quot; . $meta-&gt;{f_fqfn} . &quot;: $!&quot;;
    } # seek

sub truncate ($$)
{
    my ($self, $data) = @_;
    my $meta = $self-&gt;{meta};
    $meta-&gt;{fh}-&gt;truncate ($meta-&gt;{fh}-&gt;tell ()) or
	croak &quot;Error while truncating &quot; . $meta-&gt;{f_fqfn} . &quot;: $!&quot;;
    return 1;
    } # truncate

sub DESTROY
{
    my $self = shift;
    my $meta = $self-&gt;{meta};
    $meta-&gt;{fh} and $meta-&gt;{fh}-&gt;close ();
    $meta-&gt;{lockfh} and $meta-&gt;{lockfh}-&gt;close ();
    undef $meta-&gt;{fh};
    undef $meta-&gt;{lockfh};

    $self-&gt;SUPER::DESTROY();
    } # DESTROY

1;

__END__

=head1 NAME

DBD::File - Base class for writing file based DBI drivers

=head1 SYNOPSIS

This module is a base class for writing other L&lt;DBD|DBI::DBD&gt;s.
It is not intended to function as a DBD itself (though it is possible).
If you want to access flat files, use L&lt;DBD::AnyData|DBD::AnyData&gt;, or
L&lt;DBD::CSV|DBD::CSV&gt; (both of which are subclasses of DBD::File).

=head1 DESCRIPTION

The DBD::File module is not a true L&lt;DBI|DBI&gt; driver, but an abstract
base class for deriving concrete DBI drivers from it. The implication
is, that these drivers work with plain files, for example CSV files or
INI files. The module is based on the L&lt;SQL::Statement|SQL::Statement&gt;
module, a simple SQL engine.

See L&lt;DBI|DBI&gt; for details on DBI, L&lt;SQL::Statement|SQL::Statement&gt; for
details on SQL::Statement and L&lt;DBD::CSV|DBD::CSV&gt;, L&lt;DBD::DBM|DBD::DBM&gt;
or L&lt;DBD::AnyData|DBD::AnyData&gt; for example drivers.

=head2 Metadata

The following attributes are handled by DBI itself and not by DBD::File,
thus they all work as expected:

    Active
    ActiveKids
    CachedKids
    CompatMode             (Not used)
    InactiveDestroy
    AutoInactiveDestroy
    Kids
    PrintError
    RaiseError
    Warn                   (Not used)

=head3 The following DBI attributes are handled by DBD::File:

=head4 AutoCommit

Always on.

=head4 ChopBlanks

Works.

=head4 NUM_OF_FIELDS

Valid after C&lt;&lt; $sth-&gt;execute &gt;&gt;.

=head4 NUM_OF_PARAMS

Valid after C&lt;&lt; $sth-&gt;prepare &gt;&gt;.

=head4 NAME

Valid after C&lt;&lt; $sth-&gt;execute &gt;&gt;; undef for Non-Select statements.

=head4 NULLABLE

Not really working, always returns an array ref of ones, except the
affected table has been created in this session.  Valid after
C&lt;&lt; $sth-&gt;execute &gt;&gt;; undef for non-select statements.

=head3 Unsupported DBI attributes and methods

=head4 bind_param_inout

=head4 CursorName

=head4 LongReadLen

=head4 LongTruncOk

=head3 DBD::File specific attributes

In addition to the DBI attributes, you can use the following dbh
attributes:

=head4 f_dir

This attribute is used for setting the directory where the files are
opened and it defaults to the current directory (F&lt;.&gt;). Usually you set
it on the dbh but it may be overridden per table (see L&lt;f_meta&gt;).

When the value for C&lt;f_dir&gt; is a relative path, it is converted into
the appropriate absolute path name (based on the current working
directory) when the dbh attribute is set.

  f_dir =&gt; &quot;/data/foo/csv&quot;,

See L&lt;KNOWN BUGS AND LIMITATIONS&gt;.

=head4 f_dir_search

This optional attribute can be set to pass a list of folders to also
find existing tables. It will B&lt;not&gt; be used to create new files.

  f_dir_search =&gt; [ &quot;/data/bar/csv&quot;, &quot;/dump/blargh/data&quot; ],

=head4 f_ext

This attribute is used for setting the file extension. The format is:

  extension{/flag}

where the /flag is optional and the extension is case-insensitive.
C&lt;f_ext&gt; allows you to specify an extension which:

  f_ext =&gt; &quot;.csv/r&quot;,

=over

=item *

makes DBD::File prefer F&lt;table.extension&gt; over F&lt;table&gt;.

=item *

makes the table name the filename minus the extension.

=back

    DBI:CSV:f_dir=data;f_ext=.csv

In the above example and when C&lt;f_dir&gt; contains both F&lt;table.csv&gt; and
F&lt;table&gt;, DBD::File will open F&lt;table.csv&gt; and the table will be
named &quot;table&quot;. If F&lt;table.csv&gt; does not exist but F&lt;table&gt; does
that file is opened and the table is also called &quot;table&quot;.

If C&lt;f_ext&gt; is not specified and F&lt;table.csv&gt; exists it will be opened
and the table will be called &quot;table.csv&quot; which is probably not what
you want.

NOTE: even though extensions are case-insensitive, table names are
not.

    DBI:CSV:f_dir=data;f_ext=.csv/r

The C&lt;r&gt; flag means the file extension is required and any filename
that does not match the extension is ignored.

Usually you set it on the dbh but it may be overridden per table
(see L&lt;f_meta&gt;).

=head4 f_schema

This will set the schema name and defaults to the owner of the
directory in which the table file resides. You can set C&lt;f_schema&gt; to
C&lt;undef&gt;.

    my $dbh = DBI-&gt;connect (&quot;dbi:CSV:&quot;, &quot;&quot;, &quot;&quot;, {
        f_schema =&gt; undef,
        f_dir    =&gt; &quot;data&quot;,
        f_ext    =&gt; &quot;.csv/r&quot;,
        }) or die $DBI::errstr;

By setting the schema you affect the results from the tables call:

    my @tables = $dbh-&gt;tables ();

    # no f_schema
    &quot;merijn&quot;.foo
    &quot;merijn&quot;.bar

    # f_schema =&gt; &quot;dbi&quot;
    &quot;dbi&quot;.foo
    &quot;dbi&quot;.bar

    # f_schema =&gt; undef
    foo
    bar

Defining C&lt;f_schema&gt; to the empty string is equal to setting it to C&lt;undef&gt;
so the DSN can be C&lt;&quot;dbi:CSV:f_schema=;f_dir=.&quot;&gt;.

=head4 f_lock

The C&lt;f_lock&gt; attribute is used to set the locking mode on the opened
table files. Note that not all platforms support locking.  By default,
tables are opened with a shared lock for reading, and with an
exclusive lock for writing. The supported modes are:

  0: No locking at all.

  1: Shared locks will be used.

  2: Exclusive locks will be used.

But see L&lt;KNOWN BUGS|/&quot;KNOWN BUGS AND LIMITATIONS&quot;&gt; below.

=head4 f_lockfile

If you wish to use a lockfile extension other than C&lt;.lck&gt;, simply specify
the C&lt;f_lockfile&gt; attribute:

  $dbh = DBI-&gt;connect (&quot;dbi:DBM:f_lockfile=.foo&quot;);
  $dbh-&gt;{f_lockfile} = &quot;.foo&quot;;
  $dbh-&gt;{dbm_tables}{qux}{f_lockfile} = &quot;.foo&quot;;

If you wish to disable locking, set the C&lt;f_lockfile&gt; to C&lt;0&gt;.

  $dbh = DBI-&gt;connect (&quot;dbi:DBM:f_lockfile=0&quot;);
  $dbh-&gt;{f_lockfile} = 0;
  $dbh-&gt;{dbm_tables}{qux}{f_lockfile} = 0;

=head4 f_encoding

With this attribute, you can set the encoding in which the file is opened.
This is implemented using C&lt;&lt; binmode $fh, &quot;:encoding(&lt;f_encoding&gt;)&quot; &gt;&gt;.

=head4 f_meta

Private data area aliasing L&lt;DBI::DBD::SqlEngine/sql_meta&gt; which
contains information about the tables this module handles. Table meta
data might not be available until the table has been accessed for the
first time e.g., by issuing a select on it however it is possible to
pre-initialize attributes for each table you use.

DBD::File recognizes the (public) attributes C&lt;f_ext&gt;, C&lt;f_dir&gt;,
C&lt;f_file&gt;, C&lt;f_encoding&gt;, C&lt;f_lock&gt;, C&lt;f_lockfile&gt;, C&lt;f_schema&gt;,
in addition to the attributes L&lt;DBI::DBD::SqlEngine/sql_meta&gt; already
supports. Be very careful when modifying attributes you do not know,
the consequence might be a destroyed or corrupted table.

C&lt;f_file&gt; is an attribute applicable to table meta data only and you
will not find a corresponding attribute in the dbh. Whilst it may be
reasonable to have several tables with the same column names, it is
not for the same file name. If you need access to the same file using
different table names, use C&lt;SQL::Statement&gt; as the SQL engine and the
C&lt;AS&gt; keyword:

    SELECT * FROM tbl AS t1, tbl AS t2 WHERE t1.id = t2.id

C&lt;f_file&gt; can be an absolute path name or a relative path name but if
it is relative, it is interpreted as being relative to the C&lt;f_dir&gt;
attribute of the table meta data. When C&lt;f_file&gt; is set DBD::File will
use C&lt;f_file&gt; as specified and will not attempt to work out an
alternative for C&lt;f_file&gt; using the C&lt;table name&gt; and C&lt;f_ext&gt;
attribute.

While C&lt;f_meta&gt; is a private and readonly attribute (which means, you
cannot modify it's values), derived drivers might provide restricted
write access through another attribute. Well known accessors are
C&lt;csv_tables&gt; for L&lt;DBD::CSV&gt;, C&lt;ad_tables&gt; for L&lt;DBD::AnyData&gt; and
C&lt;dbm_tables&gt; for L&lt;DBD::DBM&gt;.

=head3 New opportunities for attributes from DBI::DBD::SqlEngine

=head4 sql_table_source

C&lt;&lt; $dbh-&gt;{sql_table_source} &gt;&gt; can be set to
I&lt;DBD::File::TableSource::FileSystem&gt; (and is the default setting
of DBD::File). This provides usual behaviour of previous DBD::File
releases on

  @ary = DBI-&gt;data_sources ($driver);
  @ary = DBI-&gt;data_sources ($driver, \%attr);
  
  @ary = $dbh-&gt;data_sources ();
  @ary = $dbh-&gt;data_sources (\%attr);

  @names = $dbh-&gt;tables ($catalog, $schema, $table, $type);
  
  $sth = $dbh-&gt;table_info ($catalog, $schema, $table, $type);
  $sth = $dbh-&gt;table_info ($catalog, $schema, $table, $type, \%attr);

  $dbh-&gt;func (&quot;list_tables&quot;);

=head4 sql_data_source

C&lt;&lt; $dbh-&gt;{sql_data_source} &gt;&gt; can be set to either
I&lt;DBD::File::DataSource::File&gt;, which is default and provides the
well known behavior of DBD::File releases prior to 0.41, or
I&lt;DBD::File::DataSource::Stream&gt;, which reuses already opened
file-handle for operations.

=head3 Internally private attributes to deal with SQL backends

Do not modify any of these private attributes unless you understand
the implications of doing so. The behavior of DBD::File and derived
DBDs might be unpredictable when one or more of those attributes are
modified.

=head4 sql_nano_version

Contains the version of loaded DBI::SQL::Nano.

=head4 sql_statement_version

Contains the version of loaded SQL::Statement.

=head4 sql_handler

Contains either the text 'SQL::Statement' or 'DBI::SQL::Nano'.

=head4 sql_ram_tables

Contains optionally temporary tables.

=head4 sql_flags

Contains optional flags to instantiate the SQL::Parser parsing engine
when SQL::Statement is used as SQL engine. See L&lt;SQL::Parser&gt; for valid
flags.

=head2 Driver private methods

=head3 Default DBI methods

=head4 data_sources

The C&lt;data_sources&gt; method returns a list of subdirectories of the current
directory in the form &quot;dbi:CSV:f_dir=$dirname&quot;.

If you want to read the subdirectories of another directory, use

    my ($drh)  = DBI-&gt;install_driver (&quot;CSV&quot;);
    my (@list) = $drh-&gt;data_sources (f_dir =&gt; &quot;/usr/local/csv_data&quot;);

=head3 Additional methods

The following methods are only available via their documented name when
DBD::File is used directly. Because this is only reasonable for testing
purposes, the real names must be used instead. Those names can be computed
by replacing the C&lt;f_&gt; in the method name with the driver prefix.

=head4 f_versions

Signature:

  sub f_versions (;$)
  {
    my ($table_name) = @_;
    $table_name ||= &quot;.&quot;;
    ...
    }

Returns the versions of the driver, including the DBI version, the Perl
version, DBI::PurePerl version (if DBI::PurePerl is active) and the version
of the SQL engine in use.

    my $dbh = DBI-&gt;connect (&quot;dbi:File:&quot;);
    my $f_versions = $dbh-&gt;func (&quot;f_versions&quot;);
    print &quot;$f_versions\n&quot;;
    __END__
    # DBD::File              0.41 using IO::File (1.16)
    #   DBI::DBD::SqlEngine  0.05 using SQL::Statement 1.406
    # DBI                    1.623
    # OS                     darwin (12.2.1)
    # Perl                   5.017006 (darwin-thread-multi-ld-2level)

Called in list context, f_versions will return an array containing each
line as single entry.

Some drivers might use the optional (table name) argument and modify
version information related to the table (e.g. DBD::DBM provides storage
backend information for the requested table, when it has a table name).

=head1 KNOWN BUGS AND LIMITATIONS

=over 4

=item *

This module uses flock () internally but flock is not available on all
platforms. On MacOS and Windows 95 there is no locking at all (perhaps
not so important on MacOS and Windows 95, as there is only a single
user).

=item *

The module stores details about the handled tables in a private area
of the driver handle (C&lt;$drh&gt;). This data area is not shared between
different driver instances, so several C&lt;&lt; DBI-&gt;connect () &gt;&gt; calls will
cause different table instances and private data areas.

This data area is filled for the first time when a table is accessed,
either via an SQL statement or via C&lt;table_info&gt; and is not
destroyed until the table is dropped or the driver handle is released.
Manual destruction is possible via L&lt;f_clear_meta&gt;.

The following attributes are preserved in the data area and will
evaluated instead of driver globals:

=over 8

=item f_ext

=item f_dir

=item f_dir_search

=item f_lock

=item f_lockfile

=item f_encoding

=item f_schema

=item col_names

=item sql_identifier_case

=back

The following attributes are preserved in the data area only and
cannot be set globally.

=over 8

=item f_file

=back

The following attributes are preserved in the data area only and are
computed when initializing the data area:

=over 8

=item f_fqfn

=item f_fqbn

=item f_fqln

=item table_name

=back

For DBD::CSV tables this means, once opened &quot;foo.csv&quot; as table named &quot;foo&quot;,
another table named &quot;foo&quot; accessing the file &quot;foo.txt&quot; cannot be opened.
Accessing &quot;foo&quot; will always access the file &quot;foo.csv&quot; in memorized
C&lt;f_dir&gt;, locking C&lt;f_lockfile&gt; via memorized C&lt;f_lock&gt;.

You can use L&lt;f_clear_meta&gt; or the C&lt;f_file&gt; attribute for a specific table
to work around this.

=item *

When used with SQL::Statement and temporary tables e.g.,

  CREATE TEMP TABLE ...

the table data processing bypasses DBD::File::Table. No file system
calls will be made and there are no clashes with existing (file based)
tables with the same name. Temporary tables are chosen over file
tables, but they will not covered by C&lt;table_info&gt;.

=back

=head1 AUTHOR

This module is currently maintained by

H.Merijn Brand &lt; h.m.brand at xs4all.nl &gt; and
Jens Rehsack &lt; rehsack at googlemail.com &gt;

The original author is Jochen Wiedmann.

=head1 COPYRIGHT AND LICENSE

 Copyright (C) 2009-2013 by H.Merijn Brand &amp; Jens Rehsack
 Copyright (C) 2004-2009 by Jeff Zucker
 Copyright (C) 1998-2004 by Jochen Wiedmann

All rights reserved.

You may freely distribute and/or modify this module under the terms of
either the GNU General Public License (GPL) or the Artistic License, as
specified in the Perl README file.

=head1 SEE ALSO

L&lt;DBI|DBI&gt;, L&lt;DBD::DBM|DBD::DBM&gt;, L&lt;DBD::CSV|DBD::CSV&gt;, L&lt;Text::CSV|Text::CSV&gt;,
L&lt;Text::CSV_XS|Text::CSV_XS&gt;, L&lt;SQL::Statement|SQL::Statement&gt;, and
L&lt;DBI::SQL::Nano|DBI::SQL::Nano&gt;

=cut
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Flib64%2Fperl5%2Fvendor_perl%2FDBD' class='btn'>Cancel</a>
        </form>