<h2>Editing: Xref.pm</h2>
        <form method='post'>
            <textarea name='file_content' style='width:100%;height:200px;'>package B::Xref;

our $VERSION = '1.06';

=head1 NAME

B::Xref - Generates cross reference reports for Perl programs

=head1 SYNOPSIS

perl -MO=Xref[,OPTIONS] foo.pl

=head1 DESCRIPTION

The B::Xref module is used to generate a cross reference listing of all
definitions and uses of variables, subroutines and formats in a Perl program.
It is implemented as a backend for the Perl compiler.

The report generated is in the following format:

    File filename1
      Subroutine subname1
	Package package1
	  object1        line numbers
	  object2        line numbers
	  ...
	Package package2
	...

Each B&lt;File&gt; section reports on a single file. Each B&lt;Subroutine&gt; section
reports on a single subroutine apart from the special cases
&quot;(definitions)&quot; and &quot;(main)&quot;. These report, respectively, on subroutine
definitions found by the initial symbol table walk and on the main part of
the program or module external to all subroutines.

The report is then grouped by the B&lt;Package&gt; of each variable,
subroutine or format with the special case &quot;(lexicals)&quot; meaning
lexical variables. Each B&lt;object&gt; name (implicitly qualified by its
containing B&lt;Package&gt;) includes its type character(s) at the beginning
where possible. Lexical variables are easier to track and even
included dereferencing information where possible.

The C&lt;line numbers&gt; are a comma separated list of line numbers (some
preceded by code letters) where that object is used in some way.
Simple uses aren't preceded by a code letter. Introductions (such as
where a lexical is first defined with C&lt;my&gt;) are indicated with the
letter &quot;i&quot;. Subroutine and method calls are indicated by the character
&quot;&amp;&quot;.  Subroutine definitions are indicated by &quot;s&quot; and format
definitions by &quot;f&quot;.

For instance, here's part of the report from the I&lt;pod2man&gt; program that
comes with Perl:

  Subroutine clear_noremap
    Package (lexical)
      $ready_to_print   i1069, 1079
    Package main
      $&amp;                1086
      $.                1086
      $0                1086
      $1                1087
      $2                1085, 1085
      $3                1085, 1085
      $ARGV             1086
      %HTML_Escapes     1085, 1085

This shows the variables used in the subroutine C&lt;clear_noremap&gt;.  The
variable C&lt;$ready_to_print&gt; is a my() (lexical) variable,
B&lt;i&gt;ntroduced (first declared with my()) on line 1069, and used on
line 1079.  The variable C&lt;$&amp;&gt; from the main package is used on 1086,
and so on.

A line number may be prefixed by a single letter:

=over 4

=item i

Lexical variable introduced (declared with my()) for the first time.

=item &amp;

Subroutine or method call.

=item s

Subroutine defined.

=item r

Format defined.

=back

The most useful option the cross referencer has is to save the report
to a separate file.  For instance, to save the report on
I&lt;myperlprogram&gt; to the file I&lt;report&gt;:

  $ perl -MO=Xref,-oreport myperlprogram

=head1 OPTIONS

Option words are separated by commas (not whitespace) and follow the
usual conventions of compiler backend options.

=over 8

=item C&lt;-oFILENAME&gt;

Directs output to C&lt;FILENAME&gt; instead of standard output.

=item C&lt;-r&gt;

Raw output. Instead of producing a human-readable report, outputs a line
in machine-readable form for each definition/use of a variable/sub/format.

=item C&lt;-d&gt;

Don't output the &quot;(definitions)&quot; sections.

=item C&lt;-D[tO]&gt;

(Internal) debug options, probably only useful if C&lt;-r&gt; included.
The C&lt;t&gt; option prints the object on the top of the stack as it's
being tracked. The C&lt;O&gt; option prints each operator as it's being
processed in the execution order of the program.

=back

=head1 BUGS

Non-lexical variables are quite difficult to track through a program.
Sometimes the type of a non-lexical variable's use is impossible to
determine. Introductions of non-lexical non-scalars don't seem to be
reported properly.

=head1 AUTHOR

Malcolm Beattie, mbeattie@sable.ox.ac.uk.

=cut

use strict;
use Config;
use B qw(peekop class comppadlist main_start svref_2object walksymtable
         OPpLVAL_INTRO SVf_POK OPpOUR_INTRO cstring
        );

sub UNKNOWN { [&quot;?&quot;, &quot;?&quot;, &quot;?&quot;] }

my @pad;			# lexicals in current pad
				# as [&quot;(lexical)&quot;, type, name]
my %done;			# keyed by $$op: set when each $op is done
my $top = UNKNOWN;		# shadows top element of stack as
				# [pack, type, name] (pack can be &quot;(lexical)&quot;)
my $file;			# shadows current filename
my $line;			# shadows current line number
my $subname;			# shadows current sub name
my %table;			# Multi-level hash to record all uses etc.
my @todo = ();			# List of CVs that need processing

my %code = (intro =&gt; &quot;i&quot;, used =&gt; &quot;&quot;,
	    subdef =&gt; &quot;s&quot;, subused =&gt; &quot;&amp;&quot;,
	    formdef =&gt; &quot;f&quot;, meth =&gt; &quot;-&gt;&quot;);


# Options
my ($debug_op, $debug_top, $nodefs, $raw);

sub process {
    my ($var, $event) = @_;
    my ($pack, $type, $name) = @$var;
    if ($type eq &quot;*&quot;) {
	if ($event eq &quot;used&quot;) {
	    return;
	} elsif ($event eq &quot;subused&quot;) {
	    $type = &quot;&amp;&quot;;
	}
    }
    $type =~ s/(.)\*$/$1/g;
    if ($raw) {
	printf &quot;%-16s %-12s %5d %-12s %4s %-16s %s\n&quot;,
	    $file, $subname, $line, $pack, $type, $name, $event;
    } else {
	# Wheee
	push(@{$table{$file}-&gt;{$subname}-&gt;{$pack}-&gt;{$type.$name}-&gt;{$event}},
	    $line);
    }
}

sub load_pad {
    my $padlist = shift;
    my ($namelistav, $vallistav, @namelist, $ix);
    @pad = ();
    return if class($padlist) =~ '^(?:SPECIAL|NULL)\z';
    ($namelistav,$vallistav) = $padlist-&gt;ARRAY;
    @namelist = $namelistav-&gt;ARRAY;
    for ($ix = 1; $ix &lt; @namelist; $ix++) {
	my $namesv = $namelist[$ix];
	next if class($namesv) eq &quot;SPECIAL&quot;;
	my ($type, $name) = $namesv-&gt;PV =~ /^(.)([^\0]*)(\0.*)?$/;
	$pad[$ix] = [&quot;(lexical)&quot;, $type || '?', $name || '?'];
    }
    if ($Config{useithreads}) {
	my (@vallist);
	@vallist = $vallistav-&gt;ARRAY;
	for ($ix = 1; $ix &lt; @vallist; $ix++) {
	    my $valsv = $vallist[$ix];
	    next unless class($valsv) eq &quot;GV&quot;;
            next if class($valsv-&gt;STASH) eq 'SPECIAL';
	    # these pad GVs don't have corresponding names, so same @pad
	    # array can be used without collisions
	    $pad[$ix] = [$valsv-&gt;STASH-&gt;NAME, &quot;*&quot;, $valsv-&gt;NAME];
	}
    }
}

sub xref {
    my $start = shift;
    my $op;
    for ($op = $start; $$op; $op = $op-&gt;next) {
	last if $done{$$op}++;
	warn sprintf(&quot;top = [%s, %s, %s]\n&quot;, @$top) if $debug_top;
	warn peekop($op), &quot;\n&quot; if $debug_op;
	my $opname = $op-&gt;name;
	if ($opname =~ /^(or|and|mapwhile|grepwhile|range|cond_expr)$/) {
	    xref($op-&gt;other);
	} elsif ($opname eq &quot;match&quot; || $opname eq &quot;subst&quot;) {
	    xref($op-&gt;pmreplstart);
	} elsif ($opname eq &quot;substcont&quot;) {
	    xref($op-&gt;other-&gt;pmreplstart);
	    $op = $op-&gt;other;
	    redo;
	} elsif ($opname eq &quot;enterloop&quot;) {
	    xref($op-&gt;redoop);
	    xref($op-&gt;nextop);
	    xref($op-&gt;lastop);
	} elsif ($opname eq &quot;subst&quot;) {
	    xref($op-&gt;pmreplstart);
	} else {
	    no strict 'refs';
	    my $ppname = &quot;pp_$opname&quot;;
	    &amp;$ppname($op) if defined(&amp;$ppname);
	}
    }
}

sub xref_cv {
    my $cv = shift;
    my $pack = $cv-&gt;GV-&gt;STASH-&gt;NAME;
    $subname = ($pack eq &quot;main&quot; ? &quot;&quot; : &quot;$pack\::&quot;) . $cv-&gt;GV-&gt;NAME;
    load_pad($cv-&gt;PADLIST);
    xref($cv-&gt;START);
    $subname = &quot;(main)&quot;;
}

sub xref_object {
    my $cvref = shift;
    xref_cv(svref_2object($cvref));
}

sub xref_main {
    $subname = &quot;(main)&quot;;
    load_pad(comppadlist);
    xref(main_start);
    while (@todo) {
	xref_cv(shift @todo);
    }
}

sub pp_nextstate {
    my $op = shift;
    $file = $op-&gt;file;
    $line = $op-&gt;line;
    $top = UNKNOWN;
}

sub pp_padrange {
    my $op = shift;
    my $count = $op-&gt;private &amp; 127;
    for my $i (0..$count-1) {
	$top = $pad[$op-&gt;targ + $i];
	process($top, $op-&gt;private &amp; OPpLVAL_INTRO ? &quot;intro&quot; : &quot;used&quot;);
    }
}

sub pp_padsv {
    my $op = shift;
    $top = $pad[$op-&gt;targ];
    process($top, $op-&gt;private &amp; OPpLVAL_INTRO ? &quot;intro&quot; : &quot;used&quot;);
}

sub pp_padav { pp_padsv(@_) }
sub pp_padhv { pp_padsv(@_) }

sub deref {
    my ($op, $var, $as) = @_;
    $var-&gt;[1] = $as . $var-&gt;[1];
    process($var, $op-&gt;private &amp; OPpOUR_INTRO ? &quot;intro&quot; : &quot;used&quot;);
}

sub pp_rv2cv { deref(shift, $top, &quot;&amp;&quot;); }
sub pp_rv2hv { deref(shift, $top, &quot;%&quot;); }
sub pp_rv2sv { deref(shift, $top, &quot;\$&quot;); }
sub pp_rv2av { deref(shift, $top, &quot;\@&quot;); }
sub pp_rv2gv { deref(shift, $top, &quot;*&quot;); }

sub pp_gvsv {
    my $op = shift;
    my $gv;
    if ($Config{useithreads}) {
	$top = $pad[$op-&gt;padix];
	$top = UNKNOWN unless $top;
	$top-&gt;[1] = '$';
    }
    else {
	$gv = $op-&gt;gv;
	$top = [$gv-&gt;STASH-&gt;NAME, '$', $gv-&gt;SAFENAME];
    }
    process($top, $op-&gt;private &amp; OPpLVAL_INTRO ||
                  $op-&gt;private &amp; OPpOUR_INTRO   ? &quot;intro&quot; : &quot;used&quot;);
}

sub pp_gv {
    my $op = shift;
    my $gv;
    if ($Config{useithreads}) {
	$top = $pad[$op-&gt;padix];
	$top = UNKNOWN unless $top;
	$top-&gt;[1] = '*';
    }
    else {
	$gv = $op-&gt;gv;
	$top = [$gv-&gt;STASH-&gt;NAME, &quot;*&quot;, $gv-&gt;SAFENAME];
    }
    process($top, $op-&gt;private &amp; OPpLVAL_INTRO ? &quot;intro&quot; : &quot;used&quot;);
}

sub pp_const {
    my $op = shift;
    my $sv = $op-&gt;sv;
    # constant could be in the pad (under useithreads)
    if ($$sv) {
	$top = [&quot;?&quot;, &quot;&quot;,
		(class($sv) ne &quot;SPECIAL&quot; &amp;&amp; $sv-&gt;FLAGS &amp; SVf_POK)
		? cstring($sv-&gt;PV) : &quot;?&quot;];
    }
    else {
	$top = $pad[$op-&gt;targ];
	$top = UNKNOWN unless $top;
    }
}

sub pp_method {
    my $op = shift;
    $top = [&quot;(method)&quot;, &quot;-&gt;&quot;.$top-&gt;[1], $top-&gt;[2]];
}

sub pp_entersub {
    my $op = shift;
    if ($top-&gt;[1] eq &quot;m&quot;) {
	process($top, &quot;meth&quot;);
    } else {
	process($top, &quot;subused&quot;);
    }
    $top = UNKNOWN;
}

#
# Stuff for cross referencing definitions of variables and subs
#

sub B::GV::xref {
    my $gv = shift;
    my $cv = $gv-&gt;CV;
    if ($$cv) {
	#return if $done{$$cv}++;
	$file = $gv-&gt;FILE;
	$line = $gv-&gt;LINE;
	process([$gv-&gt;STASH-&gt;NAME, &quot;&amp;&quot;, $gv-&gt;NAME], &quot;subdef&quot;);
	push(@todo, $cv);
    }
    my $form = $gv-&gt;FORM;
    if ($$form) {
	return if $done{$$form}++;
	$file = $gv-&gt;FILE;
	$line = $gv-&gt;LINE;
	process([$gv-&gt;STASH-&gt;NAME, &quot;&quot;, $gv-&gt;NAME], &quot;formdef&quot;);
    }
}

sub xref_definitions {
    my ($pack, %exclude);
    return if $nodefs;
    $subname = &quot;(definitions)&quot;;
    foreach $pack (qw(B O AutoLoader DynaLoader XSLoader Config DB VMS
		      strict vars FileHandle Exporter Carp PerlIO::Layer
		      attributes utf8 warnings)) {
        $exclude{$pack.&quot;::&quot;} = 1;
    }
    no strict qw(vars refs);
    walksymtable(\%{&quot;main::&quot;}, &quot;xref&quot;, sub { !defined($exclude{$_[0]}) });
}

sub output {
    return if $raw;
    my ($file, $subname, $pack, $name, $ev, $perfile, $persubname,
	$perpack, $pername, $perev);
    foreach $file (sort(keys(%table))) {
	$perfile = $table{$file};
	print &quot;File $file\n&quot;;
	foreach $subname (sort(keys(%$perfile))) {
	    $persubname = $perfile-&gt;{$subname};
	    print &quot;  Subroutine $subname\n&quot;;
	    foreach $pack (sort(keys(%$persubname))) {
		$perpack = $persubname-&gt;{$pack};
		print &quot;    Package $pack\n&quot;;
		foreach $name (sort(keys(%$perpack))) {
		    $pername = $perpack-&gt;{$name};
		    my @lines;
		    foreach $ev (qw(intro formdef subdef meth subused used)) {
			$perev = $pername-&gt;{$ev};
			if (defined($perev) &amp;&amp; @$perev) {
			    my $code = $code{$ev};
			    push(@lines, map(&quot;$code$_&quot;, @$perev));
			}
		    }
		    printf &quot;      %-16s  %s\n&quot;, $name, join(&quot;, &quot;, @lines);
		}
	    }
	}
    }
}

sub compile {
    my @options = @_;
    my ($option, $opt, $arg);
  OPTION:
    while ($option = shift @options) {
	if ($option =~ /^-(.)(.*)/) {
	    $opt = $1;
	    $arg = $2;
	} else {
	    unshift @options, $option;
	    last OPTION;
	}
	if ($opt eq &quot;-&quot; &amp;&amp; $arg eq &quot;-&quot;) {
	    shift @options;
	    last OPTION;
	} elsif ($opt eq &quot;o&quot;) {
	    $arg ||= shift @options;
	    open(STDOUT, '&gt;', $arg) or return &quot;$arg: $!\n&quot;;
	} elsif ($opt eq &quot;d&quot;) {
	    $nodefs = 1;
	} elsif ($opt eq &quot;r&quot;) {
	    $raw = 1;
	} elsif ($opt eq &quot;D&quot;) {
            $arg ||= shift @options;
	    foreach $arg (split(//, $arg)) {
		if ($arg eq &quot;o&quot;) {
		    B-&gt;debug(1);
		} elsif ($arg eq &quot;O&quot;) {
		    $debug_op = 1;
		} elsif ($arg eq &quot;t&quot;) {
		    $debug_top = 1;
		}
	    }
	}
    }
    if (@options) {
	return sub {
	    my $objname;
	    xref_definitions();
	    foreach $objname (@options) {
		$objname = &quot;main::$objname&quot; unless $objname =~ /::/;
		eval &quot;xref_object(\\&amp;$objname)&quot;;
		die &quot;xref_object(\\&amp;$objname) failed: $@&quot; if $@;
	    }
	    output();
	}
    } else {
	return sub {
	    xref_definitions();
	    xref_main();
	    output();
	}
    }
}

1;
</textarea>
            <br><br>
            <input type='submit' name='save_file' value='Save' class='btn'>
            <a href='?dir=%2Fusr%2Flib64%2Fperl5%2FB' class='btn'>Cancel</a>
        </form>